Publish srcux candidate 0000000623-20261010-204610

1 files changed, 50 insertions, 0 deletions

diff --git a/dev-python/wcmatch/wcmatch-11.1.ebuild b/dev-python/wcmatch/wcmatch-11.1.ebuild
new file mode 100644
index 000000000000..920e5350faaf
--- /dev/null
+++ b/dev-python/wcmatch/wcmatch-11.1.ebuild
@@ -0,0 +1,50 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{13..14} )
+DISTUTILS_USE_PEP517=hatchling
+
+inherit distutils-r1
+
+DESCRIPTION="Wildcard/glob file name matcher"
+HOMEPAGE="
+	https://github.com/facelessuser/wcmatch/
+	https://pypi.org/project/wcmatch/
+"
+SRC_URI="
+	https://github.com/facelessuser/wcmatch/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~x86"
+
+RDEPEND="
+	>=dev-python/bracex-3.0[${PYTHON_USEDEP}]
+"
+
+BDEPEND="
+	test? (
+		dev-vcs/git
+	)
+"
+
+EPYTEST_PLUGINS=()
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	# tests require some files in homedir
+	> "${HOME}"/test1.txt || die
+	> "${HOME}"/test2.txt || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	# https://github.com/python/cpython/issues/155823
+	local -x PYTHON_JIT=0
+	epytest
+}