Adding metadata

3 files changed, 1 insertions, 100 deletions

diff --git a/dev-python/tox/Manifest b/dev-python/tox/Manifest
index b83391225e52..eacf53d46d8b 100644
--- a/dev-python/tox/Manifest
+++ b/dev-python/tox/Manifest
@@ -1,2 +1 @@
-DIST tox-4.25.0.tar.gz 196255 BLAKE2B 16d9e85270cad1e9909de8c51c906c8245201fc10c0dd48a37b202c3f4d381be183751e9aeac452c5f2bef8773bf8ad102be2b069e8ff545a1248f423664a863 SHA512 3560b667af03ca41c1bd8fa9eaa90f8c988b7f946498f3bc2d0a4dfa3a481d8ada27acb6201bde284a2bcfe14b86ee409a3ce8e875531423862d1af88e6248fb
 DIST tox-4.26.0.tar.gz 197260 BLAKE2B be05b52e88e3a3d0484203cb893af25e6e6e6f3719cf9e8d5cecf5343e22382b86676345ce00219d599353330ade897f710daf4976e48c2d7277664094a263c9 SHA512 ad2e311cd63c45a079b8c230a2feb364270b7a8bcf44b626385f8e442c6683ae841b3f34417b504f927608685a254fef3767d832fb5cfcc324c9cbf6ff7ea997
diff --git a/dev-python/tox/tox-4.25.0.ebuild b/dev-python/tox/tox-4.25.0.ebuild
deleted file mode 100644
index 415cb48c3e1b..000000000000
--- a/dev-python/tox/tox-4.25.0.ebuild
+++ /dev/null
@@ -1,98 +0,0 @@
-# Copyright 1999-2025 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-DISTUTILS_USE_PEP517=hatchling
-PYTHON_COMPAT=( python3_{9,10,11,12,13} pypy3 )
-
-inherit distutils-r1 pypi
-
-DESCRIPTION="virtualenv-based automation of test activities"
-HOMEPAGE="
-	https://tox.readthedocs.io/
-	https://github.com/tox-dev/tox/
-	https://pypi.org/project/tox/
-"
-
-LICENSE="MIT"
-SLOT="0"
-KEYWORDS="~alpha amd64 arm arm64 hppa ~loong ~mips ppc ppc64 ~riscv ~s390 sparc x86"
-
-RDEPEND="
-	dev-python/cachetools[${PYTHON_USEDEP}]
-	dev-python/chardet[${PYTHON_USEDEP}]
-	dev-python/colorama[${PYTHON_USEDEP}]
-	dev-python/filelock[${PYTHON_USEDEP}]
-	dev-python/packaging[${PYTHON_USEDEP}]
-	dev-python/platformdirs[${PYTHON_USEDEP}]
-	dev-python/pluggy[${PYTHON_USEDEP}]
-	dev-python/pyproject-api[${PYTHON_USEDEP}]
-	$(python_gen_cond_dep '
-		dev-python/tomli[${PYTHON_USEDEP}]
-		dev-python/typing-extensions[${PYTHON_USEDEP}]
-	' 3.10)
-	dev-python/virtualenv[${PYTHON_USEDEP}]
-"
-BDEPEND="
-	dev-python/hatch-vcs[${PYTHON_USEDEP}]
-	test? (
-		dev-python/build[${PYTHON_USEDEP}]
-		dev-python/distlib[${PYTHON_USEDEP}]
-		dev-python/flaky[${PYTHON_USEDEP}]
-		dev-python/psutil[${PYTHON_USEDEP}]
-		dev-python/pytest-mock[${PYTHON_USEDEP}]
-		dev-python/pytest-xdist[${PYTHON_USEDEP}]
-		dev-python/re-assert[${PYTHON_USEDEP}]
-		$(python_gen_cond_dep '
-			dev-python/time-machine[${PYTHON_USEDEP}]
-		' 'python*')
-	)
-"
-
-distutils_enable_tests pytest
-
-src_prepare() {
-	# upstream lower bounds are meaningless
-	sed -i -e 's:>=[0-9.]*::' pyproject.toml || die
-	distutils-r1_src_prepare
-}
-
-python_test() {
-	# devpi_process is not packaged, and has lots of dependencies
-	cat > "${T}"/devpi_process.py <<-EOF || die
-		def IndexServer(*args, **kwargs): raise NotImplementedError()
-	EOF
-
-	local -x PYTHONPATH=${T}:${PYTHONPATH}
-	local EPYTEST_DESELECT=(
-		# Internet
-		tests/tox_env/python/virtual_env/package/test_package_cmd_builder.py::test_build_wheel_external
-		tests/tox_env/python/virtual_env/package/test_package_cmd_builder.py::test_run_installpkg_targz
-	)
-	local EPYTEST_IGNORE=(
-		# requires devpi*
-		tests/test_provision.py
-	)
-
-	case ${EPYTHON} in
-		pypy3*)
-			EPYTEST_DESELECT+=(
-				'tests/tox_env/python/pip/test_pip_install.py::test_constrain_package_deps[explicit-True-True]'
-				'tests/tox_env/python/pip/test_pip_install.py::test_constrain_package_deps[requirements-True-True]'
-				'tests/tox_env/python/pip/test_pip_install.py::test_constrain_package_deps[constraints-True-True]'
-				'tests/tox_env/python/pip/test_pip_install.py::test_constrain_package_deps[explicit+requirements-True-True]'
-				'tests/tox_env/python/pip/test_pip_install.py::test_constrain_package_deps[requirements_indirect-True-True]'
-				'tests/tox_env/python/pip/test_pip_install.py::test_constrain_package_deps[requirements_constraints_indirect-True-True]'
-			)
-			;;
-		python3.13)
-			EPYTEST_DESELECT+=(
-				# https://github.com/tox-dev/tox/issues/3290
-				'tests/config/loader/test_str_convert.py::test_str_convert_ok_py39[1,2-value1-Optional]'
-			)
-			;;
-	esac
-
-	epytest
-}
diff --git a/dev-python/tox/tox-4.26.0.ebuild b/dev-python/tox/tox-4.26.0.ebuild
index 25f6c0040e9e..662607985d54 100644
--- a/dev-python/tox/tox-4.26.0.ebuild
+++ b/dev-python/tox/tox-4.26.0.ebuild
@@ -17,7 +17,7 @@ HOMEPAGE="
 
 LICENSE="MIT"
 SLOT="0"
-KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+KEYWORDS="~alpha amd64 arm arm64 hppa ~loong ~mips ppc ppc64 ~riscv ~s390 sparc x86"
 
 RDEPEND="
 	dev-python/cachetools[${PYTHON_USEDEP}]