3 files changed, 72 insertions, 0 deletions
diff --git a/dev-java/jackson/Manifest b/dev-java/jackson/Manifest
new file mode 100644
index 000000000000..2152b09306d9
--- /dev/null
+++ b/dev-java/jackson/Manifest
@@ -0,0 +1 @@
+DIST jackson-core-2.9.10.tar.gz 416803 BLAKE2B 9d8efc39b09b9619da301dc7fec3bd6339133c3fea3af46bbd77530883662b3b1d4ba2536cb8bd7ff7609a79ae6cfce135a3a5d75076bb7884e5e2878ac0107b SHA512 26b22e3fa60190877f5227c936ee32fdb4014347307904b140a6c787bb732df598b0ed48e7014cb6e51172abe52783e4d866f135706c8ebc77e24bdf087e9e71
diff --git a/dev-java/jackson/jackson-2.9.10.ebuild b/dev-java/jackson/jackson-2.9.10.ebuild
new file mode 100644
index 000000000000..b495fe7cf278
--- /dev/null
+++ b/dev-java/jackson/jackson-2.9.10.ebuild
@@ -0,0 +1,59 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+JAVA_PKG_IUSE="doc source"
+
+inherit java-pkg-2 java-pkg-simple
+
+DESCRIPTION="High-performance JSON processor"
+HOMEPAGE="https://github.com/FasterXML/jackson-core"
+SRC_URI="https://github.com/FasterXML/${PN}-core/archive/${PN}-core-${PV}.tar.gz"
+LICENSE="Apache-2.0"
+SLOT="2"
+KEYWORDS="~amd64 ~x86"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND=">=virtual/jre-1.7"
+DEPEND=">=virtual/jdk-1.7
+	test? ( dev-java/junit:4 )"
+
+S="${WORKDIR}/${PN}-core-${PN}-core-${PV}"
+JAVA_SRC_DIR="src/main/java"
+
+src_prepare() {
+	default
+
+	sed -e 's:@package@:com.fasterxml.jackson.core.json:g' \
+		-e "s:@projectversion@:${PV}:g" \
+		-e 's:@projectgroupid@:com.fasterxml.jackson.core:g' \
+		-e 's:@projectartifactid@:jackson-core:g' \
+		"${JAVA_SRC_DIR}/com/fasterxml/jackson/core/json/PackageVersion.java.in" \
+		> "${JAVA_SRC_DIR}/com/fasterxml/jackson/core/json/PackageVersion.java" || die
+
+	java-pkg-2_src_prepare
+}
+
+src_compile() {
+	java-pkg-simple_src_compile
+	java-pkg_addres ${PN}.jar src/main/resources
+}
+
+src_install() {
+	java-pkg-simple_src_install
+	dodoc README.md release-notes/{CREDITS,VERSION}-2.x
+}
+
+src_test() {
+	cd src/test/java || die
+
+	local CP=".:../resources:${S}/${PN}.jar:$(java-pkg_getjars junit-4)"
+	local TESTS=$(find * -name "Test*.java")
+	TESTS="${TESTS//.java}"
+	TESTS="${TESTS//\//.}"
+
+	ejavac -cp "${CP}" -d . $(find * -name "*.java")
+	ejunit4 -classpath "${CP}" ${TESTS}
+}
diff --git a/dev-java/jackson/metadata.xml b/dev-java/jackson/metadata.xml
new file mode 100644
index 000000000000..3121a95f5b11
--- /dev/null
+++ b/dev-java/jackson/metadata.xml
@@ -0,0 +1,12 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+  <maintainer type="project">
+    <email>java@gentoo.org</email>
+    <name>Java</name>
+  </maintainer>
+  <upstream>
+    <remote-id type="github">FasterXML/jackson-core</remote-id>
+  </upstream>
+	<origin>gentoo-staging</origin>
+</pkgmetadata>