From 767f7c7f0c8666a5db06b3134c37b6e80e4b57fe Mon Sep 17 00:00:00 2001
From: Crucible <crucible@localhost>
Date: Fri, 9 Oct 2026 03:04:58 -0500
Subject: Publish srcux candidate 0000000611-20261009-030303

---
 dev-python/pymongo/Manifest              |   1 +
 dev-python/pymongo/pymongo-4.16.0.ebuild |   2 +-
 dev-python/pymongo/pymongo-4.17.0.ebuild |   2 +-
 dev-python/pymongo/pymongo-4.18.0.ebuild |   2 +-
 dev-python/pymongo/pymongo-4.18.1.ebuild |   2 +-
 dev-python/pymongo/pymongo-4.18.2.ebuild |   2 +-
 dev-python/pymongo/pymongo-4.18.3.ebuild | 201 +++++++++++++++++++++++++++++++
 7 files changed, 207 insertions(+), 5 deletions(-)
 create mode 100644 dev-python/pymongo/pymongo-4.18.3.ebuild

(limited to 'dev-python/pymongo')

diff --git a/dev-python/pymongo/Manifest b/dev-python/pymongo/Manifest
index 76b75d8e1fec..e6703178ab91 100644
--- a/dev-python/pymongo/Manifest
+++ b/dev-python/pymongo/Manifest
@@ -3,3 +3,4 @@ DIST mongo-python-driver-4.17.0.gh.tar.gz 2597488 BLAKE2B ad733542ca37f1de3e267e
 DIST mongo-python-driver-4.18.0.gh.tar.gz 2821886 BLAKE2B a7905ba2c5ef44ffc0d3d9ab3da8b59445358652a7a0ded6b1929bf36dfcc0bda63fad52b6f5c80a1bc746433521dc8690c064c10d312f07e2b28658f88ec217 SHA512 c4d2ded2148f98e2a510547b2e14d2aa4bd566d5b7c89e03a787d30be068c78278f5ff90edf4160a875df7bb6342773bc73cf14ac4cae2b66d679661ef6ed918
 DIST mongo-python-driver-4.18.1.gh.tar.gz 2824031 BLAKE2B 16147601da6004c0c87adefe9bf74ce21bcda1a3cf25c0c0ab9d5dc1542b92c1581fa1bb1c6f7024615990e8142ab87bc3fe665ec8cac6df9f48b0accaf9acc7 SHA512 2dd0b300cbfdbc8de197fd5ee21f5bca210b5df1efb1223dd3aa50cddae34b87fd16799450d8126769e50c97ce203d69e9bb1aa4b67a16f63e53a933db88a707
 DIST mongo-python-driver-4.18.2.gh.tar.gz 2825405 BLAKE2B 7e1f59ae6473232a1fad4d00b722d85d72584faf3c2fc320669474242e62ed8bf12e07a96c360be86d62e446b4cc33b62c57b6ad319ba7989071404eacf52a65 SHA512 93456d698fd867410d6a00550b7d9739b13a8907b1e451501402a878c907de1525db7648d7c24bf90144982a3f525e2ae5352c2ee677776303bda495b5982c71
+DIST mongo-python-driver-4.18.3.gh.tar.gz 2826394 BLAKE2B 830bd301aa011d1e21e61e29df699b4d64bccfc3fd49a6617ebdbe169ad7799b8a4a04dbeddbc570f8a92b22b7f078f062382ada27e8fdf116c86965876aa70f SHA512 a4f0f1ee3474a73244916b1352ad4fbbc372dfe0a486438fb4a843eecb03e4daec6d4902bcbd890ad585dac80bb2a2c7d3c13710b96f0330f5fc28e14ec3a9d4
diff --git a/dev-python/pymongo/pymongo-4.16.0.ebuild b/dev-python/pymongo/pymongo-4.16.0.ebuild
index 59464aaeaaf0..bc371f16d2e5 100644
--- a/dev-python/pymongo/pymongo-4.16.0.ebuild
+++ b/dev-python/pymongo/pymongo-4.16.0.ebuild
@@ -23,7 +23,7 @@ S=${WORKDIR}/${MY_P}
 
 LICENSE="Apache-2.0"
 SLOT="0"
