Adding metadata

6 files changed, 104 insertions, 5 deletions

diff --git a/dev-python/tox/Manifest b/dev-python/tox/Manifest
index ad08e08d631c..bfe21d486e3f 100644
--- a/dev-python/tox/Manifest
+++ b/dev-python/tox/Manifest
@@ -4,3 +4,5 @@ DIST tox-4.53.1.tar.gz 276809 BLAKE2B 18e99c00cf24d12705050f59a2843d26ce02019825
 DIST tox-4.53.1.tar.gz.provenance 9432 BLAKE2B 33d7b56f0658c9fd009862674eb1b7c7d140af1a19a6c424765c4731376565d4d71b4c99b712782369fff1b7ad2a37c25d7bb5e0c3e64c0de86f3c867cbee63e SHA512 c626b2095aa0d1c94552a56b05cdf66fefd7a5eda1c6db33c3ebfa52bd4e96b118754412d6da872675b0fc76224c9c2e53abbd507b3b10aeac24d752e839df34
 DIST tox-4.54.0.tar.gz 279256 BLAKE2B f1a1265879ce21f9f4005268dd5800dd7d84d6c914f453d75c86fca6176aaab7c8e2c7a8091bc9103320469ab7c8b82f6faecb9473521f9442f818ca1a94d741 SHA512 923f622c8c0706a7d667e74b1ff42ec9c8ef578bc59e335cbb03ec3b654025263350241ee72c775499519f9d0b504fa859fe365b9435f25698c84449a3e217ed
 DIST tox-4.54.0.tar.gz.provenance 9424 BLAKE2B b9f9dee2859d4e640edd8e9ca8274a2715c25a11fe4639ec0b210f9565a12a50523c7f3e051f370259a70772b29abd617b28fa177da7bdc69179b8bd8ff35cf7 SHA512 efdf4aabc3d64219f842c06b9b8ae07b1532076269bd4753bf11e93ff59498337e35eb436f5c5a43028ba4027cd63b5d216febdeb6e0ec9208a435305c8a785f
+DIST tox-4.55.0.tar.gz 279415 BLAKE2B 11dda60b9cabd4829237c736bcb9772dd67fb0b3cd3ab5298c8c4ffd7a641430d2ad642a3fd74d8ccae96344b91cf73aeadf1b734b1bd61eb2284c0ba38c70eb SHA512 febc47e4eec439f60dbd26a996469923129aa079abc660f90e6f3da6f37aa1bc335970aea9cde5b7747cbf236acbfd54038aa9b97bba66603ce30c59dde0b39a
+DIST tox-4.55.0.tar.gz.provenance 9518 BLAKE2B 63757d88294e09a97b15c77315e567b10bbade87ce731051e2fa513adedf03d43df2fc135b635dfe378d292a5a6cdd81b4177b1d8bb6b7ee5bf5111856738899 SHA512 532bdf5719ce9ea6b11894af6043890289fc72e87d1c2476fc629c2ec8766f76e2444282ee6bb5f9160c20145571c079138e777629b6d026f3420a38f6602fd5
diff --git a/dev-python/tox/metadata.xml b/dev-python/tox/metadata.xml
index ea8988e8af6a..5fdbbc141076 100644
--- a/dev-python/tox/metadata.xml
+++ b/dev-python/tox/metadata.xml
@@ -6,6 +6,6 @@
   <name>Python</name>
  </maintainer>
  
- <origin>gentoo-staging</origin>
+ <origin>liguros-repo</origin>
  <stabilize-allarches/>
 </pkgmetadata>
\ No newline at end of file
diff --git a/dev-python/tox/tox-4.50.3.ebuild b/dev-python/tox/tox-4.50.3.ebuild
index 686a3e26e15f..3982eaaa1609 100644
--- a/dev-python/tox/tox-4.50.3.ebuild
+++ b/dev-python/tox/tox-4.50.3.ebuild
@@ -5,7 +5,7 @@ EAPI=8
 
 DISTUTILS_USE_PEP517=hatchling
 PYPI_VERIFY_REPO=https://github.com/tox-dev/tox
-PYTHON_COMPAT=( python3_{10..14} )
+PYTHON_COMPAT=( python3_{11..14} pypy3_11 )
 
 inherit distutils-r1 pypi
 
diff --git a/dev-python/tox/tox-4.53.1.ebuild b/dev-python/tox/tox-4.53.1.ebuild
index ceecbe35635f..555ad13d967d 100644
--- a/dev-python/tox/tox-4.53.1.ebuild
+++ b/dev-python/tox/tox-4.53.1.ebuild
@@ -5,7 +5,7 @@ EAPI=8
 
 DISTUTILS_USE_PEP517=hatchling
 PYPI_VERIFY_REPO=https://github.com/tox-dev/tox
-PYTHON_COMPAT=( python3_{10..14} )
+PYTHON_COMPAT=( python3_{11..14} pypy3_11 )
 
 inherit distutils-r1 pypi
 
