From d0038bbd997895e3be896bff91db9ef24b24c89c Mon Sep 17 00:00:00 2001
From: Crucible <crucible@localhost>
Date: Thu, 22 Oct 2026 15:00:50 -0500
Subject: Publish srcux candidate 0000000792-20261022-145705

---
 dev-python/sphinx/Manifest            |   1 +
 dev-python/sphinx/sphinx-9.2.0.ebuild | 104 ++++++++++++++++++++++++++++++++++
 2 files changed, 105 insertions(+)
 create mode 100644 dev-python/sphinx/sphinx-9.2.0.ebuild

(limited to 'dev-python/sphinx')

diff --git a/dev-python/sphinx/Manifest b/dev-python/sphinx/Manifest
index 9004e97b29a8..4fa9dddaa082 100644
--- a/dev-python/sphinx/Manifest
+++ b/dev-python/sphinx/Manifest
@@ -1,2 +1,3 @@
 DIST sphinx-9.1.0.gh.tar.gz 8840512 BLAKE2B 54f680ff84b43b3508c1c9208ff41dc9fba1ae8f8dd608287511fb16e28dc7fa72419165b41f556af266e00c737cd8cc23a6617776fa88f0dbb8379fbbf59397 SHA512 3b17a3d4123d19ed47c7ab7786edcbe7eb0566f298d9de22efb3f4f0476b6c0ddf858b57812f2dac718458d98ddc742a443b7c94771693a1ed3bf868850639b1
 DIST sphinx-9.1.1.gh.tar.gz 8840940 BLAKE2B 786a8f87dd28dae7ef5799fd39ff5ae2bbcdd6f2b100aa7d9f5a9c1c4b732fad1866431436013c6d540426e6ca5d76c4856479426e21a7aeb31e79a79d04d495 SHA512 b5b82e8f9694ff5b7238ed357ddb0bd2f938f9cefd366859af9d92ec55cc40892a56259bd87dddacfb91500c73d628e8aa97ddd5ea0fe53509ec372952f28f27
+DIST sphinx-9.2.0.gh.tar.gz 8876769 BLAKE2B 085b97cb8d33d47974a44bf14bd54ef6944b4880f0f6609b7d653b34df028d553ce5288efae7306f0a1a76cd2e79a950e8e5c29d4579c14efcd1ef7a62bf1116 SHA512 12f0339ca56893e2eb66c18816cb38e52eb5631053ce45693b8d9ee03e9d1249bf3a19c92cb3b4c3826615338582445600721755a2c449d85c78905073d7e14e
diff --git a/dev-python/sphinx/sphinx-9.2.0.ebuild b/dev-python/sphinx/sphinx-9.2.0.ebuild
new file mode 100644
index 000000000000..f28b6aaac66a
--- /dev/null
+++ b/dev-python/sphinx/sphinx-9.2.0.ebuild
@@ -0,0 +1,104 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=flit-core
+PYTHON_COMPAT=( python3_{13..14} )
+PYTHON_REQ_USE="threads(+)"
+
+inherit distutils-r1
+
+MY_P=${P/_}
+DESCRIPTION="Python documentation generator"
+HOMEPAGE="
+	https://www.sphinx-doc.org/
+	https://github.com/sphinx-doc/sphinx/
+	https://pypi.org/project/Sphinx/
+"
+SRC_URI="
+	https://github.com/sphinx-doc/sphinx/archive/v${PV/_}.tar.gz
+		-> ${MY_P}.gh.tar.gz
+"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="BSD-2"
+SLOT="0"
+if [[ ${PV} != *_rc* ]]; then
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+fi
+IUSE="doc latex"
+
+RDEPEND="
+	>=dev-python/alabaster-1.0[${PYTHON_USEDEP}]
+	>=dev-python/babel-2.18[${PYTHON_USEDEP}]
+	>=dev-python/docutils-0.21[${PYTHON_USEDEP}]
+	>=dev-python/imagesize-1.3[${PYTHON_USEDEP}]
+	>=dev-python/jinja2-3.1[${PYTHON_USEDEP}]
+	>=dev-python/packaging-25.0[${PYTHON_USEDEP}]
+	>=dev-python/pygments-2.19[${PYTHON_USEDEP}]
+	>=dev-python/requests-2.32.5[${PYTHON_USEDEP}]
+	>=dev-python/roman-numerals-3.0[${PYTHON_USEDEP}]
+	>=dev-python/snowballstemmer-3.0.1[${PYTHON_USEDEP}]
+	>=dev-python/sphinxcontrib-applehelp-1.0.7[${PYTHON_USEDEP}]
+	>=dev-python/sphinxcontrib-devhelp-1.0.6[${PYTHON_USEDEP}]
+	>=dev-python/sphinxcontrib-htmlhelp-2.0.6[${PYTHON_USEDEP}]
+	>=dev-python/sphinxcontrib-jsmath-1.0.1[${PYTHON_USEDEP}]
+	>=dev-python/sphinxcontrib-qthelp-1.0.6[${PYTHON_USEDEP}]
+	>=dev-python/sphinxcontrib-serializinghtml-1.1.9[${PYTHON_USEDEP}]
+	latex? (
+		dev-texlive/texlive-latexextra
+		dev-texlive/texlive-luatex
+		app-text/dvipng
+	)
+"
+BDEPEND="
+	doc? (
+		dev-python/sphinxcontrib-websupport[${PYTHON_USEDEP}]
+		media-gfx/graphviz
+	)
+	test? (
+		app-text/dvipng
+		>=dev-python/cython-3.1[${PYTHON_USEDEP}]
+		>=dev-python/defusedxml-0.7.1[${PYTHON_USEDEP}]
+		dev-python/pytest-rerunfailures[${PYTHON_USEDEP}]
+		>=dev-python/setuptools-80.0[${PYTHON_USEDEP}]
+		>=dev-python/typing-extensions-4.15[${PYTHON_USEDEP}]
+		dev-texlive/texlive-fontsextra
+		dev-texlive/texlive-latexextra
+		dev-texlive/texlive-luatex
+		virtual/imagemagick-tools[jpeg,png,svg]
+	)
+"
+
+EPYTEST_PLUGINS=()
+EPYTEST_RERUNS=5
+# EPYTEST_XDIST breaks stuff
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	local PATCHES=(
+		"${FILESDIR}/sphinx-3.2.1-doc-link.patch"
+	)
+
+	distutils-r1_python_prepare_all
+
+	# disable internet access
+	sed -i -e 's:^intersphinx_mapping:disabled_&:' \
+		doc/conf.py || die
+	# unpin dependencies
+	sed -i -e 's:,<[0-9.]*::' pyproject.toml || die
+}
+
+python_compile_all() {
+	# we can't use distutils_enable_sphinx because it would
+	# introduce a dep on itself
+	use doc && build_sphinx doc
+}
+
+python_test() {
+	mkdir -p "${BUILD_DIR}/sphinx_tempdir" || die
+	local -x SPHINX_TEST_TEMPDIR="${BUILD_DIR}/sphinx_tempdir"
+
+	epytest
+}
-- 
cgit v1.3