Publish srcux candidate 0000000740-20261019-200200

1 files changed, 62 insertions, 0 deletions

diff --git a/dev-python/platformdirs/platformdirs-4.13.4.ebuild b/dev-python/platformdirs/platformdirs-4.13.4.ebuild
new file mode 100644
index 000000000000..64fa02613d59
--- /dev/null
+++ b/dev-python/platformdirs/platformdirs-4.13.4.ebuild
@@ -0,0 +1,62 @@
+# Copyright 2021-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=flit-core
+PYPI_VERIFY_REPO=https://github.com/tox-dev/platformdirs
+PYTHON_COMPAT=( python3_{13..14} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="A small Python module for determining appropriate platform-specific dirs"
+HOMEPAGE="
+	https://pypi.org/project/platformdirs/
+	https://github.com/tox-dev/platformdirs/
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~arm64-macos ~x64-macos ~x64-solaris"
+
+BDEPEND="
+	test? (
+		dev-python/appdirs[${PYTHON_USEDEP}]
+	)
+"
+
+EPYTEST_PLUGINS=( pytest-mock )
+distutils_enable_tests pytest
+
+src_configure() {
+	grep -q 'build-backend = "hatchling' pyproject.toml ||
+		die "Upstream changed build-backend, recheck"
+	# write a custom pyproject.toml to ease setuptools bootstrap
+	cat > pyproject.toml <<-EOF || die
+		[build-system]
+		requires = ["flit_core >=3.2,<4"]
+		build-backend = "flit_core.buildapi"
+
+		[project]
+		name = "${PN}"
+		version = "${PV}"
+		description = 'A small Python package for determining appropriate platform-specific dirs, e.g. a "user data dir".'
+	EOF
+	# sigh
+	cat > src/platformdirs/version.py <<-EOF || die
+		__version__ = version = '${PV}'
+		__version_tuple__ = version_tuple = (${PV//./, })
+	EOF
+}
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# failing on -Werror, because upstream doesn't bother using
+		# new pytest
+		tests/test_pytest_plugin.py::test_import_before_pytest_main
+	)
+
+	# have to disable removing tmp_paths since upstream mocks are
+	# incomplete and break teardown
+	epytest -p platformdirs.pytest_plugin -o tmp_path_retention_policy=all
+}