Adding metadata

27 files changed, 466 insertions, 104 deletions

diff --git a/dev-python/boto3/Manifest b/dev-python/boto3/Manifest
index 7910c4dc180f..7b30d6f3aaaa 100644
--- a/dev-python/boto3/Manifest
+++ b/dev-python/boto3/Manifest
@@ -1,3 +1,4 @@
 DIST boto3-1.33.11.gh.tar.gz 754430 BLAKE2B f206c6eeb9859af85f09bb48298b941fc0c969446766638c612fa1e88e19b8f9a99ec2ecbb8565a40432cc7a7f5362459af7488a172f4bca3179385d82742feb SHA512 03f37d99b70d857d2d72e81e02fe3afb64d3139adde80db0bf3a2f78ce8fa33c5cc6965a8dbfd267b263711c73c355d69d7e629eb7f28e6bdccf5480ca9c9810
 DIST boto3-1.34.2.gh.tar.gz 756227 BLAKE2B 7253c533bac45b3848ab573d4781cf68b6bea8d504f851b58366dd3e6ac05b35fb2a85cb7aaff0e426a6bd2f9fe2933dd240e4d0283e4491e095fa93b4061971 SHA512 06eaf9b6725d312d91a4a8ba3ab85dde5f579e6d2fa42211189a6f30584b7d2a5c0cca46264bda52a076c8bd1acac9ec0476eb5d986a8e29972f69b7007de3c2
 DIST boto3-1.34.7.gh.tar.gz 759909 BLAKE2B 059228d7bd57ac34274437f77b3510dff6dca7d1293ffd6f7672b0fcc0acefffeeda2c5c2b4e19ef49bbffd4746dc226edfba52d57f5f8629516c9e830dbdd90 SHA512 43395937977ad3c860ede35d2adbb9575312ddab4972b8d258e41a7d6e86f3e6a74037dadb0f0e0f4f3d5ed715a66390041ac9c980bc8a3cfb727a44e252113e
+DIST boto3-1.34.8.gh.tar.gz 759987 BLAKE2B 32cbc7c5e82b36b7df2435f52c3f01e939c997671e8ec323840cff1554fcd84be41e1c4d17ab9b1b2779b94f815e597f8021380196c2debfb18db6fad0434cc9 SHA512 db33fb1c95f856a0a20625132e05c632baa46b3b0aacb97c9f6857a79656978abecaffd3f164b7f3eabf6e5e80f663386ab522e96c4546352bb6af6025d23fdd
diff --git a/dev-python/boto3/boto3-1.34.8.ebuild b/dev-python/boto3/boto3-1.34.8.ebuild
new file mode 100644
index 000000000000..63900e77cd21
--- /dev/null
+++ b/dev-python/boto3/boto3-1.34.8.ebuild
@@ -0,0 +1,64 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8,9,10,11,12} )
+
+inherit distutils-r1
+
+DESCRIPTION="The AWS SDK for Python"
+HOMEPAGE="
+	https://github.com/boto/boto3/
+	https://pypi.org/project/boto3/
+"
+LICENSE="Apache-2.0"
+SLOT="0"
+
+if [[ "${PV}" == "9999" ]]; then
+	EGIT_REPO_URI="https://github.com/boto/boto3"
+	inherit git-r3
+	BOTOCORE_PV=${PV}
+else
+	SRC_URI="
+		https://github.com/boto/boto3/archive/${PV}.tar.gz
+			-> ${P}.gh.tar.gz
+	"
+	KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux"
+fi
+
+RDEPEND="
+	>=dev-python/botocore-${PV}[${PYTHON_USEDEP}]
+	>=dev-python/jmespath-0.7.1[${PYTHON_USEDEP}]
+	>=dev-python/s3transfer-0.10.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/mock[${PYTHON_USEDEP}]
+	)
+"
+
+EPYTEST_XDIST=1
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	# don't lock versions to narrow ranges
+	sed -e '/botocore/ d' \
+		-e '/jmespath/ d' \
+		-e '/s3transfer/ d' \
+		-i setup.py || die
+
+	# do not rely on bundled deps in botocore (sic!)
+	find -name '*.py' -exec sed -i \
+		-e 's:from botocore[.]vendored import:import:' \
+		-e 's:from botocore[.]vendored[.]:from :' \
+		{} + || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest tests/{functional,unit}
+}
diff --git a/dev-python/botocore/Manifest b/dev-python/botocore/Manifest
index 0fb8c044540f..0b181fc3fdc8 100644
--- a/dev-python/botocore/Manifest
+++ b/dev-python/botocore/Manifest
@@ -1,3 +1,4 @@
 DIST botocore-1.33.11.gh.tar.gz 12536159 BLAKE2B bce09ad1b93210667e3c1058ab3b4350b752e330c78c29af87c53b3f3f738dd7622b1b670a4fdbfa2dfdeaf763f9885b3f82ad0eb4f44c7e7585ae5b8eaa6b5d SHA512 5d790bbb909230861cf2eb38908f5876ab9bd7e5dd1f718987797af0b263c7ea2c42d69aa1d55b66d1b954204caa04c50cd050385607637192e9ad6b33f65b7d
 DIST botocore-1.34.2.gh.tar.gz 12564834 BLAKE2B b22a3d3bd35b769a28ccb1a5116428e1904d0c9fc3452829237704dbec37a31a539f044a728b0785d09406d299d522dd601da39801249747d54e6741b46cafe2 SHA512 a3f3718bf584a871abbb3edc803de9d5329da257c050d56bdbf8a6a6c4067477812582fbd8d1d789ce18ea1f416d0ddb2be9cc3c45172292d061a94a12f3977b
 DIST botocore-1.34.7.gh.tar.gz 12606475 BLAKE2B 387ee7dfab43c44c39c7b0566b6ddcb2b666024b5b7bee2c996194988781c169e1e9462b36d09861d1c3ca899d263392f3d79129e7a2f2fc4bbfed402f5c7dd6 SHA512 3f162d4d028dd81da552e0117671971aa891bf8fab513730f40083660fa83c1f82bf1b52875cf9f7f11089ecdd79f084f3c8e76227aa826c1aac7e5735032450
