Adding metadata

3 files changed, 1 insertions, 132 deletions

diff --git a/dev-python/translate-toolkit/Manifest b/dev-python/translate-toolkit/Manifest
index 18066ea865ff..1533c1c1bf06 100644
--- a/dev-python/translate-toolkit/Manifest
+++ b/dev-python/translate-toolkit/Manifest
@@ -1,4 +1,3 @@
-DIST translate-3.19.3.gh.tar.gz 1297097 BLAKE2B 4dad6f730ad441cb709990a12eebfc38d98b805c469f07b5eafb46f85aee7c58572d449e1325a7f0f7b438288ad290136ee07b1b8acac5680a7f8a5707a7ad0e SHA512 36c2308bbe8c512bf72bf4a8d29129cf096f514c5c78f9c464183130ec287b70dc0cc79d95e73082e1c978af2e335ac48159cb0fca861a0555a320e82128275d
 DIST translate-3.19.4.gh.tar.gz 1312664 BLAKE2B 90da92402354a10bb68701781bd2572aa8461aa858840badbbdc866da8ddc600006b9d22e177f5f3ce68a5eaec14f38373f6c13c758d84f208da71a97885161d SHA512 e4fbf1276205452782f798b1f57fb2acb57fc1d92246a032e2912def53db1764121a6a0ddff9a9237a21f9bb1fad274129133517ec28e8d26add592ac7b4ebcc
 DIST translate-3.19.5.gh.tar.gz 1320567 BLAKE2B ea27702656b25423fa71f0624d68a82d75ba8a4bb334846f3dfa2f4448ead68987ad6ff15a7cd1c74f6199ecf14c80e9d3d7b50b914f74756848ed37a6974ed3 SHA512 92a5d65217ff15cee3753071cd78b218c6492049752b395fc841799c71eea056027515455b65565b2d22f1eba7305bc0d5ee453cd7995d52fa7f88f0d3fe7876
 DIST translate-3.19.6.gh.tar.gz 1327150 BLAKE2B a1337276a2a15a7d522e86def20df4137fec8f566df8ca1ec945b12e627a4ebf78aaace4266ef1ef00dca5ac30b3767dea0a1dcd79d3fe8bb8b5cf74dcff1117 SHA512 c21c563e530fe3550c1e5d97f30cb861f47bcde867547a07aaa992fe8721ad20fa18a2a2227fccd2b458cf14a2788137176a1eff5b11f4cfbc4f5cbdfdfc7729
