Publish srcux candidate 0000000386-20260924-165828

1 files changed, 67 insertions, 0 deletions

diff --git a/dev-python/notebook/notebook-7.6.3.ebuild b/dev-python/notebook/notebook-7.6.3.ebuild
new file mode 100644
index 000000000000..ce68793f8dcc
--- /dev/null
+++ b/dev-python/notebook/notebook-7.6.3.ebuild
@@ -0,0 +1,67 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYTHON_COMPAT=( python3_{13..14} )
+PYTHON_REQ_USE="threads(+)"
+
+inherit distutils-r1 pypi xdg-utils
+
+DESCRIPTION="Jupyter Interactive Notebook"
+HOMEPAGE="
+	https://jupyter.org/
+	https://github.com/jupyter/notebook/
+	https://pypi.org/project/notebook/
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64"
+
+COMMON_DEPEND="
+	>=dev-python/jupyter-builder-1.0.2[${PYTHON_USEDEP}]
+	<dev-python/jupyter-builder-2[${PYTHON_USEDEP}]
+"
+RDEPEND="
+	${COMMON_DEPEND}
+	>=dev-python/jupyter-server-2.19.0[${PYTHON_USEDEP}]
+	<dev-python/jupyter-server-3[${PYTHON_USEDEP}]
+	>=dev-python/jupyterlab-4.6.3[${PYTHON_USEDEP}]
+	<dev-python/jupyterlab-4.7[${PYTHON_USEDEP}]
+	>=dev-python/jupyterlab-server-2.28.0[${PYTHON_USEDEP}]
+	<dev-python/jupyterlab-server-3[${PYTHON_USEDEP}]
+	>=dev-python/notebook-shim-0.2[${PYTHON_USEDEP}]
+	<dev-python/notebook-shim-0.3[${PYTHON_USEDEP}]
+	>=dev-python/tornado-6.2.0[${PYTHON_USEDEP}]
+"
+
+BDEPEND="
+	${COMMON_DEPEND}
+	>=dev-python/hatch-jupyter-builder-0.5[${PYTHON_USEDEP}]
+	test? (
+		dev-python/ipykernel[${PYTHON_USEDEP}]
+		dev-python/nbval[${PYTHON_USEDEP}]
+		dev-python/requests[${PYTHON_USEDEP}]
+		dev-python/requests-unixsocket[${PYTHON_USEDEP}]
+	)
+"
+
+EPYTEST_PLUGINS=( pytest-{console-scripts,jupyter,timeout,tornasync} )
+distutils_enable_tests pytest
+
+python_install_all() {
+	distutils-r1_python_install_all
+	mv "${ED}/usr/etc" "${ED}/etc" || die
+}
+
+pkg_postinst() {
+	xdg_desktop_database_update
+	xdg_icon_cache_update
+}
+
+pkg_postrm() {
+	xdg_desktop_database_update
+	xdg_icon_cache_update
+}