summaryrefslogtreecommitdiff
path: root/dev-java
diff options
context:
space:
mode:
Diffstat (limited to 'dev-java')
-rw-r--r--dev-java/ant/ant-1.10.14-r1.ebuild21
-rw-r--r--dev-java/eclipse-ecj/eclipse-ecj-4.15-r1.ebuild65
-rw-r--r--dev-java/eclipse-ecj/eclipse-ecj-4.26-r1.ebuild65
-rw-r--r--dev-java/eclipse-ecj/eclipse-ecj-4.30-r1.ebuild (renamed from dev-java/eclipse-ecj/eclipse-ecj-4.30.ebuild)8
-rw-r--r--dev-java/eclipse-ecj/files/ecj-4.157
-rw-r--r--dev-java/eclipse-ecj/files/ecj-4.267
-rw-r--r--dev-java/emma/emma-2.0.5312-r6.ebuild82
7 files changed, 251 insertions, 4 deletions
diff --git a/dev-java/ant/ant-1.10.14-r1.ebuild b/dev-java/ant/ant-1.10.14-r1.ebuild
index a18ee50e36b4..a76c380e0571 100644
--- a/dev-java/ant/ant-1.10.14-r1.ebuild
+++ b/dev-java/ant/ant-1.10.14-r1.ebuild
@@ -71,6 +71,27 @@ DEPEND="
PDEPEND="~dev-java/ant-core-${PV}:0"
RDEPEND="
!<dev-java/ant-core-1.10.14
+ !dev-java/ant-apache-regexp
+ !dev-java/ant-apache-log4j
+ !dev-java/ant-apache-xalan2
+ !dev-java/ant-commons-logging
+ !dev-java/ant-swing
+ !dev-java/ant-junit4
+ !dev-java/ant-testutil
+ !dev-java/ant-junitlauncher
+ !dev-java/ant-jai
+ !dev-java/ant-commons-net
+ !dev-java/ant-apache-bsf
+ !dev-java/ant-jmf
+ !dev-java/ant-apache-oro
+ !dev-java/ant-javamail
+ !dev-java/ant-junit
+ !dev-java/ant-jdepend
+ !dev-java/ant-antlr
+ !dev-java/ant-apache-bcel
+ !dev-java/ant-apache-resolver
+ !dev-java/ant-jsch
+ !dev-java/ant-xz
>=virtual/jre-1.8:*
"
diff --git a/dev-java/eclipse-ecj/eclipse-ecj-4.15-r1.ebuild b/dev-java/eclipse-ecj/eclipse-ecj-4.15-r1.ebuild
new file mode 100644
index 000000000000..753425431bb8
--- /dev/null
+++ b/dev-java/eclipse-ecj/eclipse-ecj-4.15-r1.ebuild
@@ -0,0 +1,65 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+JAVA_PKG_IUSE="doc source"
+
+inherit java-pkg-2 java-pkg-simple prefix
+
+DMF="R-${PV}-202003050155"
+
+DESCRIPTION="Eclipse Compiler for Java"
+HOMEPAGE="https://www.eclipse.org/"
+SRC_URI="https://archive.eclipse.org/eclipse/downloads/drops4/${DMF}/ecjsrc-${PV}.jar"
+S="${WORKDIR}"
+
+LICENSE="EPL-1.0"
+KEYWORDS="~amd64 ~arm ~arm64"
+SLOT="4.15"
+
+BDEPEND="
+ app-arch/unzip
+ app-arch/zip
+"
+COMMON_DEP="app-eselect/eselect-java"
+DEPEND="${COMMON_DEP}
+ >=dev-java/ant-1.10.14:0
+ >=virtual/jdk-11:*"
+RDEPEND="${COMMON_DEP}
+ !dev-java/ant-eclipse-ecj:4.15
+ >=virtual/jre-1.8:*"
+
+JAVA_AUTOMATIC_MODULE_NAME="org.eclipse.jdt.core.compiler.batch"
+JAVA_CLASSPATH_EXTRA="ant"
+JAVA_JAR_FILENAME="ecj.jar"
+JAVA_LAUNCHER_FILENAME="ecj-${SLOT}"
+JAVA_MAIN_CLASS="org.eclipse.jdt.internal.compiler.batch.Main"
+JAVA_RESOURCE_DIRS="res"
+
+src_prepare() {
+ java-pkg-2_src_prepare
+
+ mkdir "${JAVA_RESOURCE_DIRS}" || die
+ find org META-INF -type f \
+ ! -name '*.java' \
+ | xargs cp --parent -t "${JAVA_RESOURCE_DIRS}" || die
+}
+
+src_install() {
+ java-pkg-simple_src_install
+ insinto /usr/share/java-config-2/compiler
+ doins "${FILESDIR}/ecj-${SLOT}"
+ eprefixify "${ED}"/usr/share/java-config-2/compiler/ecj-${SLOT}
+}
+
+pkg_postinst() {
+ einfo "To select between slots of ECJ..."
+ einfo " # eselect ecj"
+
+ eselect ecj update ecj-${SLOT}
+}
+
+pkg_postrm() {
+ eselect ecj update
+}
diff --git a/dev-java/eclipse-ecj/eclipse-ecj-4.26-r1.ebuild b/dev-java/eclipse-ecj/eclipse-ecj-4.26-r1.ebuild
new file mode 100644
index 000000000000..6a8632e9feb6
--- /dev/null
+++ b/dev-java/eclipse-ecj/eclipse-ecj-4.26-r1.ebuild
@@ -0,0 +1,65 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+JAVA_PKG_IUSE="doc source"
+
+inherit java-pkg-2 java-pkg-simple prefix
+
+DMF="R-${PV}-202211231800"
+
+DESCRIPTION="Eclipse Compiler for Java"
+HOMEPAGE="https://www.eclipse.org/"
+SRC_URI="https://archive.eclipse.org/eclipse/downloads/drops4/${DMF}/ecjsrc-${PV}.jar"
+S="${WORKDIR}"
+
+LICENSE="EPL-1.0"
+KEYWORDS="~amd64 ~arm ~arm64"
+SLOT="4.26"
+
+BDEPEND="
+ app-arch/unzip
+ app-arch/zip
+"
+COMMON_DEP="app-eselect/eselect-java"
+DEPEND="${COMMON_DEP}
+ >=dev-java/ant-1.10.14:0
+ >=virtual/jdk-17:*"
+RDEPEND="${COMMON_DEP}
+ !dev-java/ant-eclipse-ecj:4.26
+ >=virtual/jre-11:*"
+
+JAVA_AUTOMATIC_MODULE_NAME="org.eclipse.jdt.core.compiler.batch"
+JAVA_CLASSPATH_EXTRA="ant"
+JAVA_JAR_FILENAME="ecj.jar"
+JAVA_LAUNCHER_FILENAME="ecj-${SLOT}"
+JAVA_MAIN_CLASS="org.eclipse.jdt.internal.compiler.batch.Main"
+JAVA_RESOURCE_DIRS="res"
+
+src_prepare() {
+ java-pkg-2_src_prepare
+
+ mkdir "${JAVA_RESOURCE_DIRS}" || die
+ find org META-INF -type f \
+ ! -name '*.java' \
+ | xargs cp --parent -t "${JAVA_RESOURCE_DIRS}" || die
+}
+
+src_install() {
+ java-pkg-simple_src_install
+ insinto /usr/share/java-config-2/compiler
+ doins "${FILESDIR}/ecj-${SLOT}"
+ eprefixify "${ED}"/usr/share/java-config-2/compiler/ecj-${SLOT}
+}
+
+pkg_postinst() {
+ einfo "To select between slots of ECJ..."
+ einfo " # eselect ecj"
+
+ eselect ecj update ecj-${SLOT}
+}
+
+pkg_postrm() {
+ eselect ecj update
+}
diff --git a/dev-java/eclipse-ecj/eclipse-ecj-4.30.ebuild b/dev-java/eclipse-ecj/eclipse-ecj-4.30-r1.ebuild
index 4dcc76c35f8f..8198793a6a85 100644
--- a/dev-java/eclipse-ecj/eclipse-ecj-4.30.ebuild
+++ b/dev-java/eclipse-ecj/eclipse-ecj-4.30-r1.ebuild
@@ -1,4 +1,4 @@
-# Copyright 1999-2023 Gentoo Authors
+# Copyright 1999-2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
@@ -18,7 +18,7 @@ SRC_URI="https://download.eclipse.org/eclipse/downloads/drops4/${DMF}/ecjsrc-${P
S="${WORKDIR}"
LICENSE="EPL-1.0"
-KEYWORDS="~amd64 ~arm64 ~ppc64 ~x86 ~amd64-linux ~x86-linux"
+KEYWORDS="~amd64 ~arm64"
SLOT="4.30"
BDEPEND="
@@ -29,7 +29,7 @@ COMMON_DEP="app-eselect/eselect-java"
# ElementsImpl9.java:206: error:
# method does not override or implement a method from a supertype
DEPEND="${COMMON_DEP}
- dev-java/ant-core:0
+ >=dev-java/ant-1.10.14:0
>=virtual/jdk-21:*"
# Parser.java:1095: error:
# pattern matching in instanceof is not supported in -source 11
@@ -39,7 +39,7 @@ RDEPEND="${COMMON_DEP}
DOCS=( org/eclipse/jdt/core/README.md )
JAVA_AUTOMATIC_MODULE_NAME="org.eclipse.jdt.core.compiler.batch"
-JAVA_CLASSPATH_EXTRA="ant-core"
+JAVA_CLASSPATH_EXTRA="ant"
JAVA_JAR_FILENAME="ecj.jar"
JAVA_LAUNCHER_FILENAME="ecj-${SLOT}"
JAVA_MAIN_CLASS="org.eclipse.jdt.internal.compiler.batch.Main"
diff --git a/dev-java/eclipse-ecj/files/ecj-4.15 b/dev-java/eclipse-ecj/files/ecj-4.15
new file mode 100644
index 000000000000..f943dedcc19b
--- /dev/null
+++ b/dev-java/eclipse-ecj/files/ecj-4.15
@@ -0,0 +1,7 @@
+JAVAC="@GENTOO_PORTAGE_EPREFIX@/usr/bin/ecj-4.15"
+PACKAGE="=dev-java/ant-eclipse-ecj-4.15*"
+SUPPORTED_TARGET="1.1 1.2 1.3 1.4 1.5 1.6 1.7 1.8 9 10 11 12 13"
+SUPPORTED_SOURCE="1.3 1.4 1.5 1.6 1.7 1.8 9 10 11 12 13"
+ANT_BUILD_COMPILER="org.eclipse.jdt.core.JDTCompilerAdapter"
+ANT_BUILD_COMPILER_DEPS="eclipse-ecj-4.15,ant-eclipse-ecj-4.15"
+GENERATION="2"
diff --git a/dev-java/eclipse-ecj/files/ecj-4.26 b/dev-java/eclipse-ecj/files/ecj-4.26
new file mode 100644
index 000000000000..950088453264
--- /dev/null
+++ b/dev-java/eclipse-ecj/files/ecj-4.26
@@ -0,0 +1,7 @@
+JAVAC="@GENTOO_PORTAGE_EPREFIX@/usr/bin/ecj-4.25"
+PACKAGE="=dev-java/ant-eclipse-ecj-4.25*"
+SUPPORTED_TARGET="1.1 1.2 1.3 1.4 1.5 1.6 1.7 1.8 9 10 11 12 13 14 15 16 17 18 19"
+SUPPORTED_SOURCE="1.3 1.4 1.5 1.6 1.7 1.8 9 10 11 12 13 14 15 16 17 18 19"
+ANT_BUILD_COMPILER="org.eclipse.jdt.core.JDTCompilerAdapter"
+ANT_BUILD_COMPILER_DEPS="eclipse-ecj-4.26,ant-eclipse-ecj-4.26"
+GENERATION="2"
diff --git a/dev-java/emma/emma-2.0.5312-r6.ebuild b/dev-java/emma/emma-2.0.5312-r6.ebuild
new file mode 100644
index 000000000000..fd0432aee669
--- /dev/null
+++ b/dev-java/emma/emma-2.0.5312-r6.ebuild
@@ -0,0 +1,82 @@
+# Copyright 2023-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+JAVA_PKG_IUSE="doc source"
+MAVEN_PROVIDES="
+ emma:emma:${PV}
+ emma:emma_ant:${PV}
+"
+
+inherit java-pkg-2 java-pkg-simple
+
+DESCRIPTION="Free Java code coverage tool"
+HOMEPAGE="https://emma.sourceforge.net/"
+SRC_URI="mirror://sourceforge/project/emma/emma-release/${PV}/${P}-src.zip"
+S="${WORKDIR}/${P}"
+
+LICENSE="CPL-1.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64"
+
+IUSE="+launcher"
+
+BDEPEND="app-arch/unzip"
+CP_DEPEND=">=dev-java/ant-1.10.14:0"
+DEPEND="${CP_DEPEND}
+ >=virtual/jdk-1.8:*"
+RDEPEND="${CP_DEPEND}
+ >=virtual/jre-1.8:*
+ launcher? ( !sci-biology/emboss:0 )"
+
+PATCHES=( "${FILESDIR}/emma-2.0.5312-java15api.patch" )
+
+JAVADOC_CLASSPATH="ant"
+JAVADOC_SRC_DIRS=(
+ core/data core/java1{2,3,4}
+ ant/ant1{4,5}
+)
+
+src_prepare() {
+ default #780585
+}
+
+src_compile() {
+ einfo "Compiling emma.jar"
+ JAVA_JAR_FILENAME="emma.jar"
+ JAVA_MAIN_CLASS="emmarun"
+ JAVA_RESOURCE_DIRS=( core/res )
+ JAVA_SRC_DIR=( core/data core/java1{2,3,4} )
+ java-pkg-simple_src_compile
+ JAVA_GENTOO_CLASSPATH_EXTRA+=":emma.jar"
+ rm -r target || die
+
+ einfo "Compiling emma_ant.jar"
+ JAVA_JAR_FILENAME="emma_ant.jar"
+ JAVA_MAIN_CLASS="com.vladium.emma.ANTMain"
+ JAVA_RESOURCE_DIRS=()
+ JAVA_SRC_DIR=( ant/ant1{4,5} )
+ java-pkg-simple_src_compile
+ JAVA_GENTOO_CLASSPATH_EXTRA+=":emma_ant.jar"
+ rm -r target || die
+
+ use doc && ejavadoc
+}
+
+src_install() {
+ java-pkg_dojar "emma.jar" "emma_ant.jar"
+ java-pkg_register-ant-task
+
+ use launcher && java-pkg_dolauncher ${PN} --main emmarun
+
+ if use doc; then
+ java-pkg_dojavadoc target/api
+ fi
+
+ if use source; then
+ java-pkg_dosrc core/data/*
+ java-pkg_dosrc core/java1{2,3,4}/*
+ java-pkg_dosrc ant/ant1{4,5}*
+ fi
+}
generated by cgit v1.3 (git 2.53.0) at 2026-10-01 21:40:24 +0000