Adding metadata

2 files changed, 94 insertions, 0 deletions

diff --git a/dev-python/tox/Manifest b/dev-python/tox/Manifest
index b7c90c163269..45b65617072b 100644
--- a/dev-python/tox/Manifest
+++ b/dev-python/tox/Manifest
@@ -4,3 +4,5 @@ DIST tox-4.33.0.tar.gz 204690 BLAKE2B 0f025d2cc9ea9227e1a9a2f920d24eb5fbe7e04238
 DIST tox-4.33.0.tar.gz.provenance 9377 BLAKE2B 8217393511a747c97029694cc8a8a8cca66fbbe7a0b5e3b31ec14209859689b096ee0aed6c6d957734624f74f606a706cbd5eab470d4d8bb6b95406af1390608 SHA512 45215846c6e797e45f41c9ae13457790d7584dbb010c7de3b652132bba1296e01a2a027334408062c9eb5b3f66b25b0abf876f9cab831268ff90806d63ce3d44
 DIST tox-4.34.0.tar.gz 205371 BLAKE2B bc077caea5a4f729152243b7d0e7e246e6df921186a4ccae5c7bab536e8ed56df0f9fa85bdd1faced37209f7d19aa5d5b859dc8a94abe1944a5821cf224bcec0 SHA512 436d038e1f8df562ec246e6b8390de4acf93e4b19b183bec1efaedf1a3b0bb616e5e65217c4e2dedff3942b74fed538f6bf3ade442b6108cf6f5207b3a658236
 DIST tox-4.34.0.tar.gz.provenance 9189 BLAKE2B 92254099e12754294fcb6924f6e32374ac84ad7525ab3933d2cafb0bc71c55604e9f267dd4fe3a803a7106df45b61b8badbe0c90af25123fc9c874d87083671d SHA512 a616e5d5a9fafad601631e48859a7817d6c025b75280a5e508f6b7f6eba8626a9a8a153e4a320a86b7897d335cc2f6392b6214405721ecb19be4890891907aef
+DIST tox-4.34.1.tar.gz 205306 BLAKE2B 76b90cd7b665ebbd3f7d83695168fc9f861b9d1751298fc04b6019bb100131149e4fe0e89c09068bd45a1774832237dfe6423aa909808ff2f52bc6a2e2ee0018 SHA512 ec7ffdf372d1794f659c36f9a5cfc41da18e23532323fbf9a7a21fe9b9ed71ce38f801086ec64de9a8aaea0a15e7b282e24175c7f8ae31930b63fab5dbd57beb
+DIST tox-4.34.1.tar.gz.provenance 9138 BLAKE2B 33b06d64b52e3fa092d681e899d73f8e307efd5660840498406342fde9698839cb39c7d5645bb484aa06a19b81eb5731e7e6698319c89e2948375918de3eb360 SHA512 33059f07f02a19786dbd4831006ef11581f977e85d76c369e19ffdacf476b14cba66ffa99c77cb0414d0a7f20a7e25883c496b65f721c3a817d164dbd83cc697
diff --git a/dev-python/tox/tox-4.34.1.ebuild b/dev-python/tox/tox-4.34.1.ebuild
new file mode 100644
index 000000000000..c91e7ba94c16
--- /dev/null
+++ b/dev-python/tox/tox-4.34.1.ebuild
@@ -0,0 +1,92 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYPI_VERIFY_REPO=https://github.com/tox-dev/tox
+PYTHON_COMPAT=( python3_{10..14} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="virtualenv-based automation of test activities"
+HOMEPAGE="
+	https://tox.readthedocs.io/
+	https://github.com/tox-dev/tox/
+	https://pypi.org/project/tox/
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+RDEPEND="
+	dev-python/cachetools[${PYTHON_USEDEP}]
+	dev-python/chardet[${PYTHON_USEDEP}]
+	dev-python/colorama[${PYTHON_USEDEP}]
+	dev-python/filelock[${PYTHON_USEDEP}]
+	dev-python/packaging[${PYTHON_USEDEP}]
+	dev-python/platformdirs[${PYTHON_USEDEP}]
+	dev-python/pluggy[${PYTHON_USEDEP}]
+	dev-python/pyproject-api[${PYTHON_USEDEP}]
+	dev-python/virtualenv[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	dev-python/hatch-vcs[${PYTHON_USEDEP}]
+	test? (
+		dev-python/build[${PYTHON_USEDEP}]
+		dev-python/distlib[${PYTHON_USEDEP}]
+		dev-python/psutil[${PYTHON_USEDEP}]
+		dev-python/re-assert[${PYTHON_USEDEP}]
+		$(python_gen_cond_dep '
+			dev-python/time-machine[${PYTHON_USEDEP}]
+		' 'python*')
+	)
+"
+
+EPYTEST_PLUGINS=( pytest-{mock,rerunfailures,xdist} )
+# xdist seems to mess up state between successive implementation runs
+distutils_enable_tests pytest
+
+src_prepare() {
+	# upstream lower bounds are meaningless
+	sed -i -e 's:>=[0-9.]*::' pyproject.toml || die
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	# devpi_process is not packaged, and has lots of dependencies
+	cat > "${T}"/devpi_process.py <<-EOF || die
+		def IndexServer(*args, **kwargs): raise NotImplementedError()
+	EOF
+
+	local -x PYTHONPATH=${T}:${PYTHONPATH}
+	local EPYTEST_DESELECT=(
+		# Internet
+		tests/tox_env/python/virtual_env/package/test_package_cmd_builder.py::test_build_wheel_external
+		tests/tox_env/python/virtual_env/package/test_package_cmd_builder.py::test_run_installpkg_targz
+		tests/tox_env/python/virtual_env/package/test_package_pyproject.py::test_pyproject_installpkg_pep517_envs
+	)
+	local EPYTEST_IGNORE=(
+		# requires devpi*
+		tests/test_provision.py
+	)
+
+	case ${EPYTHON} in
+		python*)
+			local EPYTEST_PLUGINS=( "${EPYTEST_PLUGINS[@]}" time-machine )
+			;;
+		pypy3*)
+			EPYTEST_DESELECT+=(
+				'tests/tox_env/python/pip/test_pip_install.py::test_constrain_package_deps[explicit-True-True]'
+				'tests/tox_env/python/pip/test_pip_install.py::test_constrain_package_deps[requirements-True-True]'
+				'tests/tox_env/python/pip/test_pip_install.py::test_constrain_package_deps[constraints-True-True]'
+				'tests/tox_env/python/pip/test_pip_install.py::test_constrain_package_deps[explicit+requirements-True-True]'
+				'tests/tox_env/python/pip/test_pip_install.py::test_constrain_package_deps[requirements_indirect-True-True]'
+				'tests/tox_env/python/pip/test_pip_install.py::test_constrain_package_deps[requirements_constraints_indirect-True-True]'
+			)
+			;;
+	esac
+
+	epytest -o addopts=
+}