+DIST botocore-1.34.8.gh.tar.gz 12607766 BLAKE2B df29d3846dcb5096708223b5b4c59a2f9a7dcf213c5691bf0a619fb4c9c6ceab5fbecefce6f8ddd76752b420fcfb95bfc7ae00c933172a7f1d9281b7b08f3049 SHA512 4359320cc619cde5bf938cec00b430f6daa8bfeb0170bb476dd3a6be0ba3464aeccd6a422e4d1487a1d7ed6721cb2ffdc55465d289fcccb82f3a5ff142b782b4
diff --git a/dev-python/botocore/botocore-1.34.8.ebuild b/dev-python/botocore/botocore-1.34.8.ebuild
new file mode 100644
index 000000000000..9a0240c45f2a
--- /dev/null
+++ b/dev-python/botocore/botocore-1.34.8.ebuild
@@ -0,0 +1,68 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8,9,10,11,12} )
+
+inherit distutils-r1
+
+DESCRIPTION="Low-level, data-driven core of boto 3"
+HOMEPAGE="
+	https://github.com/boto/botocore/
+	https://pypi.org/project/botocore/
+"
+LICENSE="Apache-2.0"
+SLOT="0"
+
+if [[ "${PV}" == "9999" ]]; then
+	EGIT_REPO_URI="https://github.com/boto/botocore"
+	inherit git-r3
+else
+	SRC_URI="
+		https://github.com/boto/botocore/archive/${PV}.tar.gz
+			-> ${P}.gh.tar.gz
+	"
+	KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux"
+fi
+
+RDEPEND="
+	dev-python/six[${PYTHON_USEDEP}]
+	<dev-python/jmespath-2[${PYTHON_USEDEP}]
+	dev-python/python-dateutil[${PYTHON_USEDEP}]
+	>=dev-python/urllib3-1.25.4[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/jsonschema[${PYTHON_USEDEP}]
+	)
+"
+
+EPYTEST_XDIST=1
+distutils_enable_tests pytest
+
+src_prepare() {
+	# unpin deps
+	sed -i -e "s:>=.*':':" setup.py || die
+
+	# unbundle deps
+	rm -r botocore/vendored || die
+	find -name '*.py' -exec sed -i \
+		-e 's:from botocore[.]vendored import:import:' \
+		-e 's:from botocore[.]vendored[.]:from :' \
+		{} + || die
+
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# rely on bundled six
+		tests/functional/test_six_imports.py::test_no_bare_six_imports
+		tests/functional/test_six_threading.py::test_six_thread_safety
+	)
+
+	local -x EPYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest tests/{functional,unit}
+}
diff --git a/dev-python/cleo/metadata.xml b/dev-python/cleo/metadata.xml
index 12cb1059a8c1..ea8988e8af6a 100644
--- a/dev-python/cleo/metadata.xml
+++ b/dev-python/cleo/metadata.xml
@@ -1,10 +1,6 @@
 <?xml version="1.0" encoding="UTF-8"?>
 <!DOCTYPE pkgmetadata SYSTEM "https://liguros.gitlab.io/dtd/metadata.dtd">
 <pkgmetadata>
- <maintainer type="person">
-  <email>jsmolic@gentoo.org</email>
-  <name>Jakov Smolić</name>
- </maintainer>
  <maintainer type="project">
   <email>python@gentoo.org</email>
   <name>Python</name>
diff --git a/dev-python/clikit/metadata.xml b/dev-python/clikit/metadata.xml
index 12cb1059a8c1..ea8988e8af6a 100644
--- a/dev-python/clikit/metadata.xml
+++ b/dev-python/clikit/metadata.xml
@@ -1,10 +1,6 @@
 <?xml version="1.0" encoding="UTF-8"?>
 <!DOCTYPE pkgmetadata SYSTEM "https://liguros.gitlab.io/dtd/metadata.dtd">
 <pkgmetadata>
- <maintainer type="person">
-  <email>jsmolic@gentoo.org</email>
-  <name>Jakov Smolić</name>
- </maintainer>
  <maintainer type="project">
   <email>python@gentoo.org</email>
   <name>Python</name>
