From a96a971c845e2cd3ffad3b8f63558c6408897f0a Mon Sep 17 00:00:00 2001
From: root <root@alpha.trunkmasters.com>
Date: Thu, 9 Jul 2026 03:04:33 -0500
Subject: Adding metadata

---
 dev-python/sigstore/sigstore-4.4.0-r1.ebuild | 62 ++++++++++++++++++++++++++++
 1 file changed, 62 insertions(+)
 create mode 100644 dev-python/sigstore/sigstore-4.4.0-r1.ebuild

(limited to 'dev-python/sigstore')

diff --git a/dev-python/sigstore/sigstore-4.4.0-r1.ebuild b/dev-python/sigstore/sigstore-4.4.0-r1.ebuild
new file mode 100644
index 000000000000..e223993e6f95
--- /dev/null
+++ b/dev-python/sigstore/sigstore-4.4.0-r1.ebuild
@@ -0,0 +1,62 @@
+# Copyright 2024-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=flit-core
+PYTHON_COMPAT=( python3_{13..14} )
+
+inherit distutils-r1
+
+MY_P=sigstore-python-${PV}
+DESCRIPTION="A tool for signing Python package distributions"
+HOMEPAGE="
+	https://github.com/sigstore/sigstore-python/
+	https://pypi.org/project/sigstore/
+"
+# no tests in sdist, as of 3.3.0
+SRC_URI="
+	https://github.com/sigstore/sigstore-python/archive/v${PV}.tar.gz
+		-> ${MY_P}.gh.tar.gz
+"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
+
+RDEPEND="
+	>=dev-python/cryptography-42[${PYTHON_USEDEP}]
+	>=dev-python/id-1.1.0[${PYTHON_USEDEP}]
+	>=dev-python/platformdirs-4.2[${PYTHON_USEDEP}]
+	>=dev-python/pyopenssl-23.0.0[${PYTHON_USEDEP}]
+	>=dev-python/pyasn1-0.6[${PYTHON_USEDEP}]
+	>=dev-python/pydantic-2[${PYTHON_USEDEP}]
+	>=dev-python/pyjwt-2.1[${PYTHON_USEDEP}]
+	dev-python/requests[${PYTHON_USEDEP}]
+	>=dev-python/rfc3161-client-1.0.3[${PYTHON_USEDEP}]
+	>=dev-python/rfc8785-0.1.2[${PYTHON_USEDEP}]
+	>=dev-python/rich-13[${PYTHON_USEDEP}]
+	~dev-python/sigstore-models-0.0.6[${PYTHON_USEDEP}]
+	~dev-python/sigstore-rekor-types-0.0.18[${PYTHON_USEDEP}]
+	>=dev-python/tuf-6.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/pretend[${PYTHON_USEDEP}]
+	)
+"
+
+EPYTEST_PLUGINS=()
+distutils_enable_tests pytest
+
+src_prepare() {
+	distutils-r1_src_prepare
+
+	# unpin deps
+	sed -r -i -e 's:~=:>=:' -e 's:, ?< ?[0-9.]*::' pyproject.toml || die
+}
+
+python_test() {
+	epytest test/unit --skip-online
+}
-- 
cgit v1.3