# Copyright 2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

PYTHON_COMPAT=( python3_{13..14} )

inherit cmake multilib python-any-r1 toolchain-funcs

DESCRIPTION="Embedded graph database built for query speed and scalability"
HOMEPAGE="
	https://github.com/kuzudb/kuzu
	https://kuzudb.github.io/docs/
"
SRC_URI="https://github.com/kuzudb/${PN}/archive/refs/tags/v${PV}.tar.gz -> ${P}.tar.gz"

LICENSE="MIT"
SLOT="0"
KEYWORDS="~amd64 ~arm64"
IUSE="static-libs"

BDEPEND="${PYTHON_DEPS}"

DOCS=( README.md )

pkg_setup() {
	python-any-r1_pkg_setup

	if [[ "${MERGE_TYPE}" == "binary" ]]; then
		return
	fi

	if tc-is-gcc && [[ "$(gcc-major-version)" -lt 12 ]]; then
		die "${CATEGORY}/${PN} requires GCC 12 or newer."
	elif tc-is-clang && [[ "$(clang-major-version)" -lt 18 ]]; then
		die "${CATEGORY}/${PN} requires Clang 18 or newer."
	fi
}

src_configure() {
	local mycmakeargs=(
		-DAUTO_UPDATE_GRAMMAR=OFF
		-DBUILD_BENCHMARK=OFF
		-DBUILD_EXAMPLES=OFF
		-DBUILD_EXTENSION_TESTS=OFF
		-DBUILD_JAVA=OFF
		-DBUILD_KUZU=ON
		-DBUILD_NODEJS=OFF
		-DBUILD_PYTHON=OFF
		-DBUILD_SHELL=ON
		-DBUILD_SINGLE_FILE_HEADER=ON
		-DBUILD_TESTS=OFF
		-DENABLE_BACKTRACES=OFF
		-DENABLE_LTO=OFF
		-DENABLE_WERROR=OFF
		-DPREFER_SYSTEM_DEPS=ON
	)
	cmake_src_configure
}

src_install() {
	cmake_src_install

	if ! use static-libs; then
		rm "${ED}/usr/$(get_libdir)/libkuzu.a" || die
	fi
}