From bbb006370a87e5c60f21145a1c97a8dbbe42e7fe Mon Sep 17 00:00:00 2001
From: Crucible <crucible@localhost>
Date: Sun, 4 Oct 2026 03:05:07 -0500
Subject: Publish srcux candidate 0000000563-20261004-030310

---
 dev-python/websockets/websockets-17.2.ebuild | 61 ++++++++++++++++++++++++++++
 1 file changed, 61 insertions(+)
 create mode 100644 dev-python/websockets/websockets-17.2.ebuild

(limited to 'dev-python/websockets/websockets-17.2.ebuild')

diff --git a/dev-python/websockets/websockets-17.2.ebuild b/dev-python/websockets/websockets-17.2.ebuild
new file mode 100644
index 000000000000..fa4f27c47d22
--- /dev/null
+++ b/dev-python/websockets/websockets-17.2.ebuild
@@ -0,0 +1,61 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{13..14} )
+
+inherit distutils-r1
+
+DESCRIPTION="Library for building WebSocket servers and clients in Python"
+HOMEPAGE="
+	https://websockets.readthedocs.io/
+	https://github.com/python-websockets/websockets/
+	https://pypi.org/project/websockets/
+"
+# tests are missing pypi sdist, as of 16.0
+SRC_URI="
+	https://github.com/python-websockets/websockets/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+IUSE="+native-extensions"
+
+BDEPEND="
+	test? (
+		dev-python/trio[${PYTHON_USEDEP}]
+		dev-python/werkzeug[${PYTHON_USEDEP}]
+	)
+"
+
+EPYTEST_PLUGINS=()
+EPYTEST_RERUNS=10
+distutils_enable_tests pytest
+
+python_compile() {
+	if use native-extensions && [[ ${EPYTHON} != pypy3 ]] ; then
+		local -x BUILD_EXTENSION=yes
+	else
+		local -x BUILD_EXTENSION=no
+	fi
+
+	distutils-r1_python_compile
+}
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# requires DNS access
+		# https://bugs.gentoo.org/909567
+		tests/legacy/test_client_server.py::ClientServerTests::test_explicit_host_port
+		tests/legacy/test_client_server.py::SecureClientServerTests::test_explicit_host_port
+		# TODO
+		tests/asyncio/test_server.py::ServerTests::test_close_server_keeps_handlers_running
+	)
+
+	epytest tests --reruns-delay=2
+}
-- 
cgit v1.3