Adding metadata

27 files changed, 585 insertions, 43 deletions

diff --git a/dev-python/astroid/Manifest b/dev-python/astroid/Manifest
index b9a39dec945d..2bb9ca592daa 100644
--- a/dev-python/astroid/Manifest
+++ b/dev-python/astroid/Manifest
@@ -1,3 +1,4 @@
 DIST astroid-2.10.0.tar.gz 417686 BLAKE2B a4aa0451134403abf8e56ccd9dae106d2a92b2bd53c6772c952984ea5603b44ef5c13b9822b4fda0a146ad96a7412a602c2c46313938dea30cfb390fc55ee54d SHA512 34b52cd2e6636009369ec55a5781caaf8e8b0766b7ba4e70ff1f55d275a673266e0293f65145ff38637d6da353679314d0fbf182416146b89e210a68e39d86f0
 DIST astroid-2.11.0.tar.gz 412098 BLAKE2B 022c940913ae71ca0280a2ae47c19a6c82ea69b4f2a1c1ce0e2f00dac7a37b26f7ee2fa798db4f5d230e021ac5096b79d48b12d389d0c754dc17bde301c1712f SHA512 82423c9cf6da4e041621218acc81b9a301e4c1f532a74863c89040654d61457a89481004556a4795f021f0fc52b5f79412a35e9e43a1de33189dcae305cefdff
+DIST astroid-2.11.1.tar.gz 412506 BLAKE2B d3153b9019d5c466d39f7b27d459158cabe47cc9375afe2f1362b20620847fed0b4b09e2994e4372712fbd5bdff3cf88f709c1644abd25bdb6085e93cdcb145f SHA512 e0a1cfc67602e53c8d5b67d1605b38ee5c62886cb0ca757f0835f8af2ad94b21af58427ed4aad9f98171955733c4b333443efb1f7fdcec661d1e68c403a529b1
 DIST astroid-2.9.3.tar.gz 409069 BLAKE2B 152dbe8ab2fee3964dc8cc714a5ba48c71b5994c77d1e20683bcf028483aca22d5be5772e72d056cfd3d1f59562b447366d61fc35a2b67d545f069a8f7975e84 SHA512 7bb3bf2d456c0d22325444e641961c34eaddcddf50c97ee9f5b5c8755232cf1b65a315258403b40bb7dcad15c4f9b6b73ab0eb607525a48a65f52406969eca04