diff --git a/dev-python/hypothesis/Manifest b/dev-python/hypothesis/Manifest
index a3b7ceb9f7df..55173cc82caf 100644
--- a/dev-python/hypothesis/Manifest
+++ b/dev-python/hypothesis/Manifest
@@ -1,3 +1,4 @@
 DIST hypothesis-6.91.1.gh.tar.gz 9398188 BLAKE2B 3a068ec668f84cf84ebd274505938d861ef7b6f50a9bb33403c26c53b783ee6fe6afba214ca5d9c31e933909dd657d367c09dd74dac257348316e308ed761ccb SHA512 4004fe0dcef1dc679ee512f901f1115426fdbd8d0f2b1fc539c331157d1840bb16c415c7bcf0cbfae3e1dcf6f9741eb8e2ec725810f5d65e20e75f0ea07369b8
 DIST hypothesis-6.92.0.gh.tar.gz 9407699 BLAKE2B 7943aa958e135a954d4534b8992557a4ffd51941529cad6a8bb10b4ccd2e5c136159deaf11f822d96ecf60df536cff8b92756d902cd93de26df74ae10f73e14f SHA512 1fad215bd7ab69896d300ed39fd99a8a7145e6e21799429627b0d587939bfbe01d02fb7e1154a8b31f0b164ba9323b55b6ea36a268be20f1ef282d6b6f0d457a
 DIST hypothesis-6.92.1.gh.tar.gz 9408706 BLAKE2B b41bba23e5aa8715ff095edddcae02430db99b3294c85cd74c3f553a203bf3f484f4820494519f7100a261bc646abf6bc1d8a45dafb97d4bf709115f480f2b91 SHA512 fd5e52a258ba46682ae198457d857cfc82230be6faaefa2160a764e56ac1d8abb32dc0eaed3606877ca7fd7d184232c5e218d8f2eab54e5b9db0fd6ad30c8930
