Publish srcux candidate 0000000851-20261023-030226

2 files changed, 95 insertions, 0 deletions

diff --git a/dev-python/openstacksdk/Manifest b/dev-python/openstacksdk/Manifest
index 5176bbc41879..7da2ad48ff96 100644
--- a/dev-python/openstacksdk/Manifest
+++ b/dev-python/openstacksdk/Manifest
@@ -1,2 +1,3 @@
 DIST openstacksdk-4.20.0.tar.gz 1440710 BLAKE2B 882599b63bf119aedef1eef1729e09dc775f66459bd924d1072dad30f468f81eebf6908e2661ad1a5d1f4acdd6d473925ce0aee5d129fcc2570c399ce156f032 SHA512 a22bc39707292c7d6d741d434fc79866ce46868bceb2c0ccb729cfd7768d535ff5afcfc4f432cfffd6a064fe3763a79e7dc4c67580108d7cf24bac2a59d4f5ea
 DIST openstacksdk-4.21.0.tar.gz 1462515 BLAKE2B 3a26d7453d53f8c07e954fd8a4d40f29bd0ca4486073ce0d993c7428ae6dbeb049ff87eebe072b1ac56e4c30648fe410751bb73cf1c1169cafd6156534a1b93f SHA512 65cd90f30cf2ec39c9567bd2a271949679009ad0aa7493f04789364da107fd7ffe8eb9cabe8c38e25f892f012270ddb314509bd202fa97d885fc7a0c1e848ddd
+DIST openstacksdk-4.22.0.tar.gz 1473175 BLAKE2B 4e0fec14c415833ac17eeb155e6cc3b9d2f25372943068c4196b8038c86b7a2e270bf56b00077c71fa0e8eed59de330c28c94ecc666e0b1485d711399b1a903e SHA512 abf30745252960e09c9dcd91b93d2a726f46a43a0815b43dce1ff9952860081cd21d00e13aba70d04e987b3393d9ed32e03750ed0795dfcd63fe119c49169749
diff --git a/dev-python/openstacksdk/openstacksdk-4.22.0.ebuild b/dev-python/openstacksdk/openstacksdk-4.22.0.ebuild
new file mode 100644
index 000000000000..fa6f0e03f863
--- /dev/null
+++ b/dev-python/openstacksdk/openstacksdk-4.22.0.ebuild
@@ -0,0 +1,94 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=pbr
+PYTHON_COMPAT=( python3_{13..14} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="A collection of libraries for building applications to work with OpenStack"
+HOMEPAGE="
+	https://opendev.org/openstack/openstacksdk/
+	https://github.com/openstack/openstacksdk/
+	https://pypi.org/project/openstacksdk/
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~riscv ~x86"
+
+RDEPEND="
+	>=dev-python/cryptography-2.7[${PYTHON_USEDEP}]
+	>=dev-python/decorator-4.4.1[${PYTHON_USEDEP}]
+	>=dev-python/dogpile-cache-0.6.5[${PYTHON_USEDEP}]
+	>=dev-python/iso8601-0.1.11[${PYTHON_USEDEP}]
+	>=dev-python/jmespath-0.9.0[${PYTHON_USEDEP}]
+	>=dev-python/jsonpatch-1.21[${PYTHON_USEDEP}]
+	>=dev-python/keystoneauth1-5.16.0[${PYTHON_USEDEP}]
+	>=dev-python/os-service-types-1.8.1[${PYTHON_USEDEP}]
+	>=dev-python/pbr-2.2.0[${PYTHON_USEDEP}]
+	>=dev-python/platformdirs-3[${PYTHON_USEDEP}]
+	>=dev-python/psutil-3.2.2[${PYTHON_USEDEP}]
+	>=dev-python/pyyaml-3.13[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		>=dev-python/ddt-1.0.1[${PYTHON_USEDEP}]
+		>=dev-python/fixtures-3.0.0[${PYTHON_USEDEP}]
+		>=dev-python/jsonschema-3.2.0[${PYTHON_USEDEP}]
+		>=dev-python/oslo-config-6.1.0[${PYTHON_USEDEP}]
+		>=dev-python/oslotest-3.2.0[${PYTHON_USEDEP}]
+		>=dev-python/prometheus-client-0.4.2[${PYTHON_USEDEP}]
+		>=dev-python/requests-mock-1.2.0[${PYTHON_USEDEP}]
+		>=dev-python/statsd-3.3.0[${PYTHON_USEDEP}]
+		>=dev-python/testscenarios-0.4[${PYTHON_USEDEP}]
+		>=dev-python/testtools-2.8.0[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests unittest
+
+src_prepare() {
+	# Internet?
+	sed -e 's:test_create_dynamic_large_object:_&:' \
+		-i openstack/tests/unit/cloud/test_object.py || die
+
+	# TODO
+	sed -e 's:test_generate_form:_&:' \
+		-e 's:test_create_static_large_object:_&:' \
+		-e 's:test_object_segment_retries:_&:' \
+		-e 's:test_object_segment_retry_failure:_&:' \
+		-e 's:test_slo_manifest_retry:_&:' \
+		-i openstack/tests/unit/cloud/test_object.py || die
+	sed -e 's:test_servers:_&:' \
+		-i openstack/tests/unit/test_stats.py || die
+
+	# unhappy about paths due to test runner
+	sed -e 's:test_method_not_supported:_&:' \
+		-i openstack/tests/unit/test_exceptions.py || die
+	sed -e 's:test_repr:_&:' \
+		-i openstack/tests/unit/test_resource.py || die
+
+	# requires hacking
+	rm openstack/tests/unit/test_hacking.py || die
+
+	# fragile warning-based tests
+	sed -e 's:test_unsupported_version_override:_&:' \
+		-i openstack/tests/unit/test_missing_version.py || die
+	sed -e 's:test_create_unknown_proxy:_&:' \
+		-i openstack/tests/unit/test_connection.py || die
+
+	# stupid test checking if they pin to the newest os-service-types,
+	# except they don't actually do
+	sed -e 's:test_ost_version:_&:' \
+		-i openstack/tests/unit/test_utils.py || die
+
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	# functional tests require cloud instance access
+	eunittest -b openstack/tests/unit
+}