From e0894ddc3bd9bce1cb485fe476278c1ef9a2fd07 Mon Sep 17 00:00:00 2001
From: "Liguros - Gitlab CI/CD [develop]" <gitlab@liguros.net>
Date: Wed, 11 Mar 2026 19:11:55 +0000
Subject: Adding metadata

---
 dev-util/debugedit/debugedit-5.2.ebuild | 71 ---------------------------------
 1 file changed, 71 deletions(-)
 delete mode 100644 dev-util/debugedit/debugedit-5.2.ebuild

(limited to 'dev-util/debugedit/debugedit-5.2.ebuild')

diff --git a/dev-util/debugedit/debugedit-5.2.ebuild b/dev-util/debugedit/debugedit-5.2.ebuild
deleted file mode 100644
index 8afaf15c626f..000000000000
--- a/dev-util/debugedit/debugedit-5.2.ebuild
+++ /dev/null
@@ -1,71 +0,0 @@
-# Copyright 1999-2025 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-inherit multiprocessing verify-sig toolchain-funcs
-
-DESCRIPTION="Create debuginfo and source file distributions"
-HOMEPAGE="https://sourceware.org/debugedit/"
-SRC_URI="
-	https://sourceware.org/ftp/debugedit/${PV}/${P}.tar.xz
-	verify-sig? ( https://sourceware.org/ftp/debugedit/${PV}/${P}.tar.xz.sig )
-"
-
-LICENSE="GPL-3+ GPL-2+ LGPL-2+"
-SLOT="0"
-KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~mips ~ppc ~ppc64 ~riscv ~sparc ~x86"
-IUSE="test"
-RESTRICT="!test? ( test )"
-
-DEPEND="
-	>=dev-libs/elfutils-0.176-r1:=
-	>=dev-libs/xxhash-0.8:=
-	elibc_musl? ( >=sys-libs/error-standalone-2.0 )
-"
-RDEPEND="
-	${DEPEND}
-	sys-devel/dwz
-"
-BDEPEND="
-	sys-apps/help2man
-	virtual/pkgconfig
-	test? (
-		app-alternatives/cpio
-	)
-	verify-sig? (
-		sec-keys/openpgp-keys-debugedit
-	)
-"
-
-VERIFY_SIG_OPENPGP_KEY_PATH=/usr/share/openpgp-keys/debugedit.gpg
-
-PATCHES=(
-	"${FILESDIR}"/${P}-bashism.patch
-	"${FILESDIR}"/${P}-buildid.patch
-)
-
-src_configure() {
-	tc-export PKG_CONFIG
-
-	if use elibc_musl; then
-		export CFLAGS="${CFLAGS} $(${PKG_CONFIG} --cflags error-standalone)"
-		export LIBS="${LIBS} $(${PKG_CONFIG} --libs error-standalone)"
-	fi
-
-	local myconf=(
-		# avoid BDEP on dwz
-		DWZ=dwz
-		ac_cv_dwz_j=yes
-
-		# We don't want to effectively bundle xxhash. It fails to
-		# build with -Og and such too (bug #956627).
-		--disable-inlined-xxhash
-	)
-	econf "${myconf[@]}"
-}
-
-src_test() {
-	local -x CCACHE_DISABLE=1
-	emake -Onone check TESTSUITEFLAGS="--jobs=$(get_makeopts_jobs)"
-}
-- 
cgit v1.3