Publish srcux candidate 0000000640-20261012-030307

7 files changed, 261 insertions, 2 deletions

diff --git a/dev-util/cargo-c/Manifest b/dev-util/cargo-c/Manifest
index 22e6ce2c4b48..4d56473fd208 100644
--- a/dev-util/cargo-c/Manifest
+++ b/dev-util/cargo-c/Manifest
@@ -20,3 +20,5 @@ DIST cargo-c-0.10.23-crates.tar.xz 40352456 BLAKE2B 1d6dc199a8fe2a266b43bfaf1b0b
 DIST cargo-c-0.10.23.tar.gz 38076 BLAKE2B cea92b666d3237d706e746ad97792f4400672dfa284ed4fad06c3e204f47f8a789a69aa2b4dc9753def4cf6140648a717629021de4b97c0afb6e31ce1c9645fb SHA512 c979e3f2ed549d34a00a63afc031b2bc3eaee910523a398af492fcad5633dfcada47850b2b9e5af667fc6ba40447649016f48438c37fc1d360aa670d803dce09
 DIST cargo-c-0.10.25-crates.tar.xz 33240352 BLAKE2B 2e8032afada834cd129f7794862f38ae674ff68938cff363a85859d8c165042fbf29bbdcfa9be515e5aa989eabf6dc350582dcde2c97bbd3b9cd0f367c87cfca SHA512 6b267e094d730c36372decbc1d5e2583a37d286bb085ec8b7e7b348cc27d3cfd16a31527b9ccdbcc5da8b01fcf47e8b0ccbd95b88d003eed3330347e7c5845a4
 DIST cargo-c-0.10.25.tar.gz 41486 BLAKE2B 48e69c2a64ffb49fae54340a8e1f9f2448d28d7d14b9b5c2390be2ebf5e601244d9d4c051cae64849564b653b34c07b4f396cfbda483babd6d6c45fce67cb752 SHA512 d4825463fbb49a42d3298d0ab4fbc4c34f518985aa16f5e2884cda676e8ae34102c2e677f2ec19d578ff7db73266b0075636eb65d3f1bac0aa41bafd89d20628
+DIST cargo-c-0.10.26-crates.tar.xz 33177500 BLAKE2B 852a28ea8a5afb6439af746334d330e0b653452516243207dd30c8343cd31708b6536b178a9e873921a88a16368452d467c3b6752c3169ef05762288e8386105 SHA512 d315d0ca4333df448179222363f08d7ec697da1bf4f42e2dc37bea34211e82e6520e72e42f2dd89c308de2a903f2d2d0cf4fe1b5d0f1014827030fcc80950ad8
+DIST cargo-c-0.10.26.tar.gz 41528 BLAKE2B 30ba00b7a0c543ca841a4dcb4d41018375031d44381fcbd0d6feaeeac989b874a303023ea752001ccf311bdf050360a4b77410efa099dffae13ac5a9d6a24430 SHA512 42fbc2c35c929020ab6d208fbb31216541a7df68df99bba6ca0a422934ecffbbb350b258ee118d5db8557d5bf5d27606f8d23a460c8c08304a237915640548f6
diff --git a/dev-util/cargo-c/cargo-c-0.10.26.ebuild b/dev-util/cargo-c/cargo-c-0.10.26.ebuild
new file mode 100644
index 000000000000..b25b56951307
--- /dev/null
+++ b/dev-util/cargo-c/cargo-c-0.10.26.ebuild
@@ -0,0 +1,58 @@
+# Copyright 2022-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+# Auto-Generated by cargo-ebuild 0.5.4
+
+EAPI=8
+
+# Only bother defining this if the github tarball doesn't work!
+# Otherwise just comment it out and things should Just Work (TM).
+#MY_P="${P}+cargo-{CARGO_V}"
+
+CRATES="
+"
+
+RUST_MIN_VER="1.97.0"
+
+inherit cargo
+
+DESCRIPTION="Helper program to build and install c-like libraries"
+HOMEPAGE="https://github.com/lu-zero/cargo-c"
+if [[ -z ${MY_P} ]] ; then
+	SRC_URI="https://github.com/lu-zero/cargo-c/archive/refs/tags/v${PV}.tar.gz -> ${P}.tar.gz"
+else
+	S="${WORKDIR}/${MY_P}"
+fi
+
+SRC_URI+="
+	https://github.com/gentoo-crate-dist/cargo-c/releases/download/v${PV}/${P}-crates.tar.xz
+"
+
+LICENSE="MIT"
+# Dependent crate licenses
+LICENSE+="
+	Apache-2.0 BSD-2 BSD ISC MIT MPL-2.0 MPL-2.0 Unicode-3.0 ZLIB
+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+RDEPEND="
+	>=dev-libs/libgit2-1.9.7:=
+	dev-libs/openssl:=
+	net-libs/libssh2:=
+	net-misc/curl[ssl]
+	virtual/zlib:=
+	dev-db/sqlite:3
+"
+DEPEND="${RDEPEND}"
+
+QA_FLAGS_IGNORED="usr/bin/cargo-capi usr/bin/cargo-cbuild usr/bin/cargo-ctest usr/bin/cargo-cinstall"
+
+src_configure() {
+	# Some crates will auto-build and statically link C libraries(!)
+	# Tracker bug #709568
+	export LIBSSH2_SYS_USE_PKG_CONFIG=1
+	export LIBGIT2_NO_VENDOR=1
+	export LIBSQLITE3_SYS_USE_PKG_CONFIG=1
+	export PKG_CONFIG_ALLOW_CROSS=1
+}
diff --git a/dev-util/cvise/cvise-2.12.0-r1.ebuild b/dev-util/cvise/cvise-2.12.0-r1.ebuild
index c9fc638be0b4..c2d46e1ede87 100644
--- a/dev-util/cvise/cvise-2.12.0-r1.ebuild
+++ b/dev-util/cvise/cvise-2.12.0-r1.ebuild
@@ -15,7 +15,7 @@ SRC_URI="
 
 LICENSE="UoI-NCSA"
 SLOT="0"
