1 files changed, 57 insertions, 0 deletions
diff --git a/dev-python/blessed/blessed-1.51.0.ebuild b/dev-python/blessed/blessed-1.51.0.ebuild
new file mode 100644
index 000000000000..2d966eb57b93
--- /dev/null
+++ b/dev-python/blessed/blessed-1.51.0.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=flit-core
+PYTHON_COMPAT=( python3_{13..14} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Library for making terminal apps using colors, keyboard input and positioning"
+HOMEPAGE="
+	https://github.com/jquast/blessed/
+	https://pypi.org/project/blessed/
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~riscv ~x86"
+
+RDEPEND="
+	>=dev-python/jinxed-2.1[${PYTHON_USEDEP}]
+	>=dev-python/wcwidth-0.8.3[${PYTHON_USEDEP}]
+"
+
+distutils_enable_sphinx docs dev-python/sphinx-rtd-theme
+
+EPYTEST_PLUGINS=()
+# tests are flaky with xdist
+distutils_enable_tests pytest
+
+# README.rst is a symlink to docs/
+DOCS=()
+
+python_prepare_all() {
+	# Skip those extensions as they don't have a Gentoo package
+	# Remove calls to scripts that generate rst files because they
+	# are not present in the tarball
+	sed -e '/sphinxcontrib.manpage/d' -e '/sphinx_paramlinks/d' \
+		-e '/^for script in/,/runpy.run_path/d' \
+		-i docs/conf.py || die
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# fragile to timing
+		tests/test_sixel.py::test_sixel_height_and_width_fallback_to_xtwinops
+		tests/test_sixel.py::test_fast_path_with_caches_populated
+	)
+
+	# COLORTERM must not be truecolor
+	# See https://github.com/jquast/blessed/issues/162
+	local -x COLORTERM=
+	# Ignore coverage options
+	epytest --override-ini="addopts="
+}