Updating liguros repo

4 files changed, 157 insertions, 0 deletions

diff --git a/dev-util/eric/Manifest b/dev-util/eric/Manifest
new file mode 100644
index 000000000000..27009a0fbd21
--- /dev/null
+++ b/dev-util/eric/Manifest
@@ -0,0 +1,2 @@
+DIST eric6-18.03.tar.gz 16517664 BLAKE2B f7f5292df8bc694fc4715ec1a250d948123a2eb99a590e6824d985318446babff86aeb745f5b5dbd0707e771638eaa943673e5b546676bea97e266888b844989 SHA512 e488010791b44cc7da782620baec9b97259aaefeb90d491023ec1d4582fb68acbc06d9eedba7beef9ddc706302e06e36b9ebb4e46d6f035b6c74e9f4eb9ac400
+DIST eric6-19.11.tar.gz 16241807 BLAKE2B bd8284164c6c191e91fc08bc42f594107ebab50f71a980ef331d42fbd8d9c488d5674b2f53665718a6e723a228e838d082095fc3c3b2d40c3fb350c5be9a98ee SHA512 a8305c5185687d62231926bd4c484f3786ac1c20d125a1f8fb1b6bc0d42c57ba92bf00aaffd8699f8d7594c6432896bef8db13da85513ba4f217a60223f2f533
diff --git a/dev-util/eric/eric-18.03.ebuild b/dev-util/eric/eric-18.03.ebuild
new file mode 100644
index 000000000000..f766811e82e4
--- /dev/null
+++ b/dev-util/eric/eric-18.03.ebuild
@@ -0,0 +1,82 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+MY_P=${PN}6-${PV}
+PYTHON_COMPAT=( python3_6 )
+PYTHON_REQ_USE="sqlite,xml"
+inherit python-single-r1 xdg-utils
+
+DESCRIPTION="A full featured Python IDE using PyQt and QScintilla"
+HOMEPAGE="https://eric-ide.python-projects.org/"
+SRC_URI="mirror://sourceforge/eric-ide/${PN}6/stable/${PV}/${MY_P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="6"
+KEYWORDS="~amd64 ~ppc64 ~x86"
+IUSE=""
+
+DEPEND="
+	${PYTHON_DEPS}
+	$(python_gen_cond_dep '
+		>=dev-python/sip-4.14.3[${PYTHON_MULTI_USEDEP}]
+		>=dev-python/PyQt5-5.7.1[gui,network,printsupport,sql,svg,widgets,${PYTHON_MULTI_USEDEP}]
+		>=dev-python/qscintilla-python-2.10[qt5(+),${PYTHON_MULTI_USEDEP}]
+	')
+"
+RDEPEND="${DEPEND}
+	$(python_gen_cond_dep '
+		|| (
+			dev-python/PyQt5[help,webengine,${PYTHON_MULTI_USEDEP}]
+			dev-python/PyQt5[help,webkit,${PYTHON_MULTI_USEDEP}]
+		)
+		>=dev-python/chardet-3.0.4[${PYTHON_MULTI_USEDEP}]
+		>=dev-python/coverage-4.1.0[${PYTHON_MULTI_USEDEP}]
+		>=dev-python/pygments-2.2.0[${PYTHON_MULTI_USEDEP}]
+	')
+	!dev-util/eric:4
+	!dev-util/eric:5
+"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+S=${WORKDIR}/${MY_P}
+
+DOCS=( changelog README.rst THANKS )
+
+src_prepare() {
+	default
+
+	# Delete internal copies of dev-python/chardet and dev-python/pygments
+	rm -fr eric/ThirdParty/{CharDet,Pygments} || die
+
+	# Delete internal copy of dev-python/coverage
+	rm -fr eric/DebugClients/Python{,3}/coverage || die
+	sed -i -e 's/from DebugClients\.Python3\?\.coverage/from coverage/' \
+		$(grep -lr 'from DebugClients\.Python3\?\.coverage' .) || die
+}
+
+src_install() {
+	"${PYTHON}" install.py \
+		-b "${EPREFIX}/usr/bin" \
+		-d "$(python_get_sitedir)" \
+		-i "${D}" \
+		-c \
+		-z \
+		|| die
+
+	python_optimize
+	einstalldocs
+}
+
+pkg_postinst() {
+	xdg_desktop_database_update
+
+	if ! has_version dev-python/enchant; then
+		elog "You might want to install dev-python/pyenchant for spell checking."
+	fi
+}
+
+pkg_postrm() {
+	xdg_desktop_database_update
+}
diff --git a/dev-util/eric/eric-19.11-r1.ebuild b/dev-util/eric/eric-19.11-r1.ebuild
new file mode 100644
index 000000000000..bb8cee447042
--- /dev/null
+++ b/dev-util/eric/eric-19.11-r1.ebuild
@@ -0,0 +1,61 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7} )
+PYTHON_REQ_USE="sqlite,xml"
+inherit python-single-r1 xdg
+
+MY_P=${PN}6-${PV}
+
+DESCRIPTION="A full featured Python IDE using PyQt and QScintilla"
+HOMEPAGE="https://eric-ide.python-projects.org/"
+SRC_URI="mirror://sourceforge/eric-ide/${PN}6/stable/${PV}/${MY_P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="6"
+KEYWORDS="~amd64 ~x86"
+IUSE="spell"
+
+DEPEND="
+	${PYTHON_DEPS}
+	$(python_gen_cond_dep '
+		>=dev-python/PyQt5-5.12[gui,help,network,printsupport,sql,svg,widgets,${PYTHON_MULTI_USEDEP}]
+		dev-python/PyQtWebEngine[${PYTHON_MULTI_USEDEP}]
+		dev-python/qscintilla-python[${PYTHON_MULTI_USEDEP}]
+		dev-python/sip[${PYTHON_MULTI_USEDEP}]
+	')
+"
+RDEPEND="${DEPEND}
+	$(python_gen_cond_dep '
+		>=dev-python/chardet-3.0.4[${PYTHON_MULTI_USEDEP}]
+		>=dev-python/pygments-2.3.1[${PYTHON_MULTI_USEDEP}]
+		spell? ( dev-python/pyenchant[${PYTHON_MULTI_USEDEP}] )
+	')
+"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+S=${WORKDIR}/${MY_P}
+
+DOCS=( eric/docs/{changelog,README.rst,README-eric6-doc.rst,README-passive-debugging.rst,THANKS} )
+
+src_prepare() {
+	default
+
+	# Delete internal copies of dev-python/chardet and dev-python/pygments
+	rm -fr eric/eric6/ThirdParty/{CharDet,Pygments} || die
+}
+
+src_install() {
+	yes n | "${PYTHON}" install.py \
+		-b "${EPREFIX}/usr/bin" \
+		-d "$(python_get_sitedir)" \
+		-i "${D}" \
+		-c \
+		-z \
+		|| die
+
+	python_optimize
+	einstalldocs
+}
diff --git a/dev-util/eric/metadata.xml b/dev-util/eric/metadata.xml
new file mode 100644
index 000000000000..106b71e3454b
--- /dev/null
+++ b/dev-util/eric/metadata.xml
@@ -0,0 +1,12 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="project">
+		<email>qt@gentoo.org</email>
+		<name>Gentoo Qt Project</name>
+	</maintainer>
+	<upstream>
+		<remote-id type="sourceforge">eric-ide</remote-id>
+	</upstream>
+	<origin>gentoo-staging</origin>
+</pkgmetadata>