-KEYWORDS="~amd64 arm arm64 ~loong ~ppc ~ppc64 ~riscv ~sparc ~x86"
+KEYWORDS="~amd64 arm arm64 ~loong ppc ppc64 ~riscv ~sparc ~x86"
 IUSE="test"
 RESTRICT="!test? ( test )"
 REQUIRED_USE=${PYTHON_REQUIRED_USE}
diff --git a/dev-util/intel-graphics-compiler/Manifest b/dev-util/intel-graphics-compiler/Manifest
index 667b66b03dbb..3767b2495fb1 100644
--- a/dev-util/intel-graphics-compiler/Manifest
+++ b/dev-util/intel-graphics-compiler/Manifest
@@ -1,2 +1,3 @@
 DIST intel-graphics-compiler-2.37.1.tar.gz 12508039 BLAKE2B 9555401482133ab6efa6b214179d8c2986efe261c03613684f3db3b5f8482b53310f70682dc2fc7b69ae3d8dc6bb93c26a24a64a29b3b0069f4a860f86e50084 SHA512 27a69e8f08527d6a1f1f88a6b326d151da2806085a7c23984a8dc2d3edf33342005d4931ffc84a502b64b9f45405d50df856258caae4ff8372373cf434b7d659
 DIST intel-graphics-compiler-2.41.9.tar.gz 12952218 BLAKE2B 0471dab27e17a60e7c7c57ff22495532b4b5b083f33b8b7530bc20fd27769b55372746e6cadabd58e37bfcceb16139247e146b3c157f04780ea9153074d68e34 SHA512 f2decb6b8634d003816b403162407fc2884093914703fd2ad602855e67c07686ea94fdd301af74f7d41358d6e19f853350b5577678c8d40f17b2de66067c7882
