From f767356f836788e2bb2843072155579fe8d8d214 Mon Sep 17 00:00:00 2001
From: "Liguros - Gitlab CI/CD [develop]" <gitlab@liguros.net>
Date: Sat, 17 May 2025 06:58:15 +0000
Subject: Adding metadata

---
 dev-cpp/sol2/sol2-3.5.0.ebuild | 66 ------------------------------------------
 1 file changed, 66 deletions(-)
 delete mode 100644 dev-cpp/sol2/sol2-3.5.0.ebuild

(limited to 'dev-cpp/sol2/sol2-3.5.0.ebuild')

diff --git a/dev-cpp/sol2/sol2-3.5.0.ebuild b/dev-cpp/sol2/sol2-3.5.0.ebuild
deleted file mode 100644
index 3d483db70d0e..000000000000
--- a/dev-cpp/sol2/sol2-3.5.0.ebuild
+++ /dev/null
@@ -1,66 +0,0 @@
-# Copyright 2021-2025 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-LUA_COMPAT=( lua5-{1,3,4} luajit )
-inherit cmake lua
-
-DESCRIPTION="Header-only C++ <-> Lua API wrapper"
-HOMEPAGE="https://github.com/ThePhD/sol2"
-SRC_URI="https://github.com/ThePhD/sol2/archive/refs/tags/v${PV}.tar.gz -> ${P}.tar.gz"
-
-LICENSE="MIT"
-SLOT="0"
-KEYWORDS="~amd64 ~arm64 ~ppc64 ~x86"
-IUSE="test"
-REQUIRED_USE="${LUA_REQUIRED_USE}"
-RESTRICT="!test? ( test )"
-
-DEPEND="
-	${LUA_DEPS}
-	test? (
-		>=dev-cpp/catch-3
-	)
-"
-BDEPEND="
-	virtual/pkgconfig
-"
-
-PATCHES=(
-	"${FILESDIR}"/sol2-3.3.0-werror.patch
-	"${FILESDIR}"/sol2-3.5.0-luajit-pkgconf.patch
-	"${FILESDIR}"/sol2-3.5.0-catch-depend.patch
-	"${FILESDIR}"/sol2-3.3.0-dont-install-tests.patch
-)
-
-src_configure() {
-	sol2_configure_wrapper() {
-		local mycmakeargs=(
-			-DSOL2_BUILD_LUA=no
-			-DSOL2_TESTS=$(usex test)
-			-DSOL2_LUA_VERSION="${ELUA}"
-		)
-		cmake_src_configure
-	}
-	lua_foreach_impl sol2_configure_wrapper
-}
-
-src_compile() {
-	lua_foreach_impl cmake_src_compile
-}
-
-src_test() {
-	sol2_test_wrapper() {
-		if [[ ${ELUA} == luajit ]]; then
-			einfo "Skipping test due to https://github.com/ThePhD/sol2/issues/1221"
-		else
-			cmake_src_test
-		fi
-	}
-	lua_foreach_impl sol2_test_wrapper
-}
-
-src_install() {
-	lua_foreach_impl cmake_src_install
-}
-- 
cgit v1.3