From f118d22765d50ec3494331d5b5c45810304ea943 Mon Sep 17 00:00:00 2001
From: Crucible <crucible@localhost>
Date: Sat, 10 Oct 2026 20:48:09 -0500
Subject: Publish srcux candidate 0000000623-20261010-204610

---
 dev-python/executing/executing-2.3.0.ebuild | 52 +++++++++++++++++++++++++++++
 1 file changed, 52 insertions(+)
 create mode 100644 dev-python/executing/executing-2.3.0.ebuild

(limited to 'dev-python/executing/executing-2.3.0.ebuild')

diff --git a/dev-python/executing/executing-2.3.0.ebuild b/dev-python/executing/executing-2.3.0.ebuild
new file mode 100644
index 000000000000..8b3539ead2b2
--- /dev/null
+++ b/dev-python/executing/executing-2.3.0.ebuild
@@ -0,0 +1,52 @@
+# Copyright 2020-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_TESTED=( python3_{13..14} )
+PYTHON_COMPAT=( python3_{13..14} )
+
+inherit distutils-r1 optfeature pypi
+
+DESCRIPTION="Get information about what a Python frame is currently doing"
+HOMEPAGE="
+	https://github.com/alexmojaki/executing/
+	https://pypi.org/project/executing/
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~arm64-macos ~x64-macos"
+
+BDEPEND="
+	dev-python/setuptools-scm[${PYTHON_USEDEP}]
+	test? (
+		>=dev-python/asttokens-2.1.0[${PYTHON_USEDEP}]
+		dev-python/littleutils[${PYTHON_USEDEP}]
+		dev-python/rich[${PYTHON_USEDEP}]
+	)
+"
+
+EPYTEST_PLUGINS=()
+distutils_enable_tests pytest
+
+python_test() {
+	if ! has "${EPYTHON}" "${PYTHON_TESTED[@]/_/.}"; then
+		einfo "Skipping tests on ${EPYTHON}"
+		return
+	fi
+
+	local EPYTEST_DESELECT=()
+	if ! has_version "dev-python/ipython[${PYTHON_USEDEP}]"; then
+		EPYTEST_DESELECT+=(
+			tests/test_ipython.py
+		)
+	fi
+
+	epytest
+}
+
+pkg_postinst() {
+	optfeature "getting node's source code" dev-python/asttokens
+}
-- 
cgit v1.3