From 3b4c7e627726016d50653b6dd2e06020a1915eac Mon Sep 17 00:00:00 2001
From: Crucible <crucible@localhost>
Date: Sat, 17 Oct 2026 03:06:03 -0500
Subject: Publish srcux candidate 0000000724-20261017-030226

---
 dev-python/objgraph/objgraph-3.7.0.ebuild | 55 +++++++++++++++++++++++++++++++
 1 file changed, 55 insertions(+)
 create mode 100644 dev-python/objgraph/objgraph-3.7.0.ebuild

(limited to 'dev-python/objgraph/objgraph-3.7.0.ebuild')

diff --git a/dev-python/objgraph/objgraph-3.7.0.ebuild b/dev-python/objgraph/objgraph-3.7.0.ebuild
new file mode 100644
index 000000000000..6a9d1905c16c
--- /dev/null
+++ b/dev-python/objgraph/objgraph-3.7.0.ebuild
@@ -0,0 +1,55 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{13..14} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Draws Python object reference graphs with graphviz"
+HOMEPAGE="
+	https://github.com/mgedmin/objgraph/
+	https://pypi.org/project/objgraph/
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+IUSE="doc"
+
+RDEPEND="
+	media-gfx/graphviz
+"
+
+EPYTEST_PLUGINS=()
+distutils_enable_tests pytest
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# unhappy about pytest
+		tests.py::AtAddrsTest::test_at_addrs
+	)
+
+	case ${EPYTHON} in
+		pypy3*)
+			EPYTEST_DESELECT+=(
+				# CPython GC
+				tests.py::ByTypeTest::test_new_garbage
+
+				# repr() mismatch
+				tests.py::StringRepresentationTest::test_short_repr_mocked_instance_method_bound
+				tests.py::StringRepresentationTest::test_short_repr_mocked_instance_method_bound_with_mocked_name
+			)
+			;;
+	esac
+
+	# TODO: figure out how to run doctests
+	epytest tests.py
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( docs/* )
+	distutils-r1_python_install_all
+}
-- 
cgit v1.3