-KEYWORDS="~alpha amd64 arm arm64 ~hppa ~loong ~mips ppc ppc64 ~riscv ~s390 ~sparc x86"
+KEYWORDS="amd64 arm arm64 ~loong ~mips ppc ppc64 ~riscv ~s390 ~sparc x86"
 IUSE="doc kerberos +native-extensions +test-full"
 
 RDEPEND="
diff --git a/dev-python/pymongo/pymongo-4.17.0.ebuild b/dev-python/pymongo/pymongo-4.17.0.ebuild
index 3e447e7eb6a8..6d4f0fa3e667 100644
--- a/dev-python/pymongo/pymongo-4.17.0.ebuild
+++ b/dev-python/pymongo/pymongo-4.17.0.ebuild
@@ -23,7 +23,7 @@ S=${WORKDIR}/${MY_P}
 
 LICENSE="Apache-2.0"
 SLOT="0"
-KEYWORDS="~alpha amd64 arm ~arm64 ~hppa ~loong ~mips ppc ppc64 ~riscv ~s390 ~sparc x86"
+KEYWORDS="amd64 arm ~arm64 ~loong ~mips ppc ppc64 ~riscv ~s390 ~sparc x86"
 IUSE="doc kerberos +native-extensions +test-full"
 
 RDEPEND="
diff --git a/dev-python/pymongo/pymongo-4.18.0.ebuild b/dev-python/pymongo/pymongo-4.18.0.ebuild
index fcae8c8a4cfd..8ac26c515c70 100644
--- a/dev-python/pymongo/pymongo-4.18.0.ebuild
+++ b/dev-python/pymongo/pymongo-4.18.0.ebuild
@@ -23,7 +23,7 @@ S=${WORKDIR}/${MY_P}
 
 LICENSE="Apache-2.0"
 SLOT="0"
-KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
 IUSE="doc kerberos +native-extensions +test-full"
 
 RDEPEND="
diff --git a/dev-python/pymongo/pymongo-4.18.1.ebuild b/dev-python/pymongo/pymongo-4.18.1.ebuild
index fcae8c8a4cfd..8ac26c515c70 100644
--- a/dev-python/pymongo/pymongo-4.18.1.ebuild
+++ b/dev-python/pymongo/pymongo-4.18.1.ebuild
@@ -23,7 +23,7 @@ S=${WORKDIR}/${MY_P}
 
 LICENSE="Apache-2.0"
 SLOT="0"
-KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
 IUSE="doc kerberos +native-extensions +test-full"
 
 RDEPEND="
diff --git a/dev-python/pymongo/pymongo-4.18.2.ebuild b/dev-python/pymongo/pymongo-4.18.2.ebuild
index fcae8c8a4cfd..8ac26c515c70 100644
--- a/dev-python/pymongo/pymongo-4.18.2.ebuild
+++ b/dev-python/pymongo/pymongo-4.18.2.ebuild
@@ -23,7 +23,7 @@ S=${WORKDIR}/${MY_P}
 
 LICENSE="Apache-2.0"
 SLOT="0"
-KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
 IUSE="doc kerberos +native-extensions +test-full"
 
 RDEPEND="
