1 files changed, 46 insertions, 0 deletions
diff --git a/dev-cpp/tree/tree-3.18-r1.ebuild b/dev-cpp/tree/tree-3.18-r1.ebuild
new file mode 100644
index 000000000000..8e80f85b9080
--- /dev/null
+++ b/dev-cpp/tree/tree-3.18-r1.ebuild
@@ -0,0 +1,46 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DOCS_BUILDER="doxygen"
+DOCS_CONFIG_NAME="doxygen_tree.config"
+DOCS_DIR="doc"
+
+inherit docs toolchain-funcs
+
+DESCRIPTION="An STL-like tree class"
+HOMEPAGE="https://github.com/kpeeters/tree.hh"
+SRC_URI="https://github.com/kpeeters/tree.hh/archive/refs/tags/${PV}.tar.gz -> ${P}.tar.gz"
+S="${WORKDIR}/${PN}.hh-${PV}"
+
+LICENSE="|| ( GPL-2 GPL-3 )"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc64 ~x86"
+
+PATCHES=(
+	"${FILESDIR}"/3.18-add-missing-insert.patch
+	"${FILESDIR}"/3.18-const.patch
+	"${FILESDIR}"/3.18-cxx.patch
+	"${FILESDIR}"/3.18-fix-move-out.patch
+)
+
+src_configure() {
+	tc-export CXX
+}
+
+src_compile() {
+	docs_compile
+}
+
+src_test() {
+	cd src || die
+	emake
+	emake run_tests
+}
+
+src_install() {
+	doheader src/tree.hh src/tree_util.hh
+	dodoc -r examples
+	einstalldocs
+}