From e9505ab755d38bc1faa052626c18604e93712cb4 Mon Sep 17 00:00:00 2001
From: "Liguros - Gitlab CI/CD [develop]" <gitlab@liguros.net>
Date: Mon, 5 Feb 2024 22:48:26 +0000
Subject: Adding metadata

---
 dev-cpp/cli11/cli11-2.4.0.ebuild | 59 ++++++++++++++++++++++++++++++++++++++++
 1 file changed, 59 insertions(+)
 create mode 100644 dev-cpp/cli11/cli11-2.4.0.ebuild

(limited to 'dev-cpp/cli11/cli11-2.4.0.ebuild')

diff --git a/dev-cpp/cli11/cli11-2.4.0.ebuild b/dev-cpp/cli11/cli11-2.4.0.ebuild
new file mode 100644
index 000000000000..552deb9ddd53
--- /dev/null
+++ b/dev-cpp/cli11/cli11-2.4.0.ebuild
@@ -0,0 +1,59 @@
+# Copyright 2023-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake
+
+DESCRIPTION="Command line parser for C++11"
+HOMEPAGE="https://cliutils.github.io/CLI11/book/"
+SRC_URI="
+	https://github.com/CLIUtils/CLI11/archive/refs/tags/v${PV}.tar.gz
+		-> ${P}.tar.gz
+"
+S=${WORKDIR}/${PN^^}-${PV}
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+IUSE="doc test"
+RESTRICT="!test? ( test )"
+
+DEPEND="
+	test? (
+		dev-cpp/catch:0
+		dev-libs/boost
+	)
+"
+BDEPEND="
+	doc? (
+		app-text/doxygen
+		media-gfx/graphviz
+	)
+"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-2.4.0-cstdint.patch
+)
+
+src_configure() {
+	local mycmakeargs=(
+		-DCLI11_BUILD_DOCS=$(usex doc)
+		-DCLI11_BUILD_EXAMPLES=no
+		-DCLI11_BUILD_TESTS=$(usex test)
+		$(usev test -DCLI11_BOOST=yes)
+	)
+
+	cmake_src_configure
+}
+
+src_compile() {
+	cmake_src_compile all $(usev doc docs)
+}
+
+src_install() {
+	local DOCS=( CHANGELOG.md README.md book/{chapters,code,*.md} )
+	cmake_src_install
+
+	use doc && dodoc -r "${BUILD_DIR}"/docs/html
+}
-- 
cgit v1.3