diff --git a/dev-python/pymongo/pymongo-4.18.3.ebuild b/dev-python/pymongo/pymongo-4.18.3.ebuild
new file mode 100644
index 000000000000..8ac26c515c70
--- /dev/null
+++ b/dev-python/pymongo/pymongo-4.18.3.ebuild
@@ -0,0 +1,201 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=hatchling
+PYTHON_COMPAT=( python3_{13..14} )
+
+inherit check-reqs distutils-r1
+
+MY_P=mongo-python-driver-${PV}
+DESCRIPTION="Python driver for MongoDB"
+HOMEPAGE="
+	https://github.com/mongodb/mongo-python-driver/
+	https://pypi.org/project/pymongo/
+"
+SRC_URI="
+	https://github.com/mongodb/mongo-python-driver/archive/${PV}.tar.gz
+		-> ${MY_P}.gh.tar.gz
+"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+IUSE="doc kerberos +native-extensions +test-full"
+
+RDEPEND="
+	<dev-python/dnspython-3.0.0[${PYTHON_USEDEP}]
+	kerberos? ( dev-python/kerberos[${PYTHON_USEDEP}] )
+"
+BDEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	test? (
+		test-full? (
+			>=dev-db/mongodb-2.6.0
+		)
+	)
+"
+
+distutils_enable_sphinx doc
+
+EPYTEST_PLUGINS=( pytest-asyncio )
+EPYTEST_RERUNS=5
+distutils_enable_tests pytest
+
+reqcheck() {
+	if use test && use test-full; then
+		# During the tests, database size reaches 1.5G.
+		local CHECKREQS_DISK_BUILD=1536M
+
+		check-reqs_${1}
+	fi
+}
+
+pkg_pretend() {
+	reqcheck pkg_pretend
+}
+
+pkg_setup() {
+	reqcheck pkg_setup
+}
+
+src_prepare() {
+	distutils-r1_src_prepare
+	# we do not want hatch-requirements-txt and its ton of NIH deps
+	sed -i -e '/requirements/d' pyproject.toml || die
+}
+
+python_compile() {
+	# causes build errors to be fatal
+	local -x TOX_ENV_NAME=whatever
+	local DISTUTILS_ARGS=()
+	# unconditionally implicitly disabled on pypy3
+	if ! use native-extensions; then
+		export NO_EXT=1
+	else
+		export PYMONGO_C_EXT_MUST_BUILD=1
+		unset NO_EXT
+	fi
+
+	distutils-r1_python_compile
+
+	# upstream forces setup.py build_ext -i in their setuptools hack
+	find -name '*.so' -delete || die
+}
+
+python_test() {
+	rm -rf bson pymongo || die
+
+	local EPYTEST_DESELECT=(
+		# network-sandbox
+		test/asynchronous/test_async_loop_unblocked.py::TestClientLoopUnblocked::test_client_does_not_block_loop
+		test/asynchronous/test_client.py::AsyncClientUnitTest::test_connection_timeout_ms_propagates_to_DNS_resolver
+		test/asynchronous/test_client.py::AsyncClientUnitTest::test_detected_environment_logging
+		test/asynchronous/test_client.py::AsyncClientUnitTest::test_detected_environment_warning
+		test/asynchronous/test_client.py::TestClient::test_service_name_from_kwargs
+		test/asynchronous/test_client.py::TestClient::test_srv_max_hosts_kwarg
+		test/test_client.py::ClientUnitTest::test_connection_timeout_ms_propagates_to_DNS_resolver
+		test/test_client.py::ClientUnitTest::test_detected_environment_logging
+		test/test_client.py::ClientUnitTest::test_detected_environment_warning
+		test/test_client.py::TestClient::test_service_name_from_kwargs
+		test/test_client.py::TestClient::test_srv_max_hosts_kwarg
+		test/test_dns.py::TestCaseInsensitive::test_connect_case_insensitive
+		test/asynchronous/test_dns.py::IsolatedAsyncioTestCaseInsensitive::test_connect_case_insensitive
+		test/test_srv_polling.py
+		test/asynchronous/test_srv_polling.py
+		test/test_uri_spec.py::TestAllScenarios::test_test_uri_options_srv-options_SRV_URI_with_custom_srvServiceName
+		test/test_uri_spec.py::TestAllScenarios::test_test_uri_options_srv-options_SRV_URI_with_invalid_type_for_srvMaxHosts
+		test/test_uri_spec.py::TestAllScenarios::test_test_uri_options_srv-options_SRV_URI_with_negative_integer_for_srvMaxHosts
+		test/test_uri_spec.py::TestAllScenarios::test_test_uri_options_srv-options_SRV_URI_with_positive_srvMaxHosts_and_loadBalanced=fa
+		test/test_uri_spec.py::TestAllScenarios::test_test_uri_options_srv-options_SRV_URI_with_srvMaxHosts
+		test/test_uri_spec.py::TestAllScenarios::test_test_uri_options_srv-options_SRV_URI_with_srvMaxHosts=0_and_loadBalanced=true
+		test/test_uri_spec.py::TestAllScenarios::test_test_uri_options_srv-options_SRV_URI_with_srvMaxHosts=0_and_replicaSet
+
+		# broken regularly by changes in mypy
+		test/test_typing.py::TestMypyFails::test_mypy_failures
+
+		# fragile to timing? fails because we're getting too many logs
+		test/test_connection_logging.py::TestConnectionLoggingConnectionPoolOptions::test_maxConnecting_should_be_included_in_connection_pool_created_message_when_specified
+
+		# hangs?
+		test/asynchronous/test_grid_file.py::AsyncTestGridFile::test_small_chunks
+
+		# broken async tests?
+		test/asynchronous/test_encryption.py
+
+		# -Werror
+		test/test_read_preferences.py::TestMongosAndReadPreference::test_read_preference_hedge_deprecated
+		test/asynchronous/test_read_preferences.py::TestMongosAndReadPreference::test_read_preference_hedge_deprecated
+
+		# fragile to timing? Internet?
+		test/test_client.py::TestClient::test_repr_srv_host
+		test/asynchronous/test_client.py::TestClient::test_repr_srv_host
+		test/asynchronous/test_ssl.py::TestSSL::test_pyopenssl_ignored_in_async
+	)
+
+	if ! use test-full; then
+		# .invalid is guaranteed to return NXDOMAIN per RFC 6761
+		local -x DB_IP=mongodb.invalid
+		epytest -p asyncio
+		return
+	fi
+
+	# Yes, we need TCP/IP for that...
+	local -x DB_IP=127.0.0.1
+	local -x DB_PORT=27000
+
+	local dbpath=${TMPDIR}/mongo.db
+	local logpath=${TMPDIR}/mongod.log
+
+	local failed=
+	mkdir -p "${dbpath}" || die
+	while true; do
+		ebegin "Trying to start mongod on port ${DB_PORT}"
+
+		# mongodb is extremely inefficient
+		# https://www.mongodb.com/docs/manual/reference/ulimit/#review-and-set-resource-limits
+		ulimit -n 64000 || die
+
+		local mongod_options=(
+			--dbpath "${dbpath}"
+			--bind_ip "${DB_IP}"
+			--port "${DB_PORT}"
+			--unixSocketPrefix "${TMPDIR}"
+			--logpath "${logpath}"
+			--fork
+
+			# try to reduce resource use
+			--wiredTigerCacheSizeGB 0.25
+		)
+
+		LC_ALL=C mongod "${mongod_options[@]}" && sleep 2
+
+		# Now we need to check if the server actually started...
+		if [[ ${?} -eq 0 && -S "${TMPDIR}"/mongodb-${DB_PORT}.sock ]]; then
+			# yay!
+			eend 0
+			break
+		elif grep -q 'Address already in use' "${logpath}"; then
+			# ay, someone took our port!
+			eend 1
+			: $(( DB_PORT += 1 ))
+			continue
+		else
+			eend 1
+			eerror "Unable to start mongod for tests. See the server log:"
+			eerror "	${logpath}"
+			die "Unable to start mongod for tests."
+		fi
+	done
+
+	nonfatal epytest -m "default or default_async or encryption" || failed=1
+
+	mongod --dbpath "${dbpath}" --shutdown || die
+
+	[[ ${failed} ]] && die "Tests fail with ${EPYTHON}"
+
+	rm -rf "${dbpath}" || die
+}
-- 
cgit v1.3