diff --git a/dev-python/astroid/astroid-2.11.1.ebuild b/dev-python/astroid/astroid-2.11.1.ebuild
new file mode 100644
index 000000000000..57f7c91c8afa
--- /dev/null
+++ b/dev-python/astroid/astroid-2.11.1.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} )
+
+inherit distutils-r1
+
+DESCRIPTION="Abstract Syntax Tree for logilab packages"
+HOMEPAGE="
+	https://github.com/PyCQA/astroid/
+	https://pypi.org/project/astroid/"
+SRC_URI="
+	https://github.com/PyCQA/astroid/archive/v${PV}.tar.gz
+		-> ${P}.tar.gz
+"
+
+LICENSE="LGPL-2.1+"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+# Version specified in __pkginfo__.py.
+RDEPEND="
+	>=dev-python/lazy-object-proxy-1.4.0[${PYTHON_USEDEP}]
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	>=dev-python/typing-extensions-3.10[${PYTHON_USEDEP}]
+	<dev-python/wrapt-2[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	dev-python/setuptools_scm[${PYTHON_USEDEP}]
+	test? (
+		dev-python/nose[${PYTHON_USEDEP}]
+		dev-python/numpy[${PYTHON_USEDEP}]
+		dev-python/python-dateutil[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+export SETUPTOOLS_SCM_PRETEND_VERSION=${PV}
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# no clue why it's broken
+		tests/unittest_modutils.py::GetModulePartTest::test_known_values_get_builtin_module_part
+		tests/unittest_brain_dataclasses.py::test_pydantic_field
+	)
+
+	# Faker causes sys.path_importer_cache keys to be overwritten
+	# with PosixPaths
+	epytest -p no:faker
+}
diff --git a/dev-python/aws-sam-translator/Manifest b/dev-python/aws-sam-translator/Manifest
index e884ba8f3bc9..bce6707bb990 100644
--- a/dev-python/aws-sam-translator/Manifest
+++ b/dev-python/aws-sam-translator/Manifest
@@ -1,2 +1,3 @@
 DIST aws-sam-translator-1.40.0.tar.gz 988864 BLAKE2B 5a414bde5ceeb016267c64742e8c8dabf1460471261a84464ab2bffa4b5553eb042ffe2b4ac91b470316f64a68043e27f652b2cc5aabc8a83cf61faa89d7af51 SHA512 99c578cbe4100c30d2e6357dbb35aaf9e93180b8fce27f1b8400253153fef7d18487b5f67e0824920c6adb8bfdfe763a8fd893b3ac4ef3f781673f4761866e0e
 DIST aws-sam-translator-1.42.0.tar.gz 1017720 BLAKE2B d0166b09b99c64f5f4a4c1ebfe63b6a35ca6db73efb97f76b8748272b646fe2fcf9de06c2f6b29ce69a3edfce9235ba932913055e70f48d88569e4df25a6be0e SHA512 6b1bfd4bde203e31a9d98a385d6c0705ba651c39846358e750faf8a30c4e4e8b2ee57623af27da670ee8f1f5edca795b1b5528b5237ff9f01f911d4b9385ebcd
+DIST aws-sam-translator-1.43.0.tar.gz 1046840 BLAKE2B 19e405a07c9eb42ee77f26986eb09e6902559fc3fad5f1b7f4df0d09cb529add1c53910afa3fa3d867f048e69fb4c6872004733fc611347d4438013b80605e5c SHA512 9e7a5b4769eafcf1a9d8af7582cd4af3a82843d2c7c474495b9099fcb94f8dd0dd45d02f52ed609de7dc341b77f0f913526410935244836c3201b99c3fb6a292
diff --git a/dev-python/aws-sam-translator/aws-sam-translator-1.43.0.ebuild b/dev-python/aws-sam-translator/aws-sam-translator-1.43.0.ebuild
new file mode 100644
index 000000000000..8d673ecf7a8a
--- /dev/null
+++ b/dev-python/aws-sam-translator/aws-sam-translator-1.43.0.ebuild
@@ -0,0 +1,55 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} )
+
+inherit distutils-r1
+
+DESCRIPTION="A library that transform SAM templates into AWS CloudFormation templates"
+HOMEPAGE="
+	https://github.com/aws/serverless-application-model/
+	https://pypi.org/project/aws-sam-translator/
+"
+SRC_URI="
+	https://github.com/aws/serverless-application-model/archive/v${PV}.tar.gz
+		-> ${P}.tar.gz
+"
+S="${WORKDIR}/serverless-application-model-${PV}"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~riscv ~x86 ~amd64-linux ~x86-linux"
+
+RDEPEND="
+	>=dev-python/boto3-1.17[${PYTHON_USEDEP}]
+	>=dev-python/jsonschema-2.6[${PYTHON_USEDEP}]
+	>=dev-python/six-1.11[${PYTHON_USEDEP}]
+	dev-python/pyyaml[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/mock[${PYTHON_USEDEP}]
+		dev-python/parameterized[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+EPYTEST_DESELECT=(
+	tests/validator/test_validator_api.py::TestValidatorApi::test_errors_13_error_definitionuri
+	tests/unit/test_region_configuration.py::TestRegionConfiguration::test_is_service_supported_positive_4_ec2
+)
+
+python_prepare_all() {
+	# remove pytest-cov dependency
+	sed -r -e 's:--cov(-[[:graph:]]+|)[[:space:]]+[[:graph:]]+::g' \
+		-i pytest.ini || die
+
+	# deps are installed by ebuild, don't try to reinstall them via pip
+	truncate --size=0 requirements/*.txt || die
+
+	distutils-r1_python_prepare_all
+}
diff --git a/dev-python/boto3/Manifest b/dev-python/boto3/Manifest
index b5c6539da389..2fc7ace275fe 100644
--- a/dev-python/boto3/Manifest
+++ b/dev-python/boto3/Manifest
@@ -6,4 +6,5 @@ DIST boto3-1.21.20.tar.gz 478803 BLAKE2B a10b40e73b40933de94b6b33dfb76588cc7f614
 DIST boto3-1.21.21.tar.gz 479513 BLAKE2B 98c67938b271dd7e5d99d06ba5fd046eead618243cd3c923b7857c3e1442b89fa08afa138360b4ed5e2c96254f0f7e657b53d5edc1e4baec3435c96048d6b3a4 SHA512 bacde2f5f2632ee9965e0dd4f85861efa32a31bdb8f4a2bc97d05c4ddd88f457b2e723521310020923951f13a122236cc95598c119ac20c4c8d38cddb6a8a29d
 DIST boto3-1.21.22.tar.gz 479768 BLAKE2B 3ae647a4c06cb9f7c4c32216dba439ce8bbf346fccf5a8651c08b398bcb7fdb0a4ac81c8d311625d0f50634b90c2f8a02160a19435db836ad05edf0d998a148d SHA512 583a49907339fdb8bb1deaec7683dad6bd0c2836a05cc317a8fc97a17e7b79fd114677fd6342cf6f96b1140bf1bcf9ca0fb1fd3af1c86600e6cfba5bbbf21ec2
 DIST boto3-1.21.23.tar.gz 480322 BLAKE2B cbe0e2df766d9bd44be48d0c3304c0883dbdce93ed0ba23d7158b3ae82079b77ccb5a9f017aed89505e87e7b3df32fbe685a9d2dab0aa9174d477052b6e35781 SHA512 cb5d90012809f086f7384b181baff028d87fd25bfc2e4066d86721a3aa25c2d44c32f35ad40136fccf3a1cbf43d9524eb805f871664eb8ef74a805a92dcbf9e9
+DIST boto3-1.21.24.tar.gz 481309 BLAKE2B 964010995c28cf185ae03cbbbdaa5a86b5ff855de0e0dfb82aa7a835a3385fa3e53d5343ddaa8a01b6ba28d78d165d6263418b34b2c9edbea0040f553c088fd0 SHA512 18b5c212bc095cfccdfbc38788f5401de60fd9dc0a2c7a6179147b90a3c660d247ce77dd138ffc34382af6d834d6b51be5280d51e45b1f0ac917023f397cea7b
 DIST boto3-1.21.8.tar.gz 473069 BLAKE2B f08f76fb9c4e56e6ba5624c885973599505769d7f9eea6e20a06e1a641768b1f7b108fc7293282a55bf4c7d2b62eb34853f46b8c3ada9afb8fc25624daa60c12 SHA512 23ed88dcaefe3224db05959251befaae4f03859bf00daf649db1e838e5fb92e01a6da4bee8083366d804404aac358df19d7e4552d6aaf39f9c4b371ccc7f9088
diff --git a/dev-python/boto3/boto3-1.21.24.ebuild b/dev-python/boto3/boto3-1.21.24.ebuild
new file mode 100644
index 000000000000..80278b309f54
--- /dev/null
+++ b/dev-python/boto3/boto3-1.21.24.ebuild
@@ -0,0 +1,63 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} )
+
+inherit distutils-r1 multiprocessing
+
+DESCRIPTION="The AWS SDK for Python"
+HOMEPAGE="https://github.com/boto/boto3"
+LICENSE="Apache-2.0"
+SLOT="0"
+
+if [[ "${PV}" == "9999" ]]; then
+	EGIT_REPO_URI="https://github.com/boto/boto3"
+	inherit git-r3
+	BOTOCORE_PV=${PV}
+else
+	SRC_URI="https://github.com/boto/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux"
+
+	# botocore is x.(y+3).z
+	BOTOCORE_PV="$(ver_cut 1).$(( $(ver_cut 2) + 3)).$(ver_cut 3-)"
+fi
+
+RDEPEND="
+	>=dev-python/botocore-${BOTOCORE_PV}[${PYTHON_USEDEP}]
+	>=dev-python/jmespath-0.7.1[${PYTHON_USEDEP}]
+	>=dev-python/s3transfer-0.3.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/mock[${PYTHON_USEDEP}]
+		dev-python/pytest-xdist[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_sphinx docs/source \
+	'dev-python/guzzle_sphinx_theme'
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	# don't lock versions to narrow ranges
+	sed -e '/botocore/ d' \
+		-e '/jmespath/ d' \
+		-e '/s3transfer/ d' \
+		-i setup.py || die
+
+	# do not rely on bundled deps in botocore (sic!)
+	find -name '*.py' -exec sed -i \
+		-e 's:from botocore[.]vendored import:import:' \
+		-e 's:from botocore[.]vendored[.]:from :' \
+		{} + || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	epytest tests/{functional,unit} \
+		-n "$(makeopts_jobs "${MAKEOPTS}" "$(get_nproc)")"
+}
diff --git a/dev-python/botocore/Manifest b/dev-python/botocore/Manifest
index c307c2e31295..5429d906f551 100644
--- a/dev-python/botocore/Manifest
+++ b/dev-python/botocore/Manifest
@@ -6,4 +6,5 @@ DIST botocore-1.24.20.tar.gz 8826541 BLAKE2B 8661c7057d64905972062761a567e885077
 DIST botocore-1.24.21.tar.gz 8837199 BLAKE2B 34b321900ff52b5d8fbde87160745243fedff5ad74930c428814c86ad713a367fd036aeb3ee74267420d2c39860327b39d604ddad208fc09008be30b8aac7b62 SHA512 6b5a5011501c81b3fc616c94c1dc1c673dd2a6d3c1f40638aa36a27131876e9bf64f736c9536606b9817079b33013fd62474b685bea4088d949bd6a225c7f247
 DIST botocore-1.24.22.tar.gz 8839717 BLAKE2B 7b3843900da913561ab2a99f7371139cd8fd89a2eb52a90b33f8fb4c0449ff23a00f56347a2916b271346acf2c0721af0a9695bff3663888aa87c790705ce4c3 SHA512 070222b5eca46fa5463620af63816bc8813c717a56b4c41294556130390959ac14570a1256542f145a5b36727ced9657b386fcd5f538d64912c8a9f049673bd6
 DIST botocore-1.24.23.tar.gz 8842041 BLAKE2B 0e1bf7001fc09d165fa652406815bc5fc7d6055967d4975c9d28b4abc9841fb761af65fe6a38ed9e0d81e7d846e74e3717103debad4d69c62bd41125371b4d4f SHA512 5bd77d0f0db0da5037711e4a61362bbd48512b8f785ce104690b1275608a59594d9f64b878777081f21b0f6a6b22b19f12cb7a068c4d1e0a1b044d5146acf888
+DIST botocore-1.24.24.tar.gz 8842777 BLAKE2B 36ef7f82a15b3e9a3babcc6e68efd6e57f3a54d69bc4e281ecb2693053663fdb6ca7a2844b65447ca0ea4d61af9354024691a187d45f20da552b36783316781c SHA512 e9e0c5723eba2f29e5c06ce6530176db2a13bc2edd9d4f08d7c72a4b865bedd3045875417e07e9252fd9cff8d1c1c45bf0270534494482b1588bc13da253376a
 DIST botocore-1.24.8.tar.gz 8798121 BLAKE2B 4ca37ed7be0af62901bf154f75739cc7e07505a809e551884c72d5b5eed334fff1111fc6db016df522564a1f3d9b6f258e8eca96161a734711340bf880b553b5 SHA512 6ac2139694ab199313a0fb9a2f783b12de7f3915d10cba739f4758356a3b84a917c3c394954b6d82d7a62de907c6fe57a3559e2b9a625bb0479e7bacd31d21cc
diff --git a/dev-python/botocore/botocore-1.24.24.ebuild b/dev-python/botocore/botocore-1.24.24.ebuild
new file mode 100644
index 000000000000..5fe8ae8c2f96
--- /dev/null
+++ b/dev-python/botocore/botocore-1.24.24.ebuild
@@ -0,0 +1,68 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} )
+
+inherit distutils-r1 multiprocessing
+
+DESCRIPTION="Low-level, data-driven core of boto 3"
+HOMEPAGE="https://github.com/boto/botocore"
+LICENSE="Apache-2.0"
+SLOT="0"
+
+if [[ "${PV}" == "9999" ]]; then
+	EGIT_REPO_URI="https://github.com/boto/botocore"
+	inherit git-r3
+else
+	SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux"
+fi
+
+RDEPEND="
+	dev-python/six[${PYTHON_USEDEP}]
+	<dev-python/jmespath-2[${PYTHON_USEDEP}]
+	dev-python/python-dateutil[${PYTHON_USEDEP}]
+	>=dev-python/urllib3-1.25.4[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/jsonschema[${PYTHON_USEDEP}]
+		dev-python/pytest-xdist[${PYTHON_USEDEP}]
+	)
+"
+
+PATCHES=(
+	"${FILESDIR}/1.8.6-tests-pass-all-env-vars-to-cmd-runner.patch"
+)
+
+distutils_enable_sphinx docs/source \
+	'dev-python/guzzle_sphinx_theme'
+distutils_enable_tests pytest
+
+src_prepare() {
+	# unpin deps
+	sed -i -e "s:>=.*':':" setup.py || die
+
+	# unbundle deps
+	rm -r botocore/vendored || die
+	find -name '*.py' -exec sed -i \
+		-e 's:from botocore[.]vendored import:import:' \
+		-e 's:from botocore[.]vendored[.]:from :' \
+		{} + || die
+
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# rely on bundled six
+		tests/functional/test_six_imports.py::test_no_bare_six_imports
+		tests/functional/test_six_threading.py::test_six_thread_safety
+	)
+
+	epytest tests/{functional,unit} \
+		-n "$(makeopts_jobs "${MAKEOPTS}" "$(get_nproc)")"
+}
diff --git a/dev-python/fonttools/Manifest b/dev-python/fonttools/Manifest
index 71bce616400c..0a2fba302a03 100644
--- a/dev-python/fonttools/Manifest
+++ b/dev-python/fonttools/Manifest
@@ -1,3 +1,4 @@
 DIST fonttools-4.29.1.tar.gz 2954962 BLAKE2B e78a55e240975e12e9cfd56368eab0d18e104211d8416db833a20208c78f6e5dbce2d24d7338017882f0bd1c3c181c0af0c069025a750cba4e9f41c1b4b2489c SHA512 36f4272be18d19748069289bfb3d3339cf0b16967a12976971f9e2dd56a1e915d3176e0dd9cad08cee69b20f3d6ac1a966365d936bb091b39e23b6c693e28dc9
 DIST fonttools-4.30.0.tar.gz 2961097 BLAKE2B 23b592daa16fd215688f149d99258209b819caa843d26c889fb4016aae6d6614a9f87dd13fa1d2aa254fadb5169cf7d57ba02b7b15af79611995148d698ca2ec SHA512 2b4e676f956c3456bf3ca435a7d80e1a0a9f36872ba3a820072d1e13ed5751a8546f424369731afd4ccddc298ec0658bb4384d2e18670b108dd1b3a99fc205f4
 DIST fonttools-4.31.1.tar.gz 2964489 BLAKE2B d1bb7059383785dd527f7276ef876042f81d3e2cc5acc1b69e111b540cf8d35273a0070e6f0602ca438f35e3b83d0a04736cd5c97b1b7669822d1a6b1ad1b487 SHA512 cdf70f376e690ab1edc5e761ba45d1ddd7760c3aefdb5e9b88cc97118edd4ff694789c8b79ece791b4b6a597dcac1abb0eec5f0634f1db0792e5e62a2137282d
+DIST fonttools-4.31.2.tar.gz 2965796 BLAKE2B d776073e7a9358e67b8753dd4557e2b1b4c44d9662c8c728abe42d970bca1db1789a655df8865fef39eed3a32271749d2cb772e306f34efc87e737b7384c0b5d SHA512 50cc8bca9136675a413ac947b583f694d512872127cee129a78505d0259fe1cf6922f806558761af982758f72c7d95e1245b8de55b6ebd6ddd3bd7506d41abcf
diff --git a/dev-python/fonttools/fonttools-4.31.2.ebuild b/dev-python/fonttools/fonttools-4.31.2.ebuild
new file mode 100644
index 000000000000..0597adaf64a8
--- /dev/null
+++ b/dev-python/fonttools/fonttools-4.31.2.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} )
+PYTHON_REQ_USE="xml(+)"
+
+inherit distutils-r1 virtualx
+
+DESCRIPTION="Library for manipulating TrueType, OpenType, AFM and Type1 fonts"
+HOMEPAGE="https://github.com/fonttools/fonttools/"
+SRC_URI="https://github.com/fonttools/fonttools/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~ppc ~ppc64 ~riscv ~sparc ~x86 ~x64-macos"
+
+RDEPEND=">=dev-python/fs-2.4.9[${PYTHON_USEDEP}]"
+BDEPEND="${RDEPEND}
+	dev-python/cython[${PYTHON_USEDEP}]
+	test? (
+		app-arch/brotli[python,${PYTHON_USEDEP}]
+		app-arch/zopfli
+	)
+"
+
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	# When dev-python/pytest-shutil is installed, we get weird import errors.
+	# This is due to incomplete nesting in the Tests/ tree:
+	#
+	#   Tests/feaLib/__init__.py
+	#   Tests/ufoLib/__init__.py
+	#   Tests/svgLib/path/__init__.py
+	#   Tests/otlLib/__init__.py
+	#   Tests/varLib/__init__.py
+	#
+	# This tree requires an __init__.py in Tests/svgLib/ too, bug #701148.
+	touch Tests/svgLib/__init__.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+src_configure() {
+	export FONTTOOLS_WITH_CYTHON=1
+}
+
+src_test() {
+	# virtualx used when matplotlib is installed causing plot module tests to run
+	virtx distutils-r1_src_test
+}
+
+python_test() {
+	epytest Tests fontTools || die "Tests failed with ${EPYTHON}"
+}
diff --git a/dev-python/google-api-python-client/Manifest b/dev-python/google-api-python-client/Manifest
index 987e7c7d50fd..acf4ffd522ef 100644
--- a/dev-python/google-api-python-client/Manifest
+++ b/dev-python/google-api-python-client/Manifest
@@ -2,3 +2,4 @@ DIST google-api-python-client-2.37.0.tar.gz 28868090 BLAKE2B 971fa3a873c902a34c1
 DIST google-api-python-client-2.38.0.tar.gz 29194978 BLAKE2B 741cf925256f0bd648e68c339233cfc13a9eaa12e123e202eab64b8389bc493755838c3da8ca4e7f4ffeecacec783c41f37df1847edf0fb54387d58163c112fc SHA512 b93f1f946ebab226b9fdd9012c3ae70563197a895d9069f09c7eb8926cd8fe5567535d3677a6824f66720b9ed1f0a732f02be9440dc800a13cb7e335728a3ce8
 DIST google-api-python-client-2.40.0.tar.gz 29463380 BLAKE2B f70067d3afe614e34cf84480d7a653620b516689560033cf3ad72a963e53c76632d1254ed1ac5f492e9e4639a6d717889f0f84c283363892efa99ce1007bbb82 SHA512 ae345d46bcb13509dd631039079c3ef96899899c206bc19b47a873d8ebc9372e70f55bcada1c8ba9775d826dbe8b1fde96a8f496f5574bb15b3c73c7d848f189
 DIST google-api-python-client-2.41.0.tar.gz 29608471 BLAKE2B 5a6f9eb414f02b9528d0ee8f8777da6596bd298f6aea8191966d1ebaa67219f8ea2e44a77bc667bfedab39c4ab0352a13ba04fd805f0df9a6936247cd4cf3481 SHA512 b9ee6a4374438d019d0efd09d02426c1c773fd2ca561e2bf91e426535fec2865a47a32cc5cf780e5e7da193ca3d8b5677339fee2a4983e7f4af9612d901c883d
+DIST google-api-python-client-2.42.0.tar.gz 29772877 BLAKE2B f478a719c3a6ef2f78d1fa16c231d47f2d72b55e67746612579f644b92dbd93ebd7f320f0684d85c1c1e253ed2f5163d7f6ce2904343bbe7a4f6746889663970 SHA512 e55cd75dec478a3410829a7eb7ee5478b52b44450d4ade69e3a7ee11b30e5ab5690c93ff6444f4b723db6cd1f26ac70553b3f1b9c77dc0b428db271b773faa9f
diff --git a/dev-python/google-api-python-client/google-api-python-client-2.42.0.ebuild b/dev-python/google-api-python-client/google-api-python-client-2.42.0.ebuild
new file mode 100644
index 000000000000..a609ec488769
--- /dev/null
+++ b/dev-python/google-api-python-client/google-api-python-client-2.42.0.ebuild
@@ -0,0 +1,47 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} )
+
+inherit distutils-r1
+
+DESCRIPTION="Google API Client for Python"
+HOMEPAGE="https://github.com/googleapis/google-api-python-client"
+SRC_URI="https://github.com/googleapis/google-api-python-client/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+
+RDEPEND="
+	>=dev-python/httplib2-0.15[${PYTHON_USEDEP}]
+	<dev-python/httplib2-1[${PYTHON_USEDEP}]
+	>=dev-python/google-api-core-2.3.1[${PYTHON_USEDEP}]
+	>=dev-python/google-auth-1.35.0[${PYTHON_USEDEP}]
+	>=dev-python/google-auth-httplib2-0.1.0[${PYTHON_USEDEP}]
+	>=dev-python/uritemplate-3.0.0[${PYTHON_USEDEP}]
+	<dev-python/uritemplate-5[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/mock[${PYTHON_USEDEP}]
+		dev-python/oauth2client[${PYTHON_USEDEP}]
+		dev-python/pandas[${PYTHON_USEDEP}]
+		dev-python/parameterized[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# require Internet access (and credentials)
+		tests/test_discovery.py::DiscoveryErrors::test_credentials_and_credentials_file_mutually_exclusive
+		tests/test_discovery.py::DiscoveryFromDocument::test_api_endpoint_override_from_client_options_mapping_object
+	)
+
+	epytest tests
+}
diff --git a/dev-python/line_profiler/Manifest b/dev-python/line_profiler/Manifest
index 44f1472cfacd..e445e7dd332a 100644
--- a/dev-python/line_profiler/Manifest
+++ b/dev-python/line_profiler/Manifest
@@ -1,2 +1,3 @@
 DIST line_profiler-3.3.1.gh.tar.gz 56700 BLAKE2B 030c0fc742a6773ebb55a54a3c21d3d5e5d6d5d258a2c3cd2071ff93917411b65e100bfc6549d9c60d9a7c361c53b291d8b81538acaf5b83665c04129d25bc02 SHA512 8a3704a6df2abe71283cb2da23b738932c6f4b42aedcdefda0d318fd4b894d56831a855c4be4430657308530a04d1e96b0e15a60edca06621bdd5370c0bf9911
 DIST line_profiler-3.4.0.gh.tar.gz 49076 BLAKE2B 1fa2d7462913b21b5c3d69be64492fd5002d10c6c454cb3129860e4156cf04fbbd839b140f229b586ff9f0b195baae435bc461c4bab1405c38da49bf348827c3 SHA512 79a6e71ec083aacbc95fab5e044a2a38119bced505e5b9720288e32103773dc64a8bbbf6c2c7913b7b5057420cb31c3943cc1dce2d7d029df82b6b59e451c357
+DIST line_profiler-3.5.0.gh.tar.gz 51142 BLAKE2B 1dade129a8913f6fe42fcd646c1f8850b5a948bad476755dd54bf04815e293508d77b9160157623a6060a864722c81466690722b79a603bba9b7651ba3e7e25d SHA512 4c797bb9990e77a5ef8cb38113fe28c4925a631ca8f034f33fe2aeeeb77bf9b24cfc1fb6217ddec07b767a2dec325f388e402ca38da43790f58c644a4a147a75
diff --git a/dev-python/line_profiler/line_profiler-3.5.0.ebuild b/dev-python/line_profiler/line_profiler-3.5.0.ebuild
new file mode 100644
index 000000000000..9af49b66fb5f
--- /dev/null
+++ b/dev-python/line_profiler/line_profiler-3.5.0.ebuild
@@ -0,0 +1,50 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} )
+# force it to match scikit-build
+CMAKE_MAKEFILE_GENERATOR=ninja
+
+inherit cmake distutils-r1
+
+DESCRIPTION="Line-by-line profiler"
+HOMEPAGE="
+	https://github.com/pyutils/line_profiler/
+"
+SRC_URI="
+	https://github.com/pyutils/line_profiler/archive/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+SLOT="0"
+LICENSE="BSD"
+KEYWORDS="~amd64 ~x86"
+
+RDEPEND="
+	dev-python/ipython[${PYTHON_USEDEP}]
+"
+# technically, the package claims to support non-scikit-build build
+# but it's clearly unmaintained and broken at the moment
+BDEPEND="
+	dev-python/cython[${PYTHON_USEDEP}]
+	dev-python/scikit-build[${PYTHON_USEDEP}]
+	test? (
+		dev-python/coverage[${PYTHON_USEDEP}]
+		dev-python/ubelt[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	cmake_src_prepare
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	cd tests || die
+	epytest
+}
diff --git a/dev-python/pulsectl/Manifest b/dev-python/pulsectl/Manifest
index fcfa8a505570..a2ead330b5f8 100644
--- a/dev-python/pulsectl/Manifest
+++ b/dev-python/pulsectl/Manifest
@@ -1,4 +1,2 @@
-DIST pulsectl-21.10.5.tar.gz 40769 BLAKE2B 8346717714b4e9fd017ca917388d2ddff9c7b5a5a74a33e03e3fd5fc02048ba3d1873fb1bd10a12410dc44d88c253a4afc71f1f2542e70f36f4985659fcd9fb5 SHA512 353af9d33bb6e9f070e46a934f0933935631ca5d254430ece8b9aa9a25dd31607a45718a45c71f35f2e3801c78d7eea18c5e34f69e5a983cfc0115a8fcd05334
-DIST pulsectl-22.1.0.tar.gz 40796 BLAKE2B a401500f3927fcc86db7132a9e76b31a8dd2144fb1cf6d62be30c6dc4648298f4ed378061b48dc4c64adb3a24d25810613024d6f652aa72b696f9b05605613a8 SHA512 b55ad512c9b7b11aa848465fe8cd556c76b5e10ebc7862aefc6b459cd4526ca1a0e284e81560b5e86d22acfa8409d09683043ca789c4f59f512a77cf2273cc7e
-DIST pulsectl-22.1.1.tar.gz 40813 BLAKE2B f5f5dd1bd958d9a053fa9da1aab7aa49680b7047641088fae9a110162e8be859de275dc79990366197c1be14e0c1e555cd2a37dc20f36ae5ad9bcff29babd1d5 SHA512 7676db1d1da3816d94a297b25613e44a02cd560a4c5495a25efb90f9fafb97e16844a5e36bc67457594afc6378860e57246cc5d07ab22aba328679c6ff1bfd8b
 DIST pulsectl-22.1.3.tar.gz 40899 BLAKE2B e0a3361ce9126afe9a79817165405c38638cd7b2328162750607d7c674431f0e57762f5aaa50ab17325d493b16a5370feaa836e6899cd91c64f299af008c8825 SHA512 cc60ca006518f8be327cf7aa0dccb4820b0891e7118989b31c968bd740134751033802dbe54e203c56cf6a5d541732684dd27128c14f753acc5de38b639bdf64
+DIST pulsectl-22.3.2.tar.gz 40901 BLAKE2B 5b3eb752865e95cfbb70a7228409fea70b4c55c7297d652b4614df7ea4764dcb446f7a3e25bb89f6a55badbf6b300381c7c28c56f0a47e7faf1e63003f39d02c SHA512 7fc11c792a9e586d191a32831e0ef8896c40da1fdeddfd4467d7ec352e5e0ef0c910d7a2e8e82e1a381b16afefa17c9c9db4821be74d4694c934337b2a862f0c
diff --git a/dev-python/pulsectl/pulsectl-21.10.5.ebuild b/dev-python/pulsectl/pulsectl-21.10.5.ebuild
deleted file mode 100644
index eccec9b75e17..000000000000
--- a/dev-python/pulsectl/pulsectl-21.10.5.ebuild
+++ /dev/null
@@ -1,19 +0,0 @@
-# Copyright 1999-2021 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-PYTHON_COMPAT=( python3_{7,8,9,10} pypy3 )
-inherit distutils-r1
-
-DESCRIPTION="Python high-level interface and ctypes-based bindings for PulseAudio (libpulse)"
-HOMEPAGE="https://github.com/mk-fg/python-pulse-control"
-SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
-
-LICENSE="MIT"
-SLOT="0"
-KEYWORDS="~amd64 ~x86"
-
-RDEPEND="media-sound/pulseaudio"
-
-distutils_enable_tests unittest
diff --git a/dev-python/pulsectl/pulsectl-22.1.1.ebuild b/dev-python/pulsectl/pulsectl-22.1.1.ebuild
deleted file mode 100644
index 89066bf66e48..000000000000
--- a/dev-python/pulsectl/pulsectl-22.1.1.ebuild
+++ /dev/null
@@ -1,20 +0,0 @@
-# Copyright 1999-2022 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-DISTUTILS_USE_PEP517=setuptools
-PYTHON_COMPAT=( python3_{7,8,9,10} pypy3 )
-inherit distutils-r1
-
-DESCRIPTION="Python high-level interface and ctypes-based bindings for PulseAudio (libpulse)"
-HOMEPAGE="https://github.com/mk-fg/python-pulse-control"
-SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
-
-LICENSE="MIT"
-SLOT="0"
-KEYWORDS="~amd64 ~x86"
-
-RDEPEND="media-sound/pulseaudio"
-
-distutils_enable_tests unittest
diff --git a/dev-python/pulsectl/pulsectl-22.1.0.ebuild b/dev-python/pulsectl/pulsectl-22.3.2.ebuild
index 89066bf66e48..309a20587f95 100644
--- a/dev-python/pulsectl/pulsectl-22.1.0.ebuild
+++ b/dev-python/pulsectl/pulsectl-22.3.2.ebuild
@@ -5,6 +5,7 @@ EAPI=8
 
 DISTUTILS_USE_PEP517=setuptools
 PYTHON_COMPAT=( python3_{7,8,9,10} pypy3 )
+
 inherit distutils-r1
 
 DESCRIPTION="Python high-level interface and ctypes-based bindings for PulseAudio (libpulse)"
diff --git a/dev-python/pygit2/Manifest b/dev-python/pygit2/Manifest
index 8f8830d3e880..089ed7e723e5 100644
--- a/dev-python/pygit2/Manifest
+++ b/dev-python/pygit2/Manifest
@@ -1 +1,2 @@
 DIST pygit2-1.9.0.gh.tar.gz 312349 BLAKE2B 067074d58887597cdce9b7bbebb96a8ec8629c4dc42c87c2a0a9a23849bc2e8e36763273c7d883ccfadbc9f71a3b4b5612a9a7b58e3cfb39475e568d85cbdc64 SHA512 8934f1099004a536b78973f74efc8854cbfb736369a0592c382fbc1325409105640235a2b3ce4602ad0dce863cb9ffd34b2359c9840d2abdadb55e2a43df18f9
+DIST pygit2-1.9.1.gh.tar.gz 317487 BLAKE2B 56855e656eafc27f24d8d59a0f21e36c49d292d322e6809257036ec0673f88d3299bca76c8f1c1a16bc79d667f0c6a355467ac5960c9999b11c8eddbf398cec6 SHA512 cfc050ef8cb6af7eace49d2e2ca10c77893abcafa1b319e173d39553e01a595ba084e345dedff22e22806527ecaed5387584f813b30184931820bb2bb1c93e58
diff --git a/dev-python/pygit2/pygit2-1.9.1.ebuild b/dev-python/pygit2/pygit2-1.9.1.ebuild
new file mode 100644
index 000000000000..5b60559e5d9f
--- /dev/null
+++ b/dev-python/pygit2/pygit2-1.9.1.ebuild
@@ -0,0 +1,47 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} )
+
+inherit distutils-r1
+
+DESCRIPTION="Python bindings for libgit2"
+HOMEPAGE="
+	https://github.com/libgit2/pygit2/
+	https://pypi.org/project/pygit2/"
+SRC_URI="
+	https://github.com/libgit2/pygit2/archive/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="GPL-2-with-linking-exception"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+DEPEND="
+	=dev-libs/libgit2-1.4*:=
+"
+BDEPEND="
+	>=dev-python/cffi-1.9.1:=[${PYTHON_USEDEP}]
+"
+RDEPEND="
+	${DEPEND}
+	${BDEPEND}
+"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	distutils-r1_src_prepare
+
+	# unconditionally prevent it from using network
+	sed -i -e '/has_network/s:True:False:' test/utils.py || die
+}
+
+src_test() {
+	rm -r pygit2 || die
+	distutils-r1_src_test
+}
diff --git a/dev-python/pyspnego/pyspnego-0.5.0.ebuild b/dev-python/pyspnego/pyspnego-0.5.0.ebuild
index 7e43c40faf05..ad9c91204c66 100644
--- a/dev-python/pyspnego/pyspnego-0.5.0.ebuild
+++ b/dev-python/pyspnego/pyspnego-0.5.0.ebuild
@@ -14,7 +14,7 @@ SRC_URI="mirror://pypi/${P:0:1}/${PN}/${P}.tar.gz"
 
 LICENSE="MIT"
 SLOT="0"
-KEYWORDS="amd64 ~arm ~arm64 ~riscv x86"
+KEYWORDS="amd64 ~arm arm64 ~riscv x86"
 
 RDEPEND="
 	dev-python/cryptography[${PYTHON_USEDEP}]
diff --git a/dev-python/pytest-metadata/Manifest b/dev-python/pytest-metadata/Manifest
index f80dd2f890e5..df6c414cfa9d 100644
--- a/dev-python/pytest-metadata/Manifest
+++ b/dev-python/pytest-metadata/Manifest
@@ -1 +1,2 @@
 DIST pytest-metadata-1.11.0.tar.gz 14135 BLAKE2B 1de1c47b1d7775040075de479722fd07cb187f14cd37c5fe73458fb54ce01653295288fd11add8066170b8dc39f80c8749e739deb01ac8d579ef5e6f4339478d SHA512 09867df6158ba66f55a0a812b3731b4372f874b6bdc91301ed0c4d4c38f6fe9a4f936006d4e27f8c68d4a2d6b0fe5fedee3c6269bc6867eb1c7d73a42bda0361
+DIST pytest-metadata-2.0.0.gh.tar.gz 20152 BLAKE2B 8ce06c327a3242a049c9af2476536a85e99d56925ba4ac98d7e07f72900f8b50c59950f25f4ccbc9c6c17eb2310ad381862f24d26410bbd68a6c2868cdf83547 SHA512 b22cf7925d3f38242670efde5e5482c7f971af78edf7bcccc765602dd4d688502c9b3b5b2a9723b37334bb8ad2218eb2318a82b8b2d6576ab8d69fa1ca321245
diff --git a/dev-python/pytest-metadata/pytest-metadata-2.0.0.ebuild b/dev-python/pytest-metadata/pytest-metadata-2.0.0.ebuild
new file mode 100644
index 000000000000..f762d1b8c443
--- /dev/null
+++ b/dev-python/pytest-metadata/pytest-metadata-2.0.0.ebuild
@@ -0,0 +1,31 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} pypy3 )
+
+inherit distutils-r1
+
+DESCRIPTION="A plugin for pytest that provides access to test session metadata"
+HOMEPAGE="https://github.com/pytest-dev/pytest-metadata/"
+SRC_URI="
+	https://github.com/pytest-dev/pytest-metadata/archive/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="MPL-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+RDEPEND="
+	>=dev-python/pytest-7.1.1[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	>=dev-python/setuptools_scm-6.2.3[${PYTHON_USEDEP}]
+"
+
+distutils_enable_tests pytest
+
+export SETUPTOOLS_SCM_PRETEND_VERSION=${PV}
diff --git a/dev-python/rich/Manifest b/dev-python/rich/Manifest
index 242056873273..86b25f2ab64b 100644
--- a/dev-python/rich/Manifest
+++ b/dev-python/rich/Manifest
@@ -1,2 +1,3 @@
 DIST rich-11.2.0.gh.tar.gz 16300346 BLAKE2B 520f512a7e26613a4cc881834f8c150963b84a6dc3a43029dde6d64d1e405d82422b9c6f0098293b6f9bdb55749c7929426dad14840c9a287889c1a6a70f6bf2 SHA512 ec1178a6a320a48f589ead5163e974725f79ae63ddf9a2deb66400e43619ade8d366dbef6b524e66e603647a957b8e26266845a0bcb85912fd9ad2a81dd92f5e
 DIST rich-12.0.0.gh.tar.gz 14727980 BLAKE2B b9f7761ab1084765f804fd22f9fb18e659f91b917bb452217752683f6d61320d2703eee28de3be3bd70009fc06d04165528393c4c0ec32a49b1dc7e94989a224 SHA512 4e47e48709180ef844bcf1cd516b22de8a4f22c5121ca0582a2cff7297d97afe63232926d518cd2bf4d6d1a7cea362ab12e71eedacce6b6d378ef1a1528d9e4c
+DIST rich-12.0.1.gh.tar.gz 14857207 BLAKE2B 8e6419904ef0ba91d4b15059630f63769a28323600cb212f07c2a239201489e2078b8c4c792f486bde75efd9d09afe832fa2e2235ac91433ee24b33fcda02e68 SHA512 61077663b46a7e615b29df3b75b15ef97979c804abd283cc26f217ee8128b74a514fd7b92831d1d8928f768d2ec8230d8cd1da733106b424704a3187ee18ce95
diff --git a/dev-python/rich/rich-12.0.1.ebuild b/dev-python/rich/rich-12.0.1.ebuild
new file mode 100644
index 000000000000..e7518f2f5ef7
--- /dev/null
+++ b/dev-python/rich/rich-12.0.1.ebuild
@@ -0,0 +1,41 @@
+# Copyright 2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=poetry
+PYTHON_COMPAT=( python3_{7,8,9,10} pypy3 )
+
+inherit distutils-r1 optfeature
+
+DESCRIPTION="Python library for renrering rich text, tables, etc. to the terminal"
+HOMEPAGE="https://github.com/Textualize/rich"
+SRC_URI="
+	https://github.com/Textualize/${PN}/archive/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ppc ~ppc64 ~riscv ~sparc ~x86"
+
+RDEPEND="
+	dev-python/colorama[${PYTHON_USEDEP}]
+	dev-python/commonmark[${PYTHON_USEDEP}]
+	dev-python/pygments[${PYTHON_USEDEP}]"
+
+distutils_enable_tests pytest
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# check for exact color render string, which changes across pygments bumps
+		tests/test_syntax.py::test_python_render
+		tests/test_syntax.py::test_python_render_simple
+		tests/test_syntax.py::test_python_render_indent_guides
+	)
+	epytest -p no:pytest-qt
+}
+
+pkg_postinst() {
+	optfeature "integration with HTML widgets for Jupyter" dev-python/ipywidgets
+}
diff --git a/dev-python/sphobjinv/Manifest b/dev-python/sphobjinv/Manifest
index 54ef0e3bc0c5..b0eb5d837d52 100644
--- a/dev-python/sphobjinv/Manifest
+++ b/dev-python/sphobjinv/Manifest
@@ -1 +1,2 @@
 DIST sphobjinv-2.2.1.tar.gz 1150428 BLAKE2B 13bec53b00d14466aad652fb822ba32156d4ee3141f2df5bf55eaf77d03627c98c48dd142757ac43fe7dbf00716a85ee4c03060dfcf89e1d9aca4cd2589df5b0 SHA512 9247fc38e5d49adab0921f31e4ad1a8b2ca260c7a921b5fb9db7f800ee484335449031b0f51f81149ff71edba6cc93ab14a683ff6cdce2494322d05474e9a2c7
+DIST sphobjinv-2.2.2.tar.gz 1188094 BLAKE2B f693254f3746b0e5cb6cc863be381f41d26465eab2e1494c29f30f1a72374e8d03dfa5c433958dfa1dcbaa0a7da1ff454c42da5c09011fa67264c26e3623a302 SHA512 36e7667b071f30d4ca066422b21d298c5691321d813ba6ad9eb7a69cd4107ceb18365ee2f95865fad64ab872428b035661a3f513df2e4aab1124b48f49c7280b
diff --git a/dev-python/sphobjinv/sphobjinv-2.2.2.ebuild b/dev-python/sphobjinv/sphobjinv-2.2.2.ebuild
new file mode 100644
index 000000000000..6347f3af729c
--- /dev/null
+++ b/dev-python/sphobjinv/sphobjinv-2.2.2.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} )
+
+inherit distutils-r1
+
+DESCRIPTION="Sphinx objects.inv Inspection/Manipulation Tool"
+HOMEPAGE="
+	https://github.com/bskinn/sphobjinv/
+	https://pypi.org/project/sphobjinv/
+"
+SRC_URI="
+	https://github.com/bskinn/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz
+"
+
+LICENSE="MIT"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+SLOT="0"
+
+RDEPEND="
+	>=dev-python/attrs-19.2[${PYTHON_USEDEP}]
+	dev-python/certifi[${PYTHON_USEDEP}]
+	dev-python/fuzzywuzzy[${PYTHON_USEDEP}]
+	>=dev-python/jsonschema-3.0[${PYTHON_USEDEP}]"
+BDEPEND="
+	test? (
+		dev-python/dictdiffer[${PYTHON_USEDEP}]
+		dev-python/pytest-check[${PYTHON_USEDEP}]
+		dev-python/pytest-ordering[${PYTHON_USEDEP}]
+		dev-python/pytest-timeout[${PYTHON_USEDEP}]
+		>=dev-python/stdio-mgr-1.0.1[${PYTHON_USEDEP}]
+		dev-python/sphinx[${PYTHON_USEDEP}]
+		dev-python/timeout-decorator[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+distutils_enable_sphinx doc/source \
+	dev-python/sphinx_rtd_theme \
+	dev-python/sphinx-issues \
+	dev-python/sphinxcontrib-programoutput
+
+src_prepare() {
+	# --strict option is deprecated in pytest>6
+	sed -i -e '/addopts/d' tox.ini || die
+	sed -e '/CLI_TEST_TIMEOUT/s/2/20/' -i tests/test_cli.py || die
+
+	# remove bundled deps
+	rm -r src/sphobjinv/_vendored || die
+	sed -i -e 's:sphobjinv[.]_vendored[.]::' src/sphobjinv/*.py || die
+
+	distutils-r1_src_prepare
+}