Publish srcux candidate 0000000559-20261003-030307

1 files changed, 43 insertions, 0 deletions

diff --git a/dev-python/python-utils/python-utils-4.1.0.ebuild b/dev-python/python-utils/python-utils-4.1.0.ebuild
new file mode 100644
index 000000000000..05d102d2521e
--- /dev/null
+++ b/dev-python/python-utils/python-utils-4.1.0.ebuild
@@ -0,0 +1,43 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=uv-build
+PYPI_VERIFY_REPO=https://github.com/wolph/python-utils
+PYTHON_COMPAT=( python3_{13..14} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Collection of small Python functions & classes"
+HOMEPAGE="
+	https://github.com/WoLpH/python-utils/
+	https://pypi.org/project/python-utils/
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+
+RDEPEND="
+	dev-python/typing-extensions[${PYTHON_USEDEP}]
+"
+
+EPYTEST_PLUGINS=( pytest-asyncio )
+distutils_enable_tests pytest
+
+EPYTEST_IGNORE=(
+	docs
+	_python_utils_tests/test_logger.py
+	python_utils/loguru.py
+)
+
+EPYTEST_DESELECT=(
+	# fragile
+	_python_utils_tests/test_time.py::test_timeout_generator
+)
+
+python_prepare_all() {
+	sed -i -e '/--cov/d' pyproject.toml || die
+	distutils-r1_python_prepare_all
+}