Publish srcux candidate 0000000709-20261016-030224

2 files changed, 63 insertions, 0 deletions

diff --git a/dev-python/netcdf4/Manifest b/dev-python/netcdf4/Manifest
index c6d4fcfe2190..81339cbd6258 100644
--- a/dev-python/netcdf4/Manifest
+++ b/dev-python/netcdf4/Manifest
@@ -1 +1,2 @@
 DIST netcdf4-1.7.4.tar.gz 838352 BLAKE2B 04c53f692234ebd5fba1e58cabacba337f70dfbc909aeb798b4663eb55446bed008bf783872325d4c99d4e2cfd856aa20194835d57e76669b84824cf216771d5 SHA512 e6021d3701cfb27a283592c5804e125b64adde541f60b1636ef5c1c604ea5eca3c4f9b72c72b0af958a341d876a991a5e3d45092ab1d0ed72384b7442cd8f425
+DIST netcdf4-1.7.5.tar.gz 848901 BLAKE2B 7d1608ede3d773775726b6c04a7398dde125a2bcc1e0fb6a9216d63cda09f9e9e4c18f0ba3a05b8171b48bd8c0c6d1bf32e53b6fb0756e5ea909994ef0c49d4d SHA512 40c1347f7816936e0a280ca78df5ce41deda970394e2887cea4693f0b254db432614fa34821a3feb6fded85e58c2ad4fb5273028c1d3eb984e912699258083b2
diff --git a/dev-python/netcdf4/netcdf4-1.7.5.ebuild b/dev-python/netcdf4/netcdf4-1.7.5.ebuild
new file mode 100644
index 000000000000..a50fccb92105
--- /dev/null
+++ b/dev-python/netcdf4/netcdf4-1.7.5.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=standalone
+PYPI_PN=netCDF4
+PYTHON_COMPAT=( python3_{13..14} )
+
+inherit distutils-r1 optfeature pypi
+
+DESCRIPTION="Python/numpy interface to the netCDF C library"
+HOMEPAGE="
+	https://unidata.github.io/netcdf4-python/
+	https://github.com/unidata/netcdf4-python/
+	https://pypi.org/project/netCDF4/
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="blosc bzip2 mpi test szip zstd"
+RESTRICT="!test? ( test )"
+
+DEPEND="
+	dev-python/numpy[${PYTHON_USEDEP}]
+	sci-libs/hdf5:=
+	sci-libs/netcdf:=[blosc(-)=,bzip2(-)=,hdf5,mpi=,szip=,zstd(-)=]
+	mpi? (
+		>=dev-python/mpi4py-3.1[${PYTHON_USEDEP}]
+	)
+"
+RDEPEND="
+	${DEPEND}
+	dev-python/certifi[${PYTHON_USEDEP}]
+	dev-python/cftime[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	dev-python/cython[${PYTHON_USEDEP}]
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	test? (
+		${RDEPEND}
+		dev-python/packaging[${PYTHON_USEDEP}]
+		>=dev-python/typing-extensions-4.15.0[${PYTHON_USEDEP}]
+		sci-libs/netcdf[tools(+)]
+	)
+"
+
+EPYTEST_PLUGINS=()
+EPYTEST_XDIST=1
+distutils_enable_tests pytest
+
+python_test() {
+	local -x NO_NET=1
+	epytest test
+}
+
+pkg_postinst() {
+	optfeature "HDF4 support" sci-libs/hdf "sci-libs/netcdf[hdf]"
+	optfeature "OPeNDAP support" net-misc/curl "sci-libs/netcdf[dap]"
+}