diff --git a/dev-python/tox/tox-4.54.0.ebuild b/dev-python/tox/tox-4.54.0.ebuild
index 1ea7932f5f65..b15526c2f58a 100644
--- a/dev-python/tox/tox-4.54.0.ebuild
+++ b/dev-python/tox/tox-4.54.0.ebuild
@@ -5,7 +5,7 @@ EAPI=8
 
 DISTUTILS_USE_PEP517=hatchling
 PYPI_VERIFY_REPO=https://github.com/tox-dev/tox
-PYTHON_COMPAT=( python3_{10..14} )
+PYTHON_COMPAT=( python3_{11..14} pypy3_11 )
 
 inherit distutils-r1 pypi
 
@@ -18,7 +18,7 @@ HOMEPAGE="
 
 LICENSE="MIT"
 SLOT="0"
-KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ppc ~ppc64 ~riscv ~s390 ~x86"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~m68k ~ppc ~ppc64 ~riscv ~s390 ~x86"
 
 RDEPEND="
 	dev-python/cachetools[${PYTHON_USEDEP}]
diff --git a/dev-python/tox/tox-4.55.0.ebuild b/dev-python/tox/tox-4.55.0.ebuild
new file mode 100644
index 000000000000..b15526c2f58a
--- /dev/null
+++ b/dev-python/tox/tox-4.55.0.ebuild
@@ -0,0 +1,97 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYPI_VERIFY_REPO=https://github.com/tox-dev/tox
+PYTHON_COMPAT=( python3_{11..14} pypy3_11 )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="virtualenv-based automation of test activities"
+HOMEPAGE="
+	https://tox.readthedocs.io/
+	https://github.com/tox-dev/tox/
+	https://pypi.org/project/tox/
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~m68k ~ppc ~ppc64 ~riscv ~s390 ~x86"
+
+RDEPEND="
+	dev-python/cachetools[${PYTHON_USEDEP}]
+	dev-python/colorama[${PYTHON_USEDEP}]
+	dev-python/filelock[${PYTHON_USEDEP}]
+	dev-python/packaging[${PYTHON_USEDEP}]
+	dev-python/platformdirs[${PYTHON_USEDEP}]
+	dev-python/pluggy[${PYTHON_USEDEP}]
+	dev-python/pyproject-api[${PYTHON_USEDEP}]
+	dev-python/python-discovery[${PYTHON_USEDEP}]
+	dev-python/tomli-w[${PYTHON_USEDEP}]
+	dev-python/virtualenv[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	dev-python/docutils[${PYTHON_USEDEP}]
+	dev-python/hatch-vcs[${PYTHON_USEDEP}]
+	test? (
+		dev-python/argcomplete[${PYTHON_USEDEP}]
+		dev-python/build[${PYTHON_USEDEP}]
+		dev-python/distlib[${PYTHON_USEDEP}]
+		dev-python/psutil[${PYTHON_USEDEP}]
+		dev-python/re-assert[${PYTHON_USEDEP}]
+		$(python_gen_cond_dep '
+			dev-python/time-machine[${PYTHON_USEDEP}]
+		' 'python*')
+	)
+"
+
+EPYTEST_PLUGINS=( pytest-{mock,rerunfailures,timeout,xdist} )
+# xdist seems to mess up state between successive implementation runs
+distutils_enable_tests pytest
+
+src_prepare() {
+	# upstream lower bounds are meaningless
+	sed -i -e 's:>=[0-9.]*::' pyproject.toml || die
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	# devpi_process is not packaged, and has lots of dependencies
+	cat > "${T}"/devpi_process.py <<-EOF || die
+		def IndexServer(*args, **kwargs): raise NotImplementedError()
+	EOF
+
+	local -x PYTHONPATH=${T}:${PYTHONPATH}
+	local EPYTEST_DESELECT=(
+		# Internet
+		tests/tox_env/python/virtual_env/package/test_package_cmd_builder.py::test_build_wheel_external
+		tests/tox_env/python/virtual_env/package/test_package_cmd_builder.py::test_run_installpkg_targz
+		tests/tox_env/python/virtual_env/package/test_package_pyproject.py::test_pyproject_installpkg_pep517_envs
+		# require tombi
+		tests/session/cmd/test_schema.py::test_schema_tombi_lint
+	)
+	local EPYTEST_IGNORE=(
+		# requires devpi*
+		tests/test_provision.py
+	)
+
+	case ${EPYTHON} in
+		python*)
+			local EPYTEST_PLUGINS=( "${EPYTEST_PLUGINS[@]}" time-machine )
+			;;
+		pypy3*)
+			EPYTEST_DESELECT+=(
+				'tests/tox_env/python/pip/test_pip_install.py::test_constrain_package_deps[explicit-True-True]'
+				'tests/tox_env/python/pip/test_pip_install.py::test_constrain_package_deps[requirements-True-True]'
+				'tests/tox_env/python/pip/test_pip_install.py::test_constrain_package_deps[constraints-True-True]'
+				'tests/tox_env/python/pip/test_pip_install.py::test_constrain_package_deps[explicit+requirements-True-True]'
+				'tests/tox_env/python/pip/test_pip_install.py::test_constrain_package_deps[requirements_indirect-True-True]'
+				'tests/tox_env/python/pip/test_pip_install.py::test_constrain_package_deps[requirements_constraints_indirect-True-True]'
+			)
+			;;
+	esac
+
+	epytest -o addopts=
+}