Adding metadata

1 files changed, 56 insertions, 0 deletions

diff --git a/dev-python/sqlalchemy/sqlalchemy-1.4.26.ebuild b/dev-python/sqlalchemy/sqlalchemy-1.4.26.ebuild
new file mode 100644
index 000000000000..14e7d5896fba
--- /dev/null
+++ b/dev-python/sqlalchemy/sqlalchemy-1.4.26.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{6,7,8,9,10} pypy3 )
+PYTHON_REQ_USE="sqlite?"
+
+inherit distutils-r1 optfeature
+
+MY_PN="SQLAlchemy"
+MY_P="${MY_PN}-${PV/_beta/b}"
+
+DESCRIPTION="Python SQL toolkit and Object Relational Mapper"
+HOMEPAGE="https://www.sqlalchemy.org/ https://pypi.org/project/SQLAlchemy/"
+SRC_URI="mirror://pypi/${MY_P:0:1}/${MY_PN}/${MY_P}.tar.gz"
+S="${WORKDIR}/${MY_P}"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x64-solaris"
+IUSE="examples +sqlite test"
+
+RDEPEND="
+	$(python_gen_cond_dep '
+		dev-python/importlib_metadata[${PYTHON_USEDEP}]
+	' pypy3)
+"
+BDEPEND="
+	test? (
+		$(python_gen_impl_dep sqlite)
+	)
+"
+
+distutils_enable_tests pytest
+
+EPYTEST_IGNORE=(
+	# hardcode call counts specific to Python versions
+	test/aaa_profiling
+)
+
+python_install_all() {
+	if use examples; then
+		docompress -x "/usr/share/doc/${PF}/examples"
+		dodoc -r examples
+	fi
+
+	distutils-r1_python_install_all
+}
+
+pkg_postinst() {
+	optfeature "MySQL support" dev-python/mysqlclient dev-python/pymysql \
+		dev-python/mysql-connector-python
+	optfeature "mssql support" dev-python/pymssql
+	optfeature "postgresql support" dev-python/psycopg:2
+}