Publish srcux candidate 0000000520-20260929-030310

1 files changed, 69 insertions, 0 deletions

diff --git a/dev-python/isort/isort-9.0.2.ebuild b/dev-python/isort/isort-9.0.2.ebuild
new file mode 100644
index 000000000000..f0e75dd60fda
--- /dev/null
+++ b/dev-python/isort/isort-9.0.2.ebuild
@@ -0,0 +1,69 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYPI_VERIFY_REPO=https://github.com/PyCQA/isort
+PYTHON_COMPAT=( python3_{13..14} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="A python utility/library to sort imports"
+HOMEPAGE="
+	https://github.com/PyCQA/isort/
+	https://pypi.org/project/isort/
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+BDEPEND="
+	dev-python/hatch-vcs[${PYTHON_USEDEP}]
+	test? (
+		dev-python/black[${PYTHON_USEDEP}]
+		>=dev-python/colorama-0.4.6[${PYTHON_USEDEP}]
+		>=dev-python/mypy-extensions-1.1.0[${PYTHON_USEDEP}]
+		dev-python/natsort[${PYTHON_USEDEP}]
+		dev-vcs/git
+	)
+"
+
+EPYTEST_PLUGINS=( hypothesis pytest-mock )
+distutils_enable_tests pytest
+
+src_prepare() {
+	# unbundle tomli
+	sed -i -e 's:from ._vendored ::' isort/settings.py || die
+	rm -r isort/_vendored || die
+
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	cp -a "${BUILD_DIR}"/{install,test} || die
+	local -x PATH=${BUILD_DIR}/test/usr/bin:${PATH}
+
+	# Install necessary plugins
+	local p
+	for p in example*/; do
+		pushd "${p}" >/dev/null || die
+		distutils_pep517_install "${BUILD_DIR}"/test
+		popd >/dev/null || die
+	done
+
+	local EPYTEST_IGNORE=(
+		# Excluded from upstream's test script
+		tests/unit/test_deprecated_finders.py
+	)
+
+	if ! has_version "dev-python/pylama[${PYTHON_USEDEP}]"; then
+		EPYTEST_IGNORE+=(
+			tests/unit/test_importable.py
+			tests/unit/test_pylama_isort.py
+		)
+	fi
+
+	epytest tests/unit
+}