From 7381ef26a3e14a703da91508b2cc8606c34b804d Mon Sep 17 00:00:00 2001
From: Crucible <crucible@localhost>
Date: Mon, 19 Oct 2026 21:49:31 -0500
Subject: Publish srcux candidate 0000000740-20261019-200200

---
 dev-python/playwright/playwright-1.64.0.ebuild | 58 ++++++++++++++++++++++++++
 1 file changed, 58 insertions(+)
 create mode 100644 dev-python/playwright/playwright-1.64.0.ebuild

(limited to 'dev-python/playwright/playwright-1.64.0.ebuild')

diff --git a/dev-python/playwright/playwright-1.64.0.ebuild b/dev-python/playwright/playwright-1.64.0.ebuild
new file mode 100644
index 000000000000..e49e1625f7d2
--- /dev/null
+++ b/dev-python/playwright/playwright-1.64.0.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{13..14} )
+
+inherit distutils-r1
+
+DESCRIPTION="Python version of the Playwright testing and automation library"
+HOMEPAGE="https://github.com/microsoft/playwright-python"
+SRC_URI="https://github.com/microsoft/playwright-python/archive/refs/tags/v${PV}.tar.gz -> ${P}.tar.gz"
+
+S="${WORKDIR}/playwright-python-${PV}"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64"
+
+RDEPEND="
+	dev-util/playwright
+
+	dev-python/greenlet[${PYTHON_USEDEP}]
+	dev-python/pyee[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	dev-python/setuptools-scm[${PYTHON_USEDEP}]
+"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-1.64.0-look-up-playwright-from-the-PATH.patch"
+)
+
+EPYTEST_IGNORE=(
+	"playwright/_impl/__pyinstaller"
+)
+
+distutils_enable_tests import-check
+
+export SETUPTOOLS_SCM_PRETEND_VERSION=${PV}
+
+python_prepare_all() {
+	# Installs a Python wrapper around the driver that
+	# does nothing except calling the driver
+	sed -e '/\[project\.scripts\]/,/^\s*$/d' -i pyproject.toml || die
+
+	# Tries to download and extract the driver,
+	# but we have it in the system already
+	rm setup.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	cd "${BUILD_DIR}/install$(python_get_sitedir)" || die
+	epytest --import-check
+}
-- 
cgit v1.3