Adding metadata

7 files changed, 346 insertions, 0 deletions

diff --git a/dev-util/devscripts/Manifest b/dev-util/devscripts/Manifest
new file mode 100644
index 000000000000..8bfe80aaf88e
--- /dev/null
+++ b/dev-util/devscripts/Manifest
@@ -0,0 +1,2 @@
+DIST devscripts_2.21.3.tar.xz 980408 BLAKE2B 99207ed58c0fdc592ce491ddda79a2ecb22a8975ef70828749bf58dff9cc94f63779025b3f0326d0c2c49ca768a7e651b1f9e7843e6da298c25340916334de25 SHA512 84122dd36de7961c26044ac8b8eeee2c0aae1dd4a811b5f0d522fe43488dad2872aa044ad1f38a78e49f9d13d8c19eb583a8082d636caeebb188f1dd4f1caec7
+DIST devscripts_2.22.1.tar.xz 989556 BLAKE2B 2a2e3ca9757c710e181e807f0369c137f21070d86b4c51d8b5132ca4add33677edbd26e04a2faae93e9e4586080286888880ce450119579aa40ad205c8e5d857 SHA512 260603e1a655035c5aca3c9734db1bc6aa7e9aa017ece7e9158c57e06a1ee548922ec2defdd9dcb4560743d78aef08d30695b1bc833bd4d77fe1c7497d157c45
diff --git a/dev-util/devscripts/devscripts-2.21.3.ebuild b/dev-util/devscripts/devscripts-2.21.3.ebuild
new file mode 100644
index 000000000000..620ffd24732e
--- /dev/null
+++ b/dev-util/devscripts/devscripts-2.21.3.ebuild
@@ -0,0 +1,120 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_OPTIONAL=true
+PYTHON_COMPAT=( python3_{7,8,9,10} )
+
+inherit distutils-r1
+
+DESCRIPTION="Scripts to make the life of a Debian Package maintainer easier"
+HOMEPAGE="https://salsa.debian.org/debian/devscripts"
+SRC_URI="mirror://debian/pool/main/d/${PN}/${PN}_${PV}.tar.xz"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="python test"
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+RESTRICT="!test? ( test )"
+
+CDEPEND="
+	dev-lang/perl:=
+	dev-perl/File-DesktopEntry
+	dev-perl/File-DirList
+	dev-perl/File-HomeDir
+	dev-perl/File-Touch
+	dev-perl/IPC-Run
+	dev-perl/Moo
+	dev-perl/libwww-perl
+	dev-util/distro-info
+	python? ( ${PYTHON_DEPS} )
+"
+DEPEND="${CDEPEND}
+	test? (
+		app-arch/zip
+		dev-perl/Git-Wrapper
+		dev-perl/GitLab-API-v4
+		dev-perl/List-Compare
+		dev-perl/Software-License
+		dev-perl/String-ShellQuote
+		dev-perl/UNIVERSAL-require
+		dev-python/pyftpdlib[${PYTHON_USEDEP}]
+		dev-python/python-debian[${PYTHON_USEDEP}]
+		dev-util/shunit2
+		dev-vcs/subversion
+		sys-libs/libfaketime
+		virtual/perl-DB_File
+	)
+"
+RDEPEND="${CDEPEND}
+	app-arch/dpkg
+	app-crypt/gnupg
+	app-text/wdiff
+	dev-util/debhelper
+	dev-util/patchutils
+	sys-apps/fakeroot
+"
+BDEPEND="virtual/pkgconfig"
+
+PATCHES=(
+	"${FILESDIR}/distutils-r1.patch"
+	"${FILESDIR}/Remove-failing-tests.patch"
+	"${FILESDIR}/Replace-Debian-xsl-stylesheets-paths-with-Gentoos.patch"
+)
+
+DISTUTILS_S="${S}"/scripts
+
+src_prepare() {
+	default
+
+	# Avoid file collision with app-shells/bash-completion
+	rm "${DISTUTILS_S}"/bts.bash_completion || die
+}
+
+src_configure() {
+	default
+
+	if use python; then
+		pushd "${DISTUTILS_S}" > /dev/null || die
+		distutils-r1_src_configure
+		popd > /dev/null || die
+	fi
+}
+
+src_compile() {
+	default
+
+	if use python; then
+		pushd "${DISTUTILS_S}" > /dev/null || die
+		distutils-r1_src_compile
+		popd > /dev/null || die
+	fi
+}
+
+src_install() {
+	dodir /usr/bin
+	default
+
+	if use python; then
+		pushd "${DISTUTILS_S}" > /dev/null || die
+		distutils-r1_src_install
+		popd > /dev/null || die
+	fi
+
+	mv "${ED}"/usr/share/doc/${PN} "${ED}"/usr/share/doc/${PF} || die
+
+	# "incorrect name, no completions for command defined"
+	rm "${ED}"/usr/share/bash-completion/completions/{debcheckout,pkgnames} || die
+}
+
+src_test() {
+	default
+
+	if use python; then
+		pushd "${DISTUTILS_S}" > /dev/null || die
+		distutils-r1_src_test
+		popd > /dev/null || die
+	fi
+}
diff --git a/dev-util/devscripts/devscripts-2.22.1.ebuild b/dev-util/devscripts/devscripts-2.22.1.ebuild
new file mode 100644
index 000000000000..e1874803bbd6
--- /dev/null
+++ b/dev-util/devscripts/devscripts-2.22.1.ebuild
@@ -0,0 +1,125 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_OPTIONAL=true
+PYTHON_COMPAT=( python3_{7,8,9,10} )
+
+inherit bash-completion-r1 distutils-r1
+
+DESCRIPTION="Scripts to make the life of a Debian Package maintainer easier"
+HOMEPAGE="https://salsa.debian.org/debian/devscripts"
+SRC_URI="mirror://debian/pool/main/d/${PN}/${PN}_${PV}.tar.xz"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="python test"
+
+CDEPEND="
+	dev-lang/perl:=
+	dev-perl/File-DesktopEntry
+	dev-perl/File-DirList
+	dev-perl/File-HomeDir
+	dev-perl/File-Touch
+	dev-perl/IPC-Run
+	dev-perl/Moo
+	dev-perl/libwww-perl
+	dev-util/distro-info
+	python? ( ${PYTHON_DEPS} )
+"
+DEPEND="
+	${CDEPEND}
+	app-text/docbook-xsl-stylesheets
+	test? (
+		app-arch/zip
+		dev-perl/Git-Wrapper
+		dev-perl/GitLab-API-v4
+		dev-perl/List-Compare
+		dev-perl/Software-License
+		dev-perl/String-ShellQuote
+		dev-perl/UNIVERSAL-require
+		dev-python/pyftpdlib[${PYTHON_USEDEP}]
+		dev-python/python-debian[${PYTHON_USEDEP}]
+		dev-util/shunit2
+		dev-vcs/subversion
+		sys-libs/libfaketime
+		virtual/perl-DB_File
+	)
+"
+RDEPEND="
+	${CDEPEND}
+	app-arch/dpkg
+	app-crypt/gnupg
+	app-text/wdiff
+	dev-util/debhelper
+	dev-util/patchutils
+	sys-apps/fakeroot
+"
+BDEPEND="virtual/pkgconfig"
+
+REQUIRED_USE="
+	python? ( ${PYTHON_REQUIRED_USE} )
+	test? ( python )
+"
+RESTRICT="!test? ( test )"
+PATCHES=(
+	"${FILESDIR}/distutils-r1.patch"
+	"${FILESDIR}/Remove-failing-tests.patch"
+	"${FILESDIR}/Replace-Debian-xsl-stylesheets-paths-with-Gentoos.patch"
+)
+
+DISTUTILS_S="${S}/scripts"
+
+src_prepare() {
+	default
+
+	# Avoid file collision with app-shells/bash-completion
+	rm "${DISTUTILS_S}/bts.bash_completion" || die
+}
+
+src_configure() {
+	default
+
+	if use python; then
+		pushd "${DISTUTILS_S}" > /dev/null || die
+		python_foreach_impl distutils-r1_src_configure
+		popd > /dev/null || die
+	fi
+}
+
+src_compile() {
+	default
+
+	if use python; then
+		pushd "${DISTUTILS_S}" > /dev/null || die
+		python_foreach_impl distutils-r1_src_compile
+		popd > /dev/null || die
+	fi
+}
+
+src_install() {
+	dodir /usr/bin
+	default
+
+	if use python; then
+		pushd "${DISTUTILS_S}" > /dev/null || die
+		python_foreach_impl distutils-r1_src_install
+		popd > /dev/null || die
+	fi
+
+	mv "${ED}/usr/share/doc/${PN}" "${ED}/usr/share/doc/${PF}" || die
+
+	rm "${ED}/usr/share/bash-completion/completions/debcheckout" || die
+	mv "${ED}"/usr/share/bash-completion/completions/{pkgnames,debsnap} || die
+	bashcomp_alias debsnap wnpp-alert wnpp-check mk-build-deps rmadison mass-bug dd-list build-rdeps who-uploads transition-check getbuildlog grep-excuses rc-alert whodepends dget pts-subscribe pts-unsubscribe
+}
+
+src_test() {
+	default
+
+	pushd "${DISTUTILS_S}" > /dev/null || die
+	python_foreach_impl distutils-r1_src_test
+	popd > /dev/null || die
+}
diff --git a/dev-util/devscripts/files/Remove-failing-tests.patch b/dev-util/devscripts/files/Remove-failing-tests.patch
new file mode 100644
index 000000000000..ed0726a905c2
--- /dev/null
+++ b/dev-util/devscripts/files/Remove-failing-tests.patch
@@ -0,0 +1,22 @@
+--- a/test/Makefile
++++ b/test/Makefile
+@@ -3,14 +3,14 @@
+ 	perl \
+ 	annotate-output \
+ 	checkbashisms \
+-	dd-list \
++	 \
+ 	debchange \
+ 	debdiff \
+-	debrepro \
++	 \
+ 	debsign \
+ 	mergechanges \
+-	mk-origtargz \
++	 \
+-	package_lifecycle \
++	 \
+-	sadt \
++	 \
+ 	uscan \
+ 	uscan_ftp \
diff --git a/dev-util/devscripts/files/Replace-Debian-xsl-stylesheets-paths-with-Gentoos.patch b/dev-util/devscripts/files/Replace-Debian-xsl-stylesheets-paths-with-Gentoos.patch
new file mode 100644
index 000000000000..6b7294041800
--- /dev/null
+++ b/dev-util/devscripts/files/Replace-Debian-xsl-stylesheets-paths-with-Gentoos.patch
@@ -0,0 +1,42 @@
+--- a/po4a/Makefile
++++ b/po4a/Makefile
+@@ -34,8 +34,8 @@
+ 	pod2man --utf8 --center=" " --release="$(DESC_$(dir $@))" $< > $@
+ %.1:: %.dbk translate
+ 	xsltproc --nonet \
+-	  /usr/share/sgml/docbook/stylesheet/xsl/nwalsh/manpages/docbook.xsl $<
+-	# /usr/share/sgml/docbook/stylesheet/xsl/nwalsh/manpages/other.xsl
++	  /usr/share/sgml/docbook/xsl-stylesheets/manpages/docbook.xsl $<
++	# /usr/share/sgml/docbook/xsl-stylesheets/manpages/other.xsl
+ 	# (which is imported by the above stylesheet) insists in writing the output
+ 	# to where it wants to.  we can only move the file ourselves.
+ 	# ($* → de/deb-reversion.de)
+--- a/scripts/deb-reversion.dbk
++++ b/scripts/deb-reversion.dbk
+@@ -5,13 +5,13 @@
+ <!--
+ 
+ Process this file with an XSLT processor: `xsltproc \
+--''-nonet /usr/share/sgml/docbook/stylesheet/xsl/nwalsh/\
++-''-nonet /usr/share/sgml/docbook/xsl-stylesheets/\
+ manpages/docbook.xsl manpage.dbk'.  A manual page
+ <package>.<section> will be generated.  You may view the
+ manual page with: nroff -man <package>.<section> | less'.  A
+ typical entry in a Makefile or Makefile.am is:
+ 
+-DB2MAN=/usr/share/sgml/docbook/stylesheet/xsl/nwalsh/\
++DB2MAN=/usr/share/sgml/docbook/xsl-stylesheets/\
+ manpages/docbook.xsl
+ XP=xsltproc -''-nonet
+ 
+--- a/scripts/Makefile
++++ b/scripts/Makefile
+@@ -87,7 +87,7 @@
+ 	pod2man --utf8 --center=" " --release="Debian Utilities" $< > $@
+ %.1: %.dbk
+ 	xsltproc --nonet -o $@ \
+-	  /usr/share/sgml/docbook/stylesheet/xsl/nwalsh/manpages/docbook.xsl $<
++	  /usr/share/sgml/docbook/xsl-stylesheets/manpages/docbook.xsl $<
+ 
+ # Syntax checker
+ test_sh: $(SH_CHECKS)
diff --git a/dev-util/devscripts/files/distutils-r1.patch b/dev-util/devscripts/files/distutils-r1.patch
new file mode 100644
index 000000000000..7b6b526f0bb3
--- /dev/null
+++ b/dev-util/devscripts/files/distutils-r1.patch
@@ -0,0 +1,26 @@
+--- a/scripts/Makefile
++++ b/scripts/Makefile
+@@ -99,7 +99,6 @@
+ 	perl -I ../lib -c $<; \
+ 
+ test_py: $(VERSION_FILE)
+-	$(foreach python,$(shell py3versions -r ../debian/control),$(python) setup.py test$(\n))
+ 
+ debbisect.1: debbisect
+ 	help2man \
+@@ -131,7 +130,6 @@
+ 	cp $< $@
+ 
+ clean:
+-	python3 setup.py clean -a
+ 	find -name '*.pyc' -delete
+ 	find -name __pycache__ -delete
+ 	rm -rf devscripts.egg-info $(BC_BUILD_DIR) .pylint.d
+@@ -142,7 +140,6 @@
+ test: test_pl test_sh test_py
+ 
+ install: all
+-	python3 setup.py install --root="$(DESTDIR)" --no-compile --install-layout=deb
+ 	cp $(SCRIPTS) $(DESTDIR)$(BINDIR)
+ 	ln -sf edit-patch $(DESTDIR)$(BINDIR)/add-patch
+ 	install -d $(DESTDIR)$(COMPL_DIR)
diff --git a/dev-util/devscripts/metadata.xml b/dev-util/devscripts/metadata.xml
new file mode 100644
index 000000000000..d2b2c8ce9f88
--- /dev/null
+++ b/dev-util/devscripts/metadata.xml
@@ -0,0 +1,9 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="person">
+		<description>co-maintainers welcome</description>
+		<email>lssndrbarbieri@gmail.com</email>
+		<name>Alessandro Barbieri</name>
+	</maintainer>
+</pkgmetadata>