From 6295f37a70d50a32011b5a1ee7793fea329cd5f2 Mon Sep 17 00:00:00 2001
From: Crucible <crucible@localhost>
Date: Thu, 24 Sep 2026 16:55:33 -0500
Subject: Publish srcux candidate 0000000383-20260924-165302

---
 dev-python/gfloat/gfloat-0.5.2-r2.ebuild | 79 --------------------------------
 1 file changed, 79 deletions(-)
 delete mode 100644 dev-python/gfloat/gfloat-0.5.2-r2.ebuild

(limited to 'dev-python/gfloat/gfloat-0.5.2-r2.ebuild')

diff --git a/dev-python/gfloat/gfloat-0.5.2-r2.ebuild b/dev-python/gfloat/gfloat-0.5.2-r2.ebuild
deleted file mode 100644
index 52a0a20c2d05..000000000000
--- a/dev-python/gfloat/gfloat-0.5.2-r2.ebuild
+++ /dev/null
@@ -1,79 +0,0 @@
-# Copyright 2024-2026 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-DISTUTILS_USE_PEP517=setuptools
-PYTHON_COMPAT=( python3_{13..14} )
-
-inherit distutils-r1 pypi
-
-DESCRIPTION="Generic floating-point types in Python"
-HOMEPAGE="
-	https://github.com/graphcore-research/gfloat/
-	https://pypi.org/project/gfloat/
-"
-
-LICENSE="MIT"
-SLOT="0"
-KEYWORDS="~amd64 ~arm ~arm64 ~riscv ~x86"
-IUSE="test-rust"
-
-RDEPEND="
-	dev-python/array-api-compat[${PYTHON_USEDEP}]
-	dev-python/more-itertools[${PYTHON_USEDEP}]
-	dev-python/numpy[${PYTHON_USEDEP}]
-"
-BDEPEND="
-	test? (
-		dev-python/jinja2[${PYTHON_USEDEP}]
-		dev-python/matplotlib[${PYTHON_USEDEP}]
-		dev-python/ml-dtypes[${PYTHON_USEDEP}]
-		dev-python/tabulate[${PYTHON_USEDEP}]
-		test-rust? (
-			dev-python/nbval[${PYTHON_USEDEP}]
-		)
-		!arm? ( !x86? (
-			dev-python/pandas[${PYTHON_USEDEP}]
-		) )
-	)
-"
-
-EPYTEST_PLUGINS=()
-distutils_enable_tests pytest
-
-PATCHES=(
-	# https://github.com/graphcore-research/gfloat/pull/60
-	"${FILESDIR}/${P}-32bit.patch"
-	# https://github.com/graphcore-research/gfloat/pull/64
-	"${FILESDIR}/${P}-signed-zero-overflow.patch"
-)
-
-python_test() {
-	local EPYTEST_IGNORE=(
-		# requires array-api-strict (probably not very valuable downstream)
-		test/test_array_api.py
-		# require jax
-		docs/source/03-value-tables.ipynb
-		docs/source/04-benchmark.ipynb
-		test/test_jax.py
-		# requires mx (possibly git version), torch
-		test/test_microxcaling.py
-		# requires torch
-		test/test_torch.py
-	)
-
-	if ! has_version "dev-python/jinja2[${PYTHON_USEDEP}]" ||
-		! has_version "dev-python/pandas[${PYTHON_USEDEP}]"
-	then
-		EPYTEST_IGNORE+=(
-			docs/source
-		)
-	fi
-
-	if has_version "dev-python/nbval[${PYTHON_USEDEP}]"; then
-		epytest -p nbval
-	else
-		epytest -o addopts=
-	fi
-}
-- 
cgit v1.3