Adding metadata

2 files changed, 94 insertions, 0 deletions

diff --git a/dev-python/tox/Manifest b/dev-python/tox/Manifest
index 1e0d31aa296f..410c703e75c0 100644
--- a/dev-python/tox/Manifest
+++ b/dev-python/tox/Manifest
@@ -14,3 +14,5 @@ DIST tox-4.36.1.tar.gz 212677 BLAKE2B adc9ca41d00d73fb1a45f85934ab6619fff90b33a7
 DIST tox-4.36.1.tar.gz.provenance 9381 BLAKE2B 7d802ac1866abb6383b797fe9845562edaa2a5d806b272d4b53221d819f02661d61697698bc72f355082a28b2ede860004c77bd7a07e8d09163e2e2d5e9da24c SHA512 19810bdeba1feb52d4573c5e3fed6b20e1fbc9c2e05c5a191cb2a192096bd096cbeb133b2e888fa89c1fe7bb156179b13a3a679ea418878315ccf259f8b73db8
 DIST tox-4.38.0.tar.gz 215498 BLAKE2B d7fa0df218c205bf90d213fab3de5c729750db4ef89f2fc41754e66e0114bc2dae4ef775a4071f49218a5ea97f66510b9f86b69b88e353dab00eed2ca523e363 SHA512 1a16cf4ba44e59cd433a62405dbdccffad06ccdff8ed417344aad26ff1c35095f596ff008be4ac7c4ef94ae90e01e4454fe018417c6dac9f23516a1314128260
 DIST tox-4.38.0.tar.gz.provenance 9232 BLAKE2B 49593ac7877b6feee78ec58944f19c622a56a431266d8101d7dc2fd779626f4f1a5e204a2acf4a413207b6c930dbc2ab9dd5cbea9adb07e37480e7a0e1e040db SHA512 9e03320bd129dada7771f8cf8a8a5e51afd9c2a893d70607ccd8fe07e003cff603b775029fad209558e8dfce22b002a87353253cb331f7c098ab761fbb58621e
+DIST tox-4.39.0.tar.gz 221354 BLAKE2B e1a648abbf8b3ac10915fad3f89542b99d3140157035b55e96c532880c4a8f1e48605e7ab99f7eb40dd807bd48f754e4a202b37929f6f3b4e9c0301cfcc00b05 SHA512 a7ebdc2cb06f73b9ff84971e39811553f48b1191146116b5ebd3f59b5f9027e1cd968aac0064f9d2e267c7f0a0c28c79f75305f55bef247e8d0fdec77c7442e9
+DIST tox-4.39.0.tar.gz.provenance 9240 BLAKE2B e12c7db4f636960052c52ae8590635838c22905aaec6cd163c4a951d201b5d509028973d4247954d5ee33ff70a8cd577b41bd4864c75b3388aee56e1bc9186b1 SHA512 0a91eb44d63f071a997853891ca2edceae719d8002308dd733780350abb501465777aff1e44a027a44cd8ae09ccf25eac57ab74d99c57adf4427121e53c255ad
diff --git a/dev-python/tox/tox-4.39.0.ebuild b/dev-python/tox/tox-4.39.0.ebuild
new file mode 100644
index 000000000000..42367ebe26f8
--- /dev/null
+++ b/dev-python/tox/tox-4.39.0.ebuild
@@ -0,0 +1,92 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYPI_VERIFY_REPO=https://github.com/tox-dev/tox
+PYTHON_COMPAT=( python3_{10..14} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="virtualenv-based automation of test activities"
+HOMEPAGE="
+	https://tox.readthedocs.io/
+	https://github.com/tox-dev/tox/
+	https://pypi.org/project/tox/
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+RDEPEND="
+	dev-python/cachetools[${PYTHON_USEDEP}]
+	dev-python/chardet[${PYTHON_USEDEP}]
+	dev-python/colorama[${PYTHON_USEDEP}]
+	dev-python/filelock[${PYTHON_USEDEP}]
+	dev-python/packaging[${PYTHON_USEDEP}]
+	dev-python/platformdirs[${PYTHON_USEDEP}]
+	dev-python/pluggy[${PYTHON_USEDEP}]
+	dev-python/pyproject-api[${PYTHON_USEDEP}]
+	dev-python/virtualenv[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	dev-python/hatch-vcs[${PYTHON_USEDEP}]
+	test? (
+		dev-python/build[${PYTHON_USEDEP}]
+		dev-python/distlib[${PYTHON_USEDEP}]
+		dev-python/psutil[${PYTHON_USEDEP}]
+		dev-python/re-assert[${PYTHON_USEDEP}]
+		$(python_gen_cond_dep '
+			dev-python/time-machine[${PYTHON_USEDEP}]
+		' 'python*')
+	)
+"
+
+EPYTEST_PLUGINS=( pytest-{mock,rerunfailures,timeout,xdist} )
+# xdist seems to mess up state between successive implementation runs
+distutils_enable_tests pytest
+
+src_prepare() {
+	# upstream lower bounds are meaningless
+	sed -i -e 's:>=[0-9.]*::' pyproject.toml || die
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	# devpi_process is not packaged, and has lots of dependencies
+	cat > "${T}"/devpi_process.py <<-EOF || die
+		def IndexServer(*args, **kwargs): raise NotImplementedError()
+	EOF
+
+	local -x PYTHONPATH=${T}:${PYTHONPATH}
+	local EPYTEST_DESELECT=(
+		# Internet
+		tests/tox_env/python/virtual_env/package/test_package_cmd_builder.py::test_build_wheel_external
+		tests/tox_env/python/virtual_env/package/test_package_cmd_builder.py::test_run_installpkg_targz
+		tests/tox_env/python/virtual_env/package/test_package_pyproject.py::test_pyproject_installpkg_pep517_envs
+	)
+	local EPYTEST_IGNORE=(
+		# requires devpi*
+		tests/test_provision.py
+	)
+
+	case ${EPYTHON} in
+		python*)
+			local EPYTEST_PLUGINS=( "${EPYTEST_PLUGINS[@]}" time-machine )
+			;;
+		pypy3*)
+			EPYTEST_DESELECT+=(
+				'tests/tox_env/python/pip/test_pip_install.py::test_constrain_package_deps[explicit-True-True]'
+				'tests/tox_env/python/pip/test_pip_install.py::test_constrain_package_deps[requirements-True-True]'
+				'tests/tox_env/python/pip/test_pip_install.py::test_constrain_package_deps[constraints-True-True]'
+				'tests/tox_env/python/pip/test_pip_install.py::test_constrain_package_deps[explicit+requirements-True-True]'
+				'tests/tox_env/python/pip/test_pip_install.py::test_constrain_package_deps[requirements_indirect-True-True]'
+				'tests/tox_env/python/pip/test_pip_install.py::test_constrain_package_deps[requirements_constraints_indirect-True-True]'
+			)
+			;;
+	esac
+
+	epytest -o addopts=
+}