From bd96b5ba9a99d509459e9700db13dbe15a63535a Mon Sep 17 00:00:00 2001
From: "Liguros - Gitlab CI/CD [develop]" <gitlab@liguros.net>
Date: Sun, 3 Sep 2023 18:28:56 +0000
Subject: Adding metadata

---
 dev-cpp/rang/rang-3.2.ebuild | 48 ++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 48 insertions(+)
 create mode 100644 dev-cpp/rang/rang-3.2.ebuild

(limited to 'dev-cpp/rang/rang-3.2.ebuild')

diff --git a/dev-cpp/rang/rang-3.2.ebuild b/dev-cpp/rang/rang-3.2.ebuild
new file mode 100644
index 000000000000..a06d69c7547c
--- /dev/null
+++ b/dev-cpp/rang/rang-3.2.ebuild
@@ -0,0 +1,48 @@
+# Copyright 2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake
+
+DESCRIPTION="Minimal, header-only, modern C++ library for terminal goodies"
+HOMEPAGE="https://agauniyal.github.io/rang/"
+SRC_URI="https://github.com/agauniyal/rang/archive/refs/tags/v${PV}.tar.gz
+	-> ${P}.gh.tar.gz"
+
+LICENSE="Unlicense"
+SLOT="0"
+KEYWORDS="~amd64"
+
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+PATCHES="${FILESDIR}/${P}-fix-tests.patch"
+
+BDEPEND="test? ( dev-cpp/doctest )"
+
+src_configure() {
+	cmake_src_configure
+	if use test; then
+		local BUILD_DIR CMAKE_USE_DIR
+		BUILD_DIR="${WORKDIR}/${P}_test"
+		CMAKE_USE_DIR="${S}/test"
+		cmake_src_configure
+	fi
+}
+
+src_compile() {
+	if use test; then
+		local BUILD_DIR CMAKE_USE_DIR
+		BUILD_DIR="${WORKDIR}/${P}_test"
+		CMAKE_USE_DIR="${S}/test"
+		cmake_src_compile
+	fi
+}
+
+src_test() {
+	local BUILD_DIR CMAKE_USE_DIR
+	BUILD_DIR="${WORKDIR}/${P}_test"
+	CMAKE_USE_DIR="${S}/test"
+	cmake_src_test
+}
-- 
cgit v1.3