+DIST intel-graphics-compiler-2.42.3.tar.gz 13106687 BLAKE2B 9aef4b15bc22ea519e2e6ab3e0955a2a2929f6081911196b566c3cb5653d3b1101ddfbec64b6b27f1ef0f0346d296e65a36bf0bbcf46e204ac7b02e024aee388 SHA512 5ddeff32f36af8bb19c5170b76b14b1e3863343c35b048792edc3ddfe6211bef2ede95e9a26d7117afbd1d95066b51eac5911544a140c59ea8d702c92b9d0efa
diff --git a/dev-util/intel-graphics-compiler/intel-graphics-compiler-2.42.3.ebuild b/dev-util/intel-graphics-compiler/intel-graphics-compiler-2.42.3.ebuild
new file mode 100644
index 000000000000..33940bfd45cd
--- /dev/null
+++ b/dev-util/intel-graphics-compiler/intel-graphics-compiler-2.42.3.ebuild
@@ -0,0 +1,110 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+CMAKE_BUILD_TYPE="Release"
+LLVM_COMPAT=( 22 )
+PYTHON_COMPAT=( python3_{13..14} )
+
+inherit cmake flag-o-matic llvm-r2 python-any-r1
+
+DESCRIPTION="LLVM-based OpenCL compiler for OpenCL targetting Intel Gen graphics hardware"
+HOMEPAGE="https://github.com/intel/intel-graphics-compiler"
+SRC_URI="https://github.com/intel/${PN}/archive/refs/tags/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0/${PV}"
+KEYWORDS="~amd64"
+IUSE="debug vc"
+
+DEPEND="
+	dev-libs/opencl-clang:22[${LLVM_USEDEP}]
+	>=dev-util/spirv-tools-1.4.363.0
+	$(llvm_gen_dep '
+		llvm-core/lld:${LLVM_SLOT}
+		llvm-core/llvm:${LLVM_SLOT}
+	')
+	vc? (
+		>=dev-libs/intel-vc-intrinsics-0.25.0[${LLVM_USEDEP}]
+		dev-util/spirv-llvm-translator:22=
+	)
+"
+
+RDEPEND="
+	!dev-util/intel-graphics-compiler:legacy
+	${DEPEND}
+"
+
+BDEPEND="
+	$(python_gen_any_dep 'dev-python/mako[${PYTHON_USEDEP}]')
+	$(python_gen_any_dep 'dev-python/pyyaml[${PYTHON_USEDEP}]')
+	$(llvm_gen_dep 'llvm-core/lld:${LLVM_SLOT}')
+	${PYTHON_DEPS}
+"
+
+python_check_deps() {
+	python_has_version "dev-python/mako[${PYTHON_USEDEP}]"
+	python_has_version "dev-python/pyyaml[${PYTHON_USEDEP}]"
+}
+
+PATCHES=(
+	"${FILESDIR}/${PN}-1.0.8365-disable-git.patch"
+	"${FILESDIR}/${PN}-2.30.1-Werror.patch"
+	"${FILESDIR}/${PN}-2.41.5-guard-debug.patch"
+)
+
+pkg_setup() {
+	llvm-r2_pkg_setup
+	python-any-r1_pkg_setup
+}
+
+src_prepare() {
+	# Don't hardcode FORTIFY_SOURCE
+	sed -e '/-D_FORTIFY_SOURCE=2/d' -i IGC/CMakeLists.txt || die
+
+	cmake_src_prepare
+}
+
+src_configure() {
+	# Get LLVM version
+	local llvm_version="$(best_version -d llvm-core/llvm:${LLVM_SLOT})"
+	local llvm_version="${llvm_version%%-r*}"
+
+	# See https://github.com/intel/intel-graphics-compiler/issues/212
+	append-ldflags -Wl,-z,undefs
+
+	# See bug #938519 and https://github.com/intel/intel-graphics-compiler/issues/362
+	filter-lto
+
+	# See bug #893370 and https://github.com/intel/intel-graphics-compiler/issues/282
+	append-flags -U_GLIBCXX_ASSERTIONS
+
+	# See https://bugs.gentoo.org/718824
+	! use debug && append-cppflags -DNDEBUG
+
+	local mycmakeargs=(
+		-DBUILD_SHARED_LIBS="OFF"
+		-DCCLANG_FROM_SYSTEM="ON"
+		-DCMAKE_LIBRARY_PATH="$(get_llvm_prefix)/$(get_libdir)"
+		-DIGC_BUILD__VC_ENABLED="$(usex vc)"
+		-DIGC_OPTION__ARCHITECTURE_TARGET="Linux64"
+		-DIGC_OPTION__CLANG_MODE="Prebuilds"
+		-DIGC_OPTION__ENABLE_BF16_BIF="ON"
+		-DIGC_OPTION__LINK_KHRONOS_SPIRV_TRANSLATOR="ON"
+		-DIGC_OPTION__LLD_MODE="Prebuilds"
+		-DIGC_OPTION__LLDELF_H_DIR="$(get_llvm_prefix)/include/lld/Common"
+		-DIGC_OPTION__LLVM_MODE="Prebuilds"
+		-DIGC_OPTION__LLVM_PREFERRED_VERSION="${llvm_version##*-}"
+		-DIGC_OPTION__OPENCL_HEADER_PATH="/usr/lib/clang/${LLVM_SLOT}/include/opencl-c.h"
+		-DIGC_OPTION__SPIRV_TOOLS_MODE="Prebuilds"
+		-DIGC_OPTION__SPIRV_TRANSLATOR_MODE="Prebuilds"
+		-DIGC_OPTION__USE_PREINSTALLED_SPIRV_HEADERS="ON"
+		$(usex vc '-DIGC_OPTION__VC_INTRINSICS_MODE=Prebuilds' '')
+		-DPYTHON_EXECUTABLE="${PYTHON}"
+		-DSPIRVLLVMTranslator_INCLUDE_DIR="${EPREFIX}/usr/lib/llvm/${LLVM_SLOT}/include/LLVMSPIRVLib"
+		-Wno-dev
+	)
+
+	cmake_src_configure
+}
diff --git a/dev-util/source-highlight/source-highlight-9999.ebuild b/dev-util/source-highlight/source-highlight-9999.ebuild
new file mode 100644
index 000000000000..e53da05cff33
--- /dev/null
+++ b/dev-util/source-highlight/source-highlight-9999.ebuild
@@ -0,0 +1,88 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit bash-completion-r1 flag-o-matic libtool optfeature autotools
+
+DESCRIPTION="Generate highlighted source code as an (x)html document"
+HOMEPAGE="https://www.gnu.org/software/src-highlite/source-highlight.html"
+
+LICENSE="GPL-3"
+SLOT="0"
+if [[ ${PV} == *9999* ]] ; then
+	inherit git-r3
+	EGIT_REPO_URI="https://https.git.savannah.gnu.org/git/src-highlite.git"
+else
+	SRC_URI="mirror://gnu/src-highlite/${P}.tar.gz"
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~x64-solaris"
+fi
+
+IUSE="doc static-libs test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="dev-libs/boost:="
+DEPEND="${RDEPEND}"
+BDEPEND="
+	sys-devel/bison
+	sys-devel/flex
+	test? ( dev-util/ctags )
+"
+
+src_prepare() {
+	default
+
+	[[ ${PV} == 9999 ]] && eautoreconf
+
+	if ! use doc; then
+		sed -i -e 's/ doc / /g' Makefile* || die
+	fi
+
+	# Although all unpatched libtools are probably broken, this one ignores LTO
+	# warning flags.
+	elibtoolize
+}
+
+src_configure() {
+	# Needs bison
+	unset YACC LEX
+
+	# Fails to build otherwise with some ambiguous refs
+	append-cxxflags -std=gnu++17
+
+	# ODR violations: https://savannah.gnu.org/bugs/index.php?65086
+	filter-lto
+
+	econf \
+		--without-bash-completion \
+		$(use_enable static-libs static) \
+		--with-boost="${EPREFIX}/usr" \
+		--with-boost-regex="boost_regex"
+}
+
+src_compile() {
+	local -x LD_LIBRARY_PATH="${S}/lib/srchilite/.libs/"
+	emake
+}
+
+src_test() {
+	local -x LD_LIBRARY_PATH="${S}/lib/srchilite/.libs/"
+	emake check
+}
+
+src_install() {
+	use doc && local HTML_DOCS=( doc/*.{html,css,java} )
+	default
+
+	# That's not how we want it
+	rm -rf "${ED}"/usr/share/{aclocal,doc} || die
+
+	# package provides .pc file
+	find "${D}" -name '*.la' -delete || die
+
+	dobashcomp completion/source-highlight
+}
+
+pkg_postinst() {
+	optfeature "ctags support" dev-util/ctags
+}
diff --git a/dev-util/tree-sitter-cli/tree-sitter-cli-0.27.0.ebuild b/dev-util/tree-sitter-cli/tree-sitter-cli-0.27.0.ebuild
index 70b27ace6644..333a4f97afff 100644
--- a/dev-util/tree-sitter-cli/tree-sitter-cli-0.27.0.ebuild
+++ b/dev-util/tree-sitter-cli/tree-sitter-cli-0.27.0.ebuild
@@ -27,7 +27,7 @@ LICENSE+="
 	MIT Unicode-3.0 ZLIB
 "
 SLOT="0"
-KEYWORDS="~amd64 ~arm ~arm64 ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+KEYWORDS="amd64 arm arm64 ~loong ~mips ppc ppc64 ~riscv ~s390 ~sparc x86"
 
 # Test seems to require files (grammar definitions) that we don't have.
 RESTRICT="test"