Publish srcux candidate 0000000652-20261014-030308HEADdevelop

1 files changed, 40 insertions, 0 deletions

diff --git a/dev-python/wrapt/wrapt-2.5.1.ebuild b/dev-python/wrapt/wrapt-2.5.1.ebuild
new file mode 100644
index 000000000000..c0b172cb4e24
--- /dev/null
+++ b/dev-python/wrapt/wrapt-2.5.1.ebuild
@@ -0,0 +1,40 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=setuptools
+PYPI_VERIFY_REPO=https://github.com/GrahamDumpleton/wrapt
+PYTHON_COMPAT=( python3_{13..14} )
+
+inherit distutils-r1 pypi
+
+MY_P=${P/_}
+DESCRIPTION="Module for decorators, wrappers and monkey patching"
+HOMEPAGE="
+	https://github.com/GrahamDumpleton/wrapt/
+	https://pypi.org/project/wrapt/
+"
+
+LICENSE="BSD"
+SLOT="0"
+if [[ ${PV} != *_rc* ]]; then
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~x64-macos"
+fi
+IUSE="+native-extensions"
+
+EPYTEST_PLUGINS=()
+distutils_enable_tests pytest
+
+src_prepare() {
+	distutils-r1_src_prepare
+
+	# skip mypy tests, they are fragile
+	rm -r tests/mypy || die
+}
+
+python_compile() {
+	local -x WRAPT_INSTALL_EXTENSIONS=$(usex native-extensions true false)
+	distutils-r1_python_compile
+}