+DIST hypothesis-6.92.2.gh.tar.gz 9408586 BLAKE2B f6d873d16a337ceb5d78bc80622a08fb6856b5fdbd0c0c228bca13d340375b882416bf6ad4cfd08bb9959807ce1ac482ef5b4202792713c76a30dfff78fd4d4b SHA512 51bfd0b5d520fe84b4e682772888320d61bc4c52c6b4dda609f758336cc151bcf00714635e19230cdd1695209b6adf05cee349a82003e443dc5f52a7f105feb5
diff --git a/dev-python/hypothesis/hypothesis-6.92.2.ebuild b/dev-python/hypothesis/hypothesis-6.92.2.ebuild
new file mode 100644
index 000000000000..a8a6a71f13d8
--- /dev/null
+++ b/dev-python/hypothesis/hypothesis-6.92.2.ebuild
@@ -0,0 +1,90 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+CLI_COMPAT=( python3_{10..12} )
+PYTHON_COMPAT=( python3_{8,9,10,11,12} pypy3 )
+PYTHON_REQ_USE="threads(+),sqlite"
+
+inherit distutils-r1 multiprocessing optfeature
+
+TAG=hypothesis-python-${PV}
+MY_P=hypothesis-${TAG}
+DESCRIPTION="A library for property based testing"
+HOMEPAGE="
+	https://github.com/HypothesisWorks/hypothesis/
+	https://pypi.org/project/hypothesis/
+"
+SRC_URI="
+	https://github.com/HypothesisWorks/hypothesis/archive/${TAG}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+S="${WORKDIR}/${MY_P}/hypothesis-python"
+
+LICENSE="MPL-2.0"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+IUSE="cli"
+
+RDEPEND="
+	>=dev-python/attrs-22.2.0[${PYTHON_USEDEP}]
+	>=dev-python/sortedcontainers-2.1.0[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '
+		>=dev-python/exceptiongroup-1.0.0_rc8[${PYTHON_USEDEP}]
+	' 3.9 3.10)
+	cli? (
+		$(python_gen_cond_dep '
+			dev-python/black[${PYTHON_USEDEP}]
+			dev-python/click[${PYTHON_USEDEP}]
+		' "${CLI_COMPAT[@]}")
+	)
+"
+BDEPEND="
+	test? (
+		dev-python/pexpect[${PYTHON_USEDEP}]
+		dev-python/pytest-xdist[${PYTHON_USEDEP}]
+		!!<dev-python/requests-toolbelt-0.10.1
+	)
+"
+
+distutils_enable_tests pytest
+
+python_test() {
+	# subtests are broken by warnings from random plugins
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	local -x PYTEST_PLUGINS=xdist.plugin,_hypothesis_pytestplugin
+	local -x HYPOTHESIS_NO_PLUGINS=1
+
+	# NB: paths need to be relative to pytest.ini,
+	# i.e. start with hypothesis-python/
+	local EPYTEST_DESELECT=()
+	case ${EPYTHON} in
+		pypy3)
+			EPYTEST_DESELECT+=(
+				# failing due to warnings from numpy/cython
+				hypothesis-python/tests/pytest/test_fixtures.py::test_given_plus_overridden_fixture
+			)
+			;;
+	esac
+
+	epytest -o filterwarnings= -n "$(makeopts_jobs)" --dist=worksteal \
+		tests/cover tests/pytest tests/quality
+}
+
+python_install() {
+	distutils-r1_python_install
+	if ! use cli || ! has "${EPYTHON}" "${CLI_COMPAT[@]/_/.}"; then
+		rm -r "${ED}/usr/bin" "${D}$(python_get_scriptdir)" || die
+	fi
+}
+
+pkg_postinst() {
+	optfeature "datetime support" dev-python/pytz
+	optfeature "dateutil support" dev-python/python-dateutil
+	optfeature "numpy support" dev-python/numpy
+	optfeature "django support" dev-python/django dev-python/pytz
+	optfeature "pandas support" dev-python/pandas
+	optfeature "pytest support" dev-python/pytest
+}
diff --git a/dev-python/ipykernel/Manifest b/dev-python/ipykernel/Manifest
index 784f9bc948e5..10157317b2ce 100644
--- a/dev-python/ipykernel/Manifest
+++ b/dev-python/ipykernel/Manifest
@@ -1 +1,2 @@
 DIST ipykernel-6.27.1.tar.gz 157828 BLAKE2B d81c241d55a6b45098bd38805dd8db2dd10c13bd290102f96011fc134b54925218da03ee6bdddd2de137089017e157cd6806ce3884279d3bc00684a357b60c7a SHA512 c4ee96c934e66a1d27d680bb43adb88affb49e605310d4d619cd42b0a294d82ad7884a110998eb3004be4f010d847968694b4c8327efa26976062249895132c6
+DIST ipykernel-6.28.0.tar.gz 157701 BLAKE2B 61b5415e6209cc83ea5f97f7a485489c5338539e711abab0358006835f0cff3d4d3a51b797eaaf44ef4666b225a0b64b9d135b9607a42dcb7d43a9bb38e9155d SHA512 81efbaafc48ad22b54719eebe7564d9d386407272b6c9bad34a2685ec73e1f831a2753251a7ff47c337becad272a39311f15faa7dac331e53272f3ccc975a860
diff --git a/dev-python/ipykernel/ipykernel-6.28.0.ebuild b/dev-python/ipykernel/ipykernel-6.28.0.ebuild
new file mode 100644
index 000000000000..205747f226cd
--- /dev/null
+++ b/dev-python/ipykernel/ipykernel-6.28.0.ebuild
@@ -0,0 +1,78 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYTHON_COMPAT=( python3_{8,9,10,11,12} pypy3 )
+PYTHON_REQ_USE="threads(+)"
+
+inherit distutils-r1 pypi virtualx
+
+DESCRIPTION="IPython Kernel for Jupyter"
+HOMEPAGE="
+	https://github.com/ipython/ipykernel/
+	https://pypi.org/project/ipykernel/
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~arm64-macos ~x64-macos"
+
+RDEPEND="
+	>=dev-python/comm-0.1.1[${PYTHON_USEDEP}]
+	!elibc_Darwin? (
+		$(python_gen_cond_dep '
+			>=dev-python/debugpy-1.6.5[${PYTHON_USEDEP}]
+		' 'python*')
+	)
+	>=dev-python/ipython-7.23.1[${PYTHON_USEDEP}]
+	>=dev-python/jupyter-client-8[${PYTHON_USEDEP}]
+	>=dev-python/jupyter-core-4.12[${PYTHON_USEDEP}]
+	>=dev-python/matplotlib-inline-0.1[${PYTHON_USEDEP}]
+	dev-python/nest-asyncio[${PYTHON_USEDEP}]
+	dev-python/packaging[${PYTHON_USEDEP}]
+	dev-python/psutil[${PYTHON_USEDEP}]
+	>=dev-python/pyzmq-24[${PYTHON_USEDEP}]
+	>=dev-python/tornado-6.1[${PYTHON_USEDEP}]
+	>=dev-python/traitlets-5.4.0[${PYTHON_USEDEP}]
+"
+# RDEPEND seems specifically needed in BDEPEND, at least jupyter
+# bug #816486
+BDEPEND="
+	${RDEPEND}
+	test? (
+		dev-python/flaky[${PYTHON_USEDEP}]
+		dev-python/pytest-asyncio[${PYTHON_USEDEP}]
+		dev-python/pytest-timeout[${PYTHON_USEDEP}]
+		dev-python/ipyparallel[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+python_compile() {
+	distutils-r1_python_compile
+	# Use python3 in kernel.json configuration, bug #784764
+	sed -i -e '/python3.[0-9]\+/s//python3/' \
+		"${BUILD_DIR}/install${EPREFIX}/usr/share/jupyter/kernels/python3/kernel.json" || die
+}
+
+src_test() {
+	local EPYTEST_DESELECT=(
+		# TODO
+		tests/test_debugger.py::test_attach_debug
+		tests/test_debugger.py::test_breakpoint_in_cell_with_leading_empty_lines
+		tests/test_debugger.py::test_rich_inspect_at_breakpoint
+		tests/test_debugger.py::test_rich_inspect_not_at_breakpoint
+		tests/test_debugger.py::test_set_breakpoints
+		tests/test_debugger.py::test_stop_on_breakpoint
+		tests/test_debugger.py::test_copy_to_globals
+		# hangs?
+		tests/test_eventloop.py::test_tk_loop
+		# doesn't like pyside2?
+		tests/test_eventloop.py::test_qt_enable_gui
+	)
+
+	virtx distutils-r1_src_test
+}
diff --git a/dev-python/jupyter-core/Manifest b/dev-python/jupyter-core/Manifest
index 95f9c4f51a74..d41db9d5899e 100644
--- a/dev-python/jupyter-core/Manifest
+++ b/dev-python/jupyter-core/Manifest
@@ -1,2 +1,3 @@
 DIST jupyter_core-5.5.0.tar.gz 85369 BLAKE2B 41fa2381023c8f2313607d2ac989d1f35dcd362abd4b9573affaf9fc34cd48eb260d2ad68af97be2d47aa4a077f1756e6e291a4f0dd48c9774df2d31dda7e9b4 SHA512 92ca5ddc69d58ecdf1f707104e950ba43c88630991b0a6951fb6ba83260573b9f48c7903b25ae7bc105c08b3179de4bebb5a87b66453b96ceed631cbf555d631
 DIST jupyter_core-5.5.1.tar.gz 85962 BLAKE2B a00e96b417d86cc66ac483d031919483ded2e06da9688ed3554d96b5b6709f6ffd1d3602a63160d37c4774d37ee166aed3f3fb81f7f9882482302c8189a19fce SHA512 f82ce8a0f6671b06b6bb768d1a7cf85a9b28be57ba88809334d2fbcfed0d6e2bc5a2320a128ed8a8b498a763d157b1ecc1dc093de1c1aa97a65770a5b715c202
+DIST jupyter_core-5.6.0.tar.gz 86418 BLAKE2B 70ab01fc13772f772c374a9452f36926f43bf85c6a19108592ce91238df137116f683692a69cbbb2693a87222728b76de0d4b80563bcd5b6d9019aac874e1d91 SHA512 2a2ff1a6ecc12adbd98b1beaea6206f58fe6d24b841102a436ed42106639992454eb4af2515ff268e95749fa01c3352ac1c919bfb053f3ebe22e1d9d9f9e03d3
diff --git a/dev-python/jupyter-core/jupyter-core-5.6.0.ebuild b/dev-python/jupyter-core/jupyter-core-5.6.0.ebuild
new file mode 100644
index 000000000000..fd1a2c6167f8
--- /dev/null
+++ b/dev-python/jupyter-core/jupyter-core-5.6.0.ebuild
@@ -0,0 +1,40 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYTHON_COMPAT=( python3_{8,9,10,11,12} pypy3 )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Core common functionality of Jupyter projects"
+HOMEPAGE="
+	https://jupyter.org/
+	https://github.com/jupyter/jupyter_core/
+	https://pypi.org/project/jupyter-core/
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~arm64-macos ~x64-macos"
+
+RDEPEND="
+	>=dev-python/platformdirs-2.5[${PYTHON_USEDEP}]
+	>=dev-python/traitlets-5.11.2[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		>=dev-python/ipython-4.0.1[${PYTHON_USEDEP}]
+		dev-python/pip[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_sphinx docs \
+	dev-python/myst-parser \
+	dev-python/pydata-sphinx-theme \
+	dev-python/sphinx-autodoc-typehints \
+	dev-python/sphinxcontrib-github-alt \
+	dev-python/sphinxcontrib-spelling \
+	dev-python/traitlets
+distutils_enable_tests pytest
diff --git a/dev-python/jupyter-server-terminals/Manifest b/dev-python/jupyter-server-terminals/Manifest
index 561326d9642d..16d90dcfac3e 100644
--- a/dev-python/jupyter-server-terminals/Manifest
+++ b/dev-python/jupyter-server-terminals/Manifest
@@ -1,2 +1,3 @@
 DIST jupyter_server_terminals-0.4.4.tar.gz 29850 BLAKE2B 064876d7a10e7ff66da83e07d562abe53d609caeb27bcd7b7181d10c06af4406ee048b45b73092c8f3b0c10df40494eca1edb5234030154c63ea6a330f85a115 SHA512 5b1a6a9cfd550108be7f6664eac5ab7581d75e78a7dfc9825af2346b0d9b19f05543dcce010dafb9554c0782bf8e7929bf0ef96bdf2db392ab9b9ec1a3633fdd
 DIST jupyter_server_terminals-0.5.0.tar.gz 30616 BLAKE2B b2cbfab34850cf64c7d0793dc8703d99a40f34437e5222cc310d888306ff8228ff4a04602666a174bed91eb22232e28bdd8963180b8a92c75b3190676d08e65e SHA512 398419590bfad09846dd4f283896962af772700f6bf43b2cd3c2516830a9693ce4f383a9e3620e9d5613985f4d60c0758fad8961e7ba023f7f5b73200679ee25
+DIST jupyter_server_terminals-0.5.1.tar.gz 30742 BLAKE2B 616be4e82e7650f3dd9c2031bd2607315d0f906bd7556d442bb0d6b277c4ef88c1d4856557a2bad62cff16322e00d28412fd3132e5a9372b5d463ca67b75d24e SHA512 e3006e61aa712675bcdcf85dcb1f775da8064b8a621d852f51063707ebe3462ffe75efbb646dd76075d9ee075b80458290a075f502f270487b9390ba3f6881c5
diff --git a/dev-python/jupyter-server-terminals/jupyter-server-terminals-0.5.1.ebuild b/dev-python/jupyter-server-terminals/jupyter-server-terminals-0.5.1.ebuild
new file mode 100644
index 000000000000..a2446625dab0
--- /dev/null
+++ b/dev-python/jupyter-server-terminals/jupyter-server-terminals-0.5.1.ebuild
@@ -0,0 +1,45 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYTHON_COMPAT=( python3_{8,9,10,11,12} pypy3 )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="A Jupyter Server Extension Providing Terminals"
+HOMEPAGE="
+	https://jupyter.org/
+	https://github.com/jupyter-server/jupyter_server_terminals/
+	https://pypi.org/project/jupyter-server-terminals/
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+RDEPEND="
+	dev-python/terminado[${PYTHON_USEDEP}]
+"
+
+BDEPEND="
+	test? (
+		dev-python/jupyter-server[${PYTHON_USEDEP}]
+		dev-python/pytest-jupyter[${PYTHON_USEDEP}]
+		dev-python/pytest-timeout[${PYTHON_USEDEP}]
+	)
+"
+
+EPYTEST_DESELECT=(
+	# Fails if shell is not bash
+	tests/test_terminal.py::test_terminal_create_with_cwd
+	tests/test_terminal.py::test_terminal_create_with_relative_cwd
+)
+
+distutils_enable_tests pytest
+
+python_install_all() {
+	distutils-r1_python_install_all
+	mv "${ED}/usr/etc" "${ED}/etc" || die
+}
diff --git a/dev-python/jwcrypto/Manifest b/dev-python/jwcrypto/Manifest
index 9c81f01d3e75..a2224b960f77 100644
--- a/dev-python/jwcrypto/Manifest
+++ b/dev-python/jwcrypto/Manifest
@@ -1 +1,2 @@
 DIST jwcrypto-1.5.0.gh.tar.gz 95669 BLAKE2B c8a408e3bdd929a939562eeebe59b33eb422fdf3251b8572b362a08286975220810bf7b2d0d937ef4f20c76ff133b5246f810a3cb7fa7caf685ecd03729ba5e0 SHA512 92c8c735dffe3664e93ead9a5764139f188d349b78c45d09ea9ede68b271f19f4cd16418f9184df49f2f9def16864624edc3d08bda30fd73fbf3daa2b12157a4
+DIST jwcrypto-1.5.1.gh.tar.gz 96563 BLAKE2B 13b39b27825031d4f30e1399bac085ba846551b5e50c49ae2a1ff31182e47a896ef9bfdd1705a40e59ddeb6850ba7bafd19ccf83d9f8177c47936e220df881db SHA512 fecb993a1157b6e689d3e845c8839f3178e32ab7fc920bf6b7328705293dae5e3d1424532b066f6dedd9c25a5cdeec91089ed4b83c4592cf6e1690419b5a5539
diff --git a/dev-python/jwcrypto/jwcrypto-1.5.1.ebuild b/dev-python/jwcrypto/jwcrypto-1.5.1.ebuild
new file mode 100644
index 000000000000..3cafbb75769d
--- /dev/null
+++ b/dev-python/jwcrypto/jwcrypto-1.5.1.ebuild
@@ -0,0 +1,37 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8,9,10,11,12} pypy3 )
+
+inherit distutils-r1
+
+DESCRIPTION="Implements JWK,JWS,JWE specifications using python-cryptography"
+HOMEPAGE="
+	https://github.com/latchset/jwcrypto/
+	https://pypi.org/project/jwcrypto/
+"
+SRC_URI="
+	https://github.com/latchset/jwcrypto/archive/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="LGPL-3+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~riscv ~x86"
+
+RDEPEND="
+	>=dev-python/cryptography-3.4[${PYTHON_USEDEP}]
+	dev-python/deprecated[${PYTHON_USEDEP}]
+"
+
+distutils_enable_sphinx docs/source
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	# Do not install doc in non-standard paths
+	sed -e "/data_files/d" -i setup.py || die
+	distutils-r1_python_prepare_all
+}
diff --git a/dev-python/langdetect/Manifest b/dev-python/langdetect/Manifest
index e9da2ac43cac..a11d7c268c91 100644
--- a/dev-python/langdetect/Manifest
+++ b/dev-python/langdetect/Manifest
@@ -1,3 +1 @@
 DIST langdetect-1.0.9.tar.gz 981474 BLAKE2B ea8a9c3f16a2987c080742473bff4f2c1503f53fb3c2b40b0b1d6212bb6133ea22dce7864ffcfb8968c3a46b157d45cb3e2cf6f84bdbed0266cc716a853b032c SHA512 7558d674c47b080c79e43a00a25d2c7f77188cf60bea2cecb3bebb803d75e1aa42b43c74bd26ea1b541f4cb927421908882cbec01a91f0913984217e71ccc8db
-EBUILD langdetect-1.0.9.ebuild 493 BLAKE2B 0df8bce19bc80f79f8e76bcef5a4c2caf333365fe0cb9a3c076b7858bceded5a3e58921474f866a2709dd657b7ed330c1ec4a7f9d7bab0fcf1bc92d77cabc32d SHA512 ea2a1adcb133ac5fc951ba1aa90ef1ce3dfcc424e59727591763d4875aa044a74188be2d15fd89c6b2e83ed6ea04ec3d9851ed584ae79d2c2c127bde7d994b48
-MISC metadata.xml 457 BLAKE2B 630128a3e982b6d60cc7b9f74c79fcb5ee47a71a02c73a50af9da8cedb6fad8e20a7f74b881e5b25c6483b92c9edbd56552cd38b2d9cbfa8b3eb4530facea969 SHA512 674f4f5cd809c6c77bc14e0f5687fa972bef14bdfa0b3343c5d66b7163eef1906eb87d060c8288732f825de71dce291ad0b841a5f2f0dd230f957b5687e45d45
diff --git a/dev-python/langdetect/metadata.xml b/dev-python/langdetect/metadata.xml
index 020e07f2a3dd..736a1167c898 100644
--- a/dev-python/langdetect/metadata.xml
+++ b/dev-python/langdetect/metadata.xml
@@ -1,12 +1,6 @@
 <?xml version="1.0" encoding="UTF-8"?>
 <!DOCTYPE pkgmetadata SYSTEM "https://liguros.gitlab.io/dtd/metadata.dtd">
 <pkgmetadata>
- <maintainer type="person">
-  <email>marcin.deranek@slonko.net</email>
-  <name>Marcin Deranek</name>
- </maintainer>
- <upstream>
-  <bugs-to>https://github.com/Mimino666/langdetect/issues</bugs-to>
- </upstream>
- <origin>slonko-overlay</origin>
+ 
+ <origin>gentoo-guru-overlay</origin>
 </pkgmetadata>
\ No newline at end of file
diff --git a/dev-python/pastel/metadata.xml b/dev-python/pastel/metadata.xml
index 12cb1059a8c1..ea8988e8af6a 100644
--- a/dev-python/pastel/metadata.xml
+++ b/dev-python/pastel/metadata.xml
@@ -1,10 +1,6 @@
 <?xml version="1.0" encoding="UTF-8"?>
 <!DOCTYPE pkgmetadata SYSTEM "https://liguros.gitlab.io/dtd/metadata.dtd">
 <pkgmetadata>
- <maintainer type="person">
-  <email>jsmolic@gentoo.org</email>
-  <name>Jakov Smolić</name>
- </maintainer>
  <maintainer type="project">
   <email>python@gentoo.org</email>
   <name>Python</name>
diff --git a/dev-python/pycpio/Manifest b/dev-python/pycpio/Manifest
index bdcb06c06a50..e6bbe54a649a 100644
--- a/dev-python/pycpio/Manifest
+++ b/dev-python/pycpio/Manifest
@@ -1,2 +1,2 @@
-DIST pycpio-0.6.0.tar.gz 17226 BLAKE2B dcbd9b74c0aa0e5b4eb8e826787f6de86493c2fc3df596a86040273197e2e3aaa504939cd01974f58e1034ce747049139ee4a7d65ee6721ed948e22417521e61 SHA512 b94783211bbbd5ecf0d39018af7e5f5ad8b64926c694c2b55efb208dc789bd0bcf379733a153e398905024b455acf962c284d7e4cfff7090211382284bdf2655
 DIST pycpio-0.6.1.tar.gz 17236 BLAKE2B 4951ba3b7ad2fe603eb1cc07c851349de2ad73985ad1b2efcdb138f2ba26c43040a09d036ef993a28190b381af58bb8dc2e876ed1dff309ac010b69341a8c881 SHA512 49386b45172b13ecdeb040b719eaae0f17e5cbf7d68d3dcbcec99e01bfb3c539b8b02a768da640f56bb8941e79053c56e391b7186c9a5e5226d91fbdc55eeb11
+DIST pycpio-0.7.0.tar.gz 17942 BLAKE2B 760bfec68fe77ac9495a01fd8481e7f7a88fce0be983e60220bba66e12b104214117fd0e18e362bf1fc7a367226a5c874940fa43c23f7fee2bb39f76ec4a2ccb SHA512 4730083295e0bde39651d323507d12adef6b27e2cde095e281c76f4b6f20262eaa40cf31eb900d6818a7266b3b21c6159a334fd088249a55d054e277200ffaaa
diff --git a/dev-python/pycpio/pycpio-0.6.0.ebuild b/dev-python/pycpio/pycpio-0.7.0.ebuild
index 5c0bc22c0251..5c0bc22c0251 100644
--- a/dev-python/pycpio/pycpio-0.6.0.ebuild
+++ b/dev-python/pycpio/pycpio-0.7.0.ebuild
diff --git a/dev-python/pylev/metadata.xml b/dev-python/pylev/metadata.xml
index 12cb1059a8c1..ea8988e8af6a 100644
--- a/dev-python/pylev/metadata.xml
+++ b/dev-python/pylev/metadata.xml
@@ -1,10 +1,6 @@
 <?xml version="1.0" encoding="UTF-8"?>
 <!DOCTYPE pkgmetadata SYSTEM "https://liguros.gitlab.io/dtd/metadata.dtd">
 <pkgmetadata>
- <maintainer type="person">
-  <email>jsmolic@gentoo.org</email>
-  <name>Jakov Smolić</name>
- </maintainer>
  <maintainer type="project">
   <email>python@gentoo.org</email>
   <name>Python</name>
diff --git a/dev-python/pymdown-extensions/Manifest b/dev-python/pymdown-extensions/Manifest
index 5a8a3162b95a..48d80c7ade70 100644
--- a/dev-python/pymdown-extensions/Manifest
+++ b/dev-python/pymdown-extensions/Manifest
@@ -1 +1,2 @@
 DIST pymdown_extensions-10.5.tar.gz 788318 BLAKE2B cf6834a848a0276d636b75df33c3ec0bcc0988a02b2d9d7d2086a0104a3f105e080fa2acaab36c010f997f351c89c61adb165152ee3b0467ee8a41da71603abf SHA512 f574fe45a8b8b30ad51e1f6b1a1ce60a65a10e560f9f5c6db6a487309acf2d65e28d79c7edad4f58192ddbda9546fd50e279e08efcbc1c2eb707de0a84696225
+DIST pymdown_extensions-10.6.tar.gz 790597 BLAKE2B 6ed0ed82771d1e6e9aaf2bf0c005aeaa8da41af5b48c1ba385f0c46c9af986c039518a9576192126a584007b23b7689b70849fdd2b590fac9b31a6a042a710e3 SHA512 ae081621fc090eb9de0a92b265f43eb355c09a595098301d2d64f6d2cd7129c14264450162b24bf41076da3a64a5151b5db3fad85a33ff23120b2aa3a775efc6
diff --git a/dev-python/pymdown-extensions/pymdown-extensions-10.6.ebuild b/dev-python/pymdown-extensions/pymdown-extensions-10.6.ebuild
new file mode 100644
index 000000000000..93b704c670cf
--- /dev/null
+++ b/dev-python/pymdown-extensions/pymdown-extensions-10.6.ebuild
@@ -0,0 +1,32 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYTHON_COMPAT=( python3_{8,9,10,11,12} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Extensions for Python Markdown"
+HOMEPAGE="
+	https://github.com/facelessuser/pymdown-extensions/
+	https://pypi.org/project/pymdown-extensions/
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~x86"
+
+RDEPEND="
+	>=dev-python/markdown-3.5[${PYTHON_USEDEP}]
+	dev-python/pyyaml[${PYTHON_USEDEP}]
+"
+
+BDEPEND="
+	test? (
+		>=dev-python/pygments-2.12.0[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
diff --git a/dev-python/tornado/Manifest b/dev-python/tornado/Manifest
index 7e493f18839f..17479fd3986d 100644
--- a/dev-python/tornado/Manifest
+++ b/dev-python/tornado/Manifest
@@ -1,2 +1 @@
-DIST tornado-6.3.3.tar.gz 509872 BLAKE2B 575928b932a912515730b23ab712d6107b27ccb37c703be722768442093d47623e27ed31f60816c4031cd04354182796275619f27896d970e350dbb51a341b0a SHA512 3d4b0f933f09b8f8d5de5f93662de73d97a0ed98f5b56e0810d803d537092c74e89315dc9aaa0af85f91e18eca64cf429f6f73bce29523ce56738398fa24a597
 DIST tornado-6.4.tar.gz 498845 BLAKE2B ebcdcfa93490107addfe69f722e2d85058a92fc366b09a4794a4d6e0a93040ef9791095a5a94d21937d4e88dea09521644cf92d0f2c7e98238dc58e6b864a009 SHA512 c063509d4c385e410c63cccdc1e9c66aa2bb739473667ede56cb801b7379b910c8059dec831d609109f3076222b588b257afd960dffa422d7a872867dcdda7c7
diff --git a/dev-python/tornado/tornado-6.3.3.ebuild b/dev-python/tornado/tornado-6.3.3.ebuild
deleted file mode 100644
index 8f42c4320f6b..000000000000
--- a/dev-python/tornado/tornado-6.3.3.ebuild
+++ /dev/null
@@ -1,75 +0,0 @@
-# Copyright 1999-2023 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-DISTUTILS_EXT=1
-DISTUTILS_USE_PEP517=setuptools
-PYTHON_COMPAT=( python3_{8,9,10,11,12} pypy3 )
-PYTHON_REQ_USE="threads(+)"
-
-inherit distutils-r1 pypi
-
-DESCRIPTION="Python web framework and asynchronous networking library"
-HOMEPAGE="
-	https://www.tornadoweb.org/
-	https://github.com/tornadoweb/tornado/
-	https://pypi.org/project/tornado/
-"
-
-LICENSE="Apache-2.0"
-SLOT="0"
-KEYWORDS="~alpha amd64 arm arm64 hppa ~ia64 ~loong ~m68k ppc ppc64 ~riscv ~s390 sparc x86 ~amd64-linux ~x86-linux ~arm64-macos ~x64-macos"
-IUSE="examples test"
-RESTRICT="!test? ( test )"
-
-RDEPEND="
-	>=dev-python/twisted-16.0.0[${PYTHON_USEDEP}]
-"
-BDEPEND="
-	test? (
-		${RDEPEND}
-		$(python_gen_cond_dep '
-			>=dev-python/pycurl-7.19.3.1[${PYTHON_USEDEP}]
-		' 'python*')
-	)
-"
-
-PATCHES=(
-	"${FILESDIR}"/${PN}-6.3.2-test-timeout-increase.patch
-	"${FILESDIR}"/${PN}-6.3.2-ignore-deprecationwarning.patch
-)
-
-src_prepare() {
-	# network-sandbox? ipv6?
-	sed -i -e 's:test_localhost:_&:' \
-		tornado/test/netutil_test.py || die
-	# regressions with py3.12, not important enough to block us
-	sed -e 's:test_chunked(:_&:' \
-		-e 's:test_gzip:_&:' \
-		-e 's:test_header_callback:_&:' \
-		-i tornado/test/{curl_,simple_,}httpclient_test.py || die
-
-	distutils-r1_src_prepare
-}
-
-python_test() {
-	local -x ASYNC_TEST_TIMEOUT=60
-	# Avoid time-sensitive tests
-	# https://github.com/tornadoweb/tornado/blob/10974e6ebee80a26a2a65bb9bd715cf858fafde5/tornado/test/util.py#L19
-	local -x TRAVIS=1
-	local -x NO_NETWORK=1
-
-	cd "${T}" || die
-	"${EPYTHON}" -m tornado.test.runtests --verbose ||
-		die "tests failed under ${EPYTHON}"
-}
-
-python_install_all() {
-	if use examples; then
-		docinto examples
-		dodoc -r demos/.
-		docompress -x /usr/share/doc/${PF}/examples
-	fi
-	distutils-r1_python_install_all
-}
diff --git a/dev-python/tornado/tornado-6.4.ebuild b/dev-python/tornado/tornado-6.4.ebuild
index 730b73733f74..2b834d2b0311 100644
--- a/dev-python/tornado/tornado-6.4.ebuild
+++ b/dev-python/tornado/tornado-6.4.ebuild
@@ -19,7 +19,7 @@ HOMEPAGE="
 
 LICENSE="Apache-2.0"
 SLOT="0"
-KEYWORDS="~alpha amd64 arm arm64 ~hppa ~ia64 ~loong ~m68k ppc ppc64 ~riscv ~s390 sparc x86 ~amd64-linux ~x86-linux ~arm64-macos ~x64-macos"
+KEYWORDS="~alpha amd64 arm arm64 hppa ~ia64 ~loong ~m68k ppc ppc64 ~riscv ~s390 sparc x86 ~amd64-linux ~x86-linux ~arm64-macos ~x64-macos"
 IUSE="test"
 RESTRICT="!test? ( test )"