Adding metadata

4 files changed, 129 insertions, 0 deletions

diff --git a/dev-python/sphinx/Manifest b/dev-python/sphinx/Manifest
new file mode 100644
index 000000000000..035a213ef3fa
--- /dev/null
+++ b/dev-python/sphinx/Manifest
@@ -0,0 +1 @@
+DIST sphinx-9.1.0.gh.tar.gz 8840512 BLAKE2B 54f680ff84b43b3508c1c9208ff41dc9fba1ae8f8dd608287511fb16e28dc7fa72419165b41f556af266e00c737cd8cc23a6617776fa88f0dbb8379fbbf59397 SHA512 3b17a3d4123d19ed47c7ab7786edcbe7eb0566f298d9de22efb3f4f0476b6c0ddf858b57812f2dac718458d98ddc742a443b7c94771693a1ed3bf868850639b1
diff --git a/dev-python/sphinx/files/sphinx-3.2.1-doc-link.patch b/dev-python/sphinx/files/sphinx-3.2.1-doc-link.patch
new file mode 100644
index 000000000000..0c1b2ad7d98c
--- /dev/null
+++ b/dev-python/sphinx/files/sphinx-3.2.1-doc-link.patch
@@ -0,0 +1,14 @@
+https://bugs.gentoo.org/728810
+--- ./doc/internals/release-process.rst
++++ ./doc/internals/release-process.rst
+@@ -97,8 +97,8 @@
+ * ``set PYTHONWARNINGS=`` and do ``make html`` (Windows)
+ 
+ But you can also explicitly enable the pending ones using e.g.
+-``PYTHONWARNINGS=default`` (see the :ref:`Python docs on configuring warnings
+-<python:describing-warning-filters>`) for more details.
++``PYTHONWARNINGS=default`` (see the `Python docs on configuring warnings
++<https://docs.python.org/3/library/warnings.html#describing-warning-filters>`_) for more details.
+ 
+ Release procedures
+ ------------------
diff --git a/dev-python/sphinx/metadata.xml b/dev-python/sphinx/metadata.xml
new file mode 100644
index 000000000000..1089b9df10e2
--- /dev/null
+++ b/dev-python/sphinx/metadata.xml
@@ -0,0 +1,11 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://docs.baldeagleos.com/dtd/metadata.dtd">
+<pkgmetadata>
+  <maintainer type="project">
+    <email>python@gentoo.org</email>
+    <name>Python</name>
+  </maintainer>
+  <longdescription lang="en">Sphinx is a tool to create documentation for Python projects (or other documents consisting of multiple reStructuredText sources).</longdescription>
+  <stabilize-allarches />
+  <origin>baldeagleos-repo</origin>
+</pkgmetadata>
diff --git a/dev-python/sphinx/sphinx-9.1.0.ebuild b/dev-python/sphinx/sphinx-9.1.0.ebuild
new file mode 100644
index 000000000000..06bff1b18fc1
--- /dev/null
+++ b/dev-python/sphinx/sphinx-9.1.0.ebuild
@@ -0,0 +1,103 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=flit
+PYTHON_COMPAT=( python3_{13..14} )
+PYTHON_REQ_USE="threads(+)"
+
+inherit distutils-r1
+
+MY_P=${P/_}
+DESCRIPTION="Python documentation generator"
+HOMEPAGE="
+	https://www.sphinx-doc.org/
+	https://github.com/sphinx-doc/sphinx/
+	https://pypi.org/project/Sphinx/
+"
+SRC_URI="
+	https://github.com/sphinx-doc/sphinx/archive/v${PV/_}.tar.gz
+		-> ${MY_P}.gh.tar.gz
+"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="BSD-2"
+SLOT="0"
+if [[ ${PV} != *_rc* ]]; then
+	KEYWORDS="~alpha amd64 arm arm64 ~hppa ~loong ~m68k ~mips ppc ppc64 ~riscv ~s390 ~sparc x86"
+fi
+IUSE="doc latex"
+
+RDEPEND="
+	>=dev-python/alabaster-0.7.14[${PYTHON_USEDEP}]
+	>=dev-python/babel-2.13[${PYTHON_USEDEP}]
+	<dev-python/docutils-0.23[${PYTHON_USEDEP}]
+	>=dev-python/docutils-0.21[${PYTHON_USEDEP}]
+	>=dev-python/imagesize-1.3[${PYTHON_USEDEP}]
+	>=dev-python/jinja2-3.1[${PYTHON_USEDEP}]
+	>=dev-python/packaging-23.0[${PYTHON_USEDEP}]
+	>=dev-python/pygments-2.14[${PYTHON_USEDEP}]
+	>=dev-python/requests-2.30.0[${PYTHON_USEDEP}]
+	>=dev-python/roman-numerals-1.0.0[${PYTHON_USEDEP}]
+	>=dev-python/snowballstemmer-2.2[${PYTHON_USEDEP}]
+	>=dev-python/sphinxcontrib-applehelp-1.0.7[${PYTHON_USEDEP}]
+	>=dev-python/sphinxcontrib-devhelp-1.0.6[${PYTHON_USEDEP}]
+	>=dev-python/sphinxcontrib-htmlhelp-2.0.6[${PYTHON_USEDEP}]
+	>=dev-python/sphinxcontrib-jsmath-1.0.1[${PYTHON_USEDEP}]
+	>=dev-python/sphinxcontrib-qthelp-1.0.6[${PYTHON_USEDEP}]
+	>=dev-python/sphinxcontrib-serializinghtml-1.1.9[${PYTHON_USEDEP}]
+	latex? (
+		dev-texlive/texlive-latexextra
+		dev-texlive/texlive-luatex
+		app-text/dvipng
+	)
+"
+BDEPEND="
+	>=dev-python/flit-core-3.11
+	doc? (
+		dev-python/sphinxcontrib-websupport[${PYTHON_USEDEP}]
+		media-gfx/graphviz
+	)
+	test? (
+		app-text/dvipng
+		>=dev-python/cython-3.0.0[${PYTHON_USEDEP}]
+		>=dev-python/defusedxml-0.7.1[${PYTHON_USEDEP}]
+		dev-python/pytest-rerunfailures[${PYTHON_USEDEP}]
+		>=dev-python/setuptools-67.0[${PYTHON_USEDEP}]
+		dev-texlive/texlive-fontsextra
+		dev-texlive/texlive-latexextra
+		dev-texlive/texlive-luatex
+		virtual/imagemagick-tools[jpeg,png,svg]
+	)
+"
+
+PATCHES=(
+	"${FILESDIR}/sphinx-3.2.1-doc-link.patch"
+)
+
+EPYTEST_PLUGINS=()
+EPYTEST_RERUNS=5
+# EPYTEST_XDIST breaks stuff
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	# disable internet access
+	sed -i -e 's:^intersphinx_mapping:disabled_&:' \
+		doc/conf.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	# we can't use distutils_enable_sphinx because it would
+	# introduce a dep on itself
+	use doc && build_sphinx doc
+}
+
+python_test() {
+	mkdir -p "${BUILD_DIR}/sphinx_tempdir" || die
+	local -x SPHINX_TEST_TEMPDIR="${BUILD_DIR}/sphinx_tempdir"
+
+	epytest
+}