From 6295f37a70d50a32011b5a1ee7793fea329cd5f2 Mon Sep 17 00:00:00 2001
From: Crucible <crucible@localhost>
Date: Thu, 24 Sep 2026 16:55:33 -0500
Subject: Publish srcux candidate 0000000383-20260924-165302

---
 dev-python/networkx/networkx-3.7.ebuild | 60 ---------------------------------
 1 file changed, 60 deletions(-)
 delete mode 100644 dev-python/networkx/networkx-3.7.ebuild

(limited to 'dev-python/networkx/networkx-3.7.ebuild')

diff --git a/dev-python/networkx/networkx-3.7.ebuild b/dev-python/networkx/networkx-3.7.ebuild
deleted file mode 100644
index 513c3fc26ca7..000000000000
--- a/dev-python/networkx/networkx-3.7.ebuild
+++ /dev/null
@@ -1,60 +0,0 @@
-# Copyright 1999-2026 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-DISTUTILS_USE_PEP517=setuptools
-PYPI_VERIFY_REPO=https://github.com/networkx/networkx
-PYTHON_FULLY_TESTED=( python3_{12..14} )
-PYTHON_COMPAT=( python3_{13..14} )
-
-inherit distutils-r1 optfeature pypi virtualx
-
-DESCRIPTION="Python tools to manipulate graphs and complex networks"
-HOMEPAGE="
-	https://networkx.org/
-	https://github.com/networkx/networkx/
-	https://pypi.org/project/networkx/
-"
-
-LICENSE="BSD"
-SLOT="0"
-KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc64 ~riscv ~sparc ~x86 ~x64-macos"
-
-BDEPEND="
-	test? (
-		>=dev-python/lxml-4.6[${PYTHON_USEDEP}]
-		$(python_gen_cond_dep '
-			>=dev-python/matplotlib-3.10[${PYTHON_USEDEP}]
-			>=dev-python/numpy-2.2[${PYTHON_USEDEP}]
-			>=dev-python/scipy-1.15[${PYTHON_USEDEP}]
-		' "${PYTHON_FULLY_TESTED[@]}")
-	)
-"
-
-EPYTEST_PLUGINS=()
-EPYTEST_XDIST=1
-distutils_enable_tests pytest
-
-src_test() {
-	virtx distutils-r1_src_test
-}
-
-python_test() {
-	# virtx implies nonfatal
-	nonfatal epytest || die
-}
-
-src_install() {
-	distutils-r1_src_install
-	# those examples use various assets and pre-compressed files
-	docompress -x /usr/share/doc/${PF}/examples
-}
-
-pkg_postinst() {
-	optfeature "recommended dependencies" "dev-python/matplotlib dev-python/numpy dev-python/pandas dev-python/scipy"
-	optfeature "graph drawing and graph layout algorithms" "dev-python/pygraphviz dev-python/pydot"
-	optfeature "YAML format reading and writing" "dev-python/pyyaml"
-	optfeature "shapefile format reading and writing" "sci-libs/gdal[python]"
-	optfeature "GraphML XML format" "dev-python/lxml"
-}
-- 
cgit v1.3