diff --git a/dev-python/translate-toolkit/translate-toolkit-3.19.3.ebuild b/dev-python/translate-toolkit/translate-toolkit-3.19.3.ebuild
deleted file mode 100644
index dfea10007db7..000000000000
--- a/dev-python/translate-toolkit/translate-toolkit-3.19.3.ebuild
+++ /dev/null
@@ -1,130 +0,0 @@
-# Copyright 1999-2026 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-DISTUTILS_USE_PEP517=setuptools
-PYTHON_COMPAT=( python3_{10..14} )
-PYTHON_REQ_USE="sqlite"
-
-inherit distutils-r1
-
-MY_P=translate-${PV}
-DESCRIPTION="Toolkit to convert between many translation formats"
-HOMEPAGE="
-	https://github.com/translate/translate/
-	https://pypi.org/project/translate-toolkit/
-"
-SRC_URI="
-	https://github.com/translate/translate/archive/${PV}.tar.gz
-		-> ${MY_P}.gh.tar.gz
-"
-S="${WORKDIR}"/${MY_P}
-
-LICENSE="GPL-2"
-SLOT="0"
-KEYWORDS="amd64 arm64"
-IUSE="+html +ical +ini +subtitles +yaml"
-
-RDEPEND="
-	app-text/iso-codes
-	>=dev-python/chardet-3.0.4[${PYTHON_USEDEP}]
-	dev-python/cheroot[${PYTHON_USEDEP}]
-	>=dev-python/levenshtein-0.12.0[${PYTHON_USEDEP}]
-	>=dev-python/lxml-5.2.0[${PYTHON_USEDEP}]
-	>=dev-python/mistletoe-1.1.0[${PYTHON_USEDEP}]
-	>=dev-python/pyparsing-3[${PYTHON_USEDEP}]
-	dev-python/ruamel-yaml[${PYTHON_USEDEP}]
-	dev-python/tomlkit[${PYTHON_USEDEP}]
-	>=dev-python/unicode-segmentation-rs-0.2.0[${PYTHON_USEDEP}]
-	>=dev-python/wcwidth-0.2.14[${PYTHON_USEDEP}]
-	sys-devel/gettext
-	html? ( dev-python/utidylib[${PYTHON_USEDEP}] )
-	ical? ( dev-python/vobject[${PYTHON_USEDEP}] )
-	ini? ( >=dev-python/iniparse-0.5[${PYTHON_USEDEP}] )
-	subtitles? ( media-video/gaupol[${PYTHON_USEDEP}] )
-	yaml? ( dev-python/pyyaml[${PYTHON_USEDEP}] )
-"
-# Technically, the test suite also has undeclared dependency
-# on dev-python/snapshottest but all the tests using it are broken
-# anyway, so we skip them.
-BDEPEND="
-	test? (
-		dev-python/phply[${PYTHON_USEDEP}]
-	)
-"
-
-EPYTEST_PLUGINS=()
-EPYTEST_XDIST=1
-distutils_enable_tests pytest
-
-src_prepare() {
-	distutils-r1_src_prepare
-
-	# strip unnecessary pins
-	sed -i -e 's:,<[0-9.]*::' pyproject.toml || die
-}
-
-src_test() {
-	# unfortunately, this bad quality package doesn't support XDG_DATA_DIRS
-	# correctly, so we need to reassemble all data files in a single directory
-	local -x XDG_DATA_HOME=${T}/share
-	cp -r translate/share "${T}/" || die
-	cp -r "${ESYSROOT}"/usr/share/gaupol "${XDG_DATA_HOME}"/ || die
-
-	distutils-r1_src_test
-}
-
-python_test() {
-	local EPYTEST_DESELECT=(
-		# Fails with network-sandbox (and even with it off but w/ softer fail)
-		'tests/xliff_conformance/test_xliff_conformance.py::test_open_office_to_xliff'
-		'tests/xliff_conformance/test_xliff_conformance.py::test_po_to_xliff'
-		# all tests based on snapshottest are broken and I'm too tired
-		# to figure this out
-		tests/translate/tools/test_pocount.py::test_{cases,output}
-		tests/translate/tools/test_junitmsgfmt.py::test_output
-	)
-	local EPYTEST_IGNORE=(
-		# unpackaged fluent.*
-		tests/translate/storage/test_fluent.py
-		tests/translate/convert/test_fluent2po.py
-		# changes directory and does not change it back, sigh
-		tests/odf_xliff/test_odf_xliff.py
-	)
-
-	if ! has_version "dev-python/iniparse[${PYTHON_USEDEP}]"; then
-		EPYTEST_IGNORE+=(
-			translate/convert/test_ini2po.py
-			translate/convert/test_po2ini.py
-		)
-	fi
-
-	if ! has_version "media-video/gaupol[${PYTHON_USEDEP}]"; then
-		EPYTEST_IGNORE+=(
-			translate/storage/test_subtitles.py
-		)
-	fi
-
-	epytest
-}
-
-python_install_all() {
-	distutils-r1_python_install_all
-
-	insinto /usr
-	doins -r translate/share
-
-	if ! use html; then
-		rm "${ED}"/usr/bin/{html2po,po2html} || die
-	fi
-	if ! use ical; then
-		rm "${ED}"/usr/bin/{ical2po,po2ical} || die
-	fi
-	if ! use ini; then
-		rm "${ED}"/usr/bin/{ini2po,po2ini} || die
-	fi
-	if ! use subtitles; then
-		rm "${ED}"/usr/bin/{sub2po,po2sub} || die
-	fi
-}
diff --git a/dev-python/translate-toolkit/translate-toolkit-3.19.4.ebuild b/dev-python/translate-toolkit/translate-toolkit-3.19.4.ebuild
index 74f9adb4cf7c..dfea10007db7 100644
--- a/dev-python/translate-toolkit/translate-toolkit-3.19.4.ebuild
+++ b/dev-python/translate-toolkit/translate-toolkit-3.19.4.ebuild
@@ -23,7 +23,7 @@ S="${WORKDIR}"/${MY_P}
 
 LICENSE="GPL-2"
 SLOT="0"
-KEYWORDS="~amd64 ~arm64"
+KEYWORDS="amd64 arm64"
 IUSE="+html +ical +ini +subtitles +yaml"
 
 RDEPEND="