From 8d50579e39879dc6ba06d9fa6829f2e9a2c77420 Mon Sep 17 00:00:00 2001
From: Crucible <crucible@localhost>
Date: Sat, 10 Oct 2026 03:05:02 -0500
Subject: Publish srcux candidate 0000000619-20261010-030308

---
 dev-python/jsonpatch/jsonpatch-1.34.ebuild | 51 ++++++++++++++++++++++++++++++
 1 file changed, 51 insertions(+)
 create mode 100644 dev-python/jsonpatch/jsonpatch-1.34.ebuild

(limited to 'dev-python/jsonpatch/jsonpatch-1.34.ebuild')

diff --git a/dev-python/jsonpatch/jsonpatch-1.34.ebuild b/dev-python/jsonpatch/jsonpatch-1.34.ebuild
new file mode 100644
index 000000000000..33a544ab47f4
--- /dev/null
+++ b/dev-python/jsonpatch/jsonpatch-1.34.ebuild
@@ -0,0 +1,51 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{13..14} )
+
+inherit distutils-r1
+
+MY_P=python-json-patch-${PV}
+DESCRIPTION="Apply JSON-Patches like http://tools.ietf.org/html/draft-pbryan-json-patch-04"
+HOMEPAGE="
+	https://github.com/stefankoegl/python-json-patch/
+	https://pypi.org/project/jsonpatch/
+"
+SRC_URI="
+	https://github.com/stefankoegl/python-json-patch/archive/v${PV}.tar.gz
+		-> ${MY_P}.gh.tar.gz
+"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc64 ~riscv ~x86"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	>=dev-python/jsonpointer-1.9[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		${RDEPEND}
+		dev-python/hypothesis[${PYTHON_USEDEP}]
+	)
+"
+
+src_prepare() {
+	distutils-r1_src_prepare
+
+	# https://github.com/stefankoegl/python-json-patch/pull/159
+	sed -e 's/unittest.makeSuite/unittest.defaultTestLoader.loadTestsFromTestCase/' \
+		-i ext_tests.py tests.py
+}
+
+python_test() {
+	"${EPYTHON}" tests.py || die "Tests of tests.py fail with ${EPYTHON}"
+	"${EPYTHON}" ext_tests.py || die "Tests of ext_tests.py fail with ${EPYTHON}"
+	"${EPYTHON}" property_tests.py || die "Tests of property_tests.py fail with ${EPYTHON}"
+}
-- 
cgit v1.3