Publish srcux candidate 0000000563-20261004-030310HEADdevelop

1 files changed, 59 insertions, 0 deletions

diff --git a/dev-cpp/simdutf/simdutf-9.2.1.ebuild b/dev-cpp/simdutf/simdutf-9.2.1.ebuild
new file mode 100644
index 000000000000..1fefa9267b49
--- /dev/null
+++ b/dev-cpp/simdutf/simdutf-9.2.1.ebuild
@@ -0,0 +1,59 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DOCS_BUILDER="doxygen"
+DOCS_DIR=""
+
+PYTHON_COMPAT=( python3_{13..14} )
+
+inherit cmake docs python-any-r1
+
+DESCRIPTION="Unicode validation and transcoding at billions of characters per second"
+HOMEPAGE="https://simdutf.github.io/simdutf/"
+SRC_URI="https://github.com/${PN}/${PN}/archive/refs/tags/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="|| ( Apache-2.0 MIT )"
+SLOT="0/36"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc ~ppc64 ~riscv ~sparc ~x86"
+IUSE="atomic-base64 test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	virtual/libiconv
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	${PYTHON_DEPS}
+	virtual/pkgconfig
+	doc? (
+		app-text/doxygen
+	)
+"
+
+src_configure() {
+
+	local mycmakeargs+=(
+		-DSIMDUTF_TESTS=$(usex test)
+		-DSIMDUTF_ATOMIC_BASE64_TESTS=$(usex test)
+	)
+
+	if use atomic-base64; then
+		mycmakeargs+=(
+			-DSIMDUTF_CXX_STANDARD=20
+		)
+	fi
+
+	cmake_src_configure
+}
+
+src_compile() {
+	cmake_src_compile
+	use doc && docs_compile
+}
+
+src_install() {
+	cmake_src_install
+	use doc && einstalldocs
+}