Adding metadata

3 files changed, 73 insertions, 1 deletions

diff --git a/dev-python/tox/Manifest b/dev-python/tox/Manifest
index a71fd5ecd623..ac9b964111be 100644
--- a/dev-python/tox/Manifest
+++ b/dev-python/tox/Manifest
@@ -1 +1,2 @@
 DIST tox-3.26.0.gh.tar.gz 308035 BLAKE2B 745d1aef11c230971a7b6b1df919440c2be1b9b0f726ab314e1a27fe6fa72b568efc8e336058249721028cc18d2c3453e4806079abb8099baa608bf6b1e98ad7 SHA512 8c2635a640bcc221735f59da633b3ae696d97c076280400f6086703c2e00d8dbad943073e0c63618e5e041199dfebd010a16a00b1498ca9ea8e884648ed40ae5
+DIST tox-3.27.0.gh.tar.gz 308774 BLAKE2B efb3d40aa3045f984fd2534124de506c166fc8fde46d655c608ffcb7a85637ebda5c8bdef6cf4d414d84433fd361143fb91f98877d8112489c479049ec4f01be SHA512 e42cb0c203afb053c8bd6b29e90384fe6c32ab2ee3fb64fe0323474ca0b7f94d3e035d9d15218da28bc93d852c5f266c04b89d4b38db7d843d1098207f99a9bf
diff --git a/dev-python/tox/tox-3.26.0.ebuild b/dev-python/tox/tox-3.26.0.ebuild
index 2c9d7a45fa3c..b1b27f5c2a1a 100644
--- a/dev-python/tox/tox-3.26.0.ebuild
+++ b/dev-python/tox/tox-3.26.0.ebuild
@@ -4,7 +4,7 @@
 EAPI=8
 
 DISTUTILS_USE_PEP517=setuptools
-PYTHON_COMPAT=( python3_{7,8,9,10} pypy3 )
+PYTHON_COMPAT=( python3_{7,8,9,10,11} pypy3 )
 
 inherit distutils-r1
 
diff --git a/dev-python/tox/tox-3.27.0.ebuild b/dev-python/tox/tox-3.27.0.ebuild
new file mode 100644
index 000000000000..3469c524465e
--- /dev/null
+++ b/dev-python/tox/tox-3.27.0.ebuild
@@ -0,0 +1,71 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10,11} pypy3 )
+
+inherit distutils-r1
+
+DESCRIPTION="virtualenv-based automation of test activities"
+HOMEPAGE="
+	https://tox.readthedocs.io/
+	https://github.com/tox-dev/tox/
+	https://pypi.org/project/tox/
+"
+SRC_URI="
+	https://github.com/tox-dev/tox/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+RDEPEND="
+	dev-python/filelock[${PYTHON_USEDEP}]
+	dev-python/packaging[${PYTHON_USEDEP}]
+	>=dev-python/pluggy-0.12[${PYTHON_USEDEP}]
+	dev-python/py[${PYTHON_USEDEP}]
+	>=dev-python/six-1.14[${PYTHON_USEDEP}]
+	>=dev-python/virtualenv-20.1.0[${PYTHON_USEDEP}]
+	dev-python/pip[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '
+		>=dev-python/tomli-1.0.0[${PYTHON_USEDEP}]
+	' 3.8 3.9 3.10)
+"
+BDEPEND="
+	dev-python/setuptools_scm[${PYTHON_USEDEP}]
+	test? (
+		>=dev-python/flaky-3.4.0[${PYTHON_USEDEP}]
+		>=dev-python/freezegun-0.3.11[${PYTHON_USEDEP}]
+		dev-python/pytest-mock[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+export SETUPTOOLS_SCM_PRETEND_VERSION=${PV}
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# broken without Internet
+		tests/unit/session/test_provision.py::test_provision_non_canonical_dep
+		tests/integration/test_provision_int.py::test_provision_interrupt_child
+
+		# expects python2 to exist
+		tests/unit/interpreters/test_interpreters.py::test_tox_get_python_executable
+	)
+
+	[[ ${EPYTHON} != pypy3 ]] && EPYTEST_DESELECT+=(
+		# capfd doesn't seem to work for some non-obvious reason
+		tests/unit/test_z_cmdline.py::TestSession::test_summary_status
+		tests/unit/session/test_provision.py::test_provision_bad_requires
+
+		# TODO?
+		tests/unit/interpreters/test_interpreters.py::test_find_alias_on_path
+	)
+
+	epytest --no-network
+}