2 files changed, 71 insertions, 0 deletions
diff --git a/dev-python/dbus-fast/Manifest b/dev-python/dbus-fast/Manifest
index 49d20b4c5671..2d4e84e52b3a 100644
--- a/dev-python/dbus-fast/Manifest
+++ b/dev-python/dbus-fast/Manifest
@@ -1 +1,2 @@
 DIST dbus-fast-5.0.22.gh.tar.gz 262681 BLAKE2B 10a4f0a9917e528109d79cee97620f4a4f78755db7d36c755d29b82f2ae47a93a9a5c1ded936cdbe0156df1675c2914f4642f6bbc4d2c22bca75e0da8590eac9 SHA512 de1dbeeb21d81d2819dee632a7617cd72a05f15cab8ff35de343c25d3ff3dd2ad794a99d842abf4da8b9432bf933df98999b545c81de9ebeed4288c0ca2dd1bb
+DIST dbus-fast-5.0.25.gh.tar.gz 297422 BLAKE2B 96624f775e146b9721574253acccafab2c10c8cf2c69022950a97c24bec36de473c487cedce0ffb7d7791427b7526b8dc82f0d1c19dceab0dea62606be5a512c SHA512 fca3e29f8f8408fbb85b3d91870cb1c7c0c3ffbd7fab454aa663642d5a20e3241db46d4909d553874fb812d8eaa5bc00d8024b324ec2d2244ddd794d6bf43093
diff --git a/dev-python/dbus-fast/dbus-fast-5.0.25.ebuild b/dev-python/dbus-fast/dbus-fast-5.0.25.ebuild
new file mode 100644
index 000000000000..8f6c5d22767a
--- /dev/null
+++ b/dev-python/dbus-fast/dbus-fast-5.0.25.ebuild
@@ -0,0 +1,70 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=poetry-core
+# TODO: freethreading compatible
+PYTHON_COMPAT=( python3_{13..14} )
+
+inherit distutils-r1 virtualx
+
+DESCRIPTION="A faster version of dbus-next"
+HOMEPAGE="
+	https://github.com/bluetooth-devices/dbus-fast/
+	https://pypi.org/project/dbus-fast/
+"
+SRC_URI="
+	https://github.com/Bluetooth-Devices/dbus-fast/archive/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~riscv"
+IUSE="+native-extensions"
+
+BDEPEND="
+	<dev-python/cython-3.3[${PYTHON_USEDEP}]
+	>=dev-python/cython-3[${PYTHON_USEDEP}]
+	>=dev-python/setuptools-65.4.1[${PYTHON_USEDEP}]
+	test? (
+		dev-python/blockbuster[${PYTHON_USEDEP}]
+		>=dev-python/pycairo-1.21.0[${PYTHON_USEDEP}]
+		>=dev-python/pygobject-3.50[${PYTHON_USEDEP}]
+	)
+"
+
+EPYTEST_PLUGINS=( pytest-{asyncio,timeout} )
+distutils_enable_tests pytest
+
+src_configure() {
+	export REQUIRE_CYTHON=1
+	if ! use native-extensions; then
+		export SKIP_CYTHON=1
+	fi
+}
+
+src_test() {
+	local dbus_params=(
+		$(dbus-daemon --session --print-address --fork --print-pid)
+	)
+	local -x DBUS_SESSION_BUS_ADDRESS=${dbus_params[0]}
+
+	virtx distutils-r1_src_test
+
+	kill "${dbus_params[1]}" || die
+}
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# interface not found on this object: org.freedesktop.DBus.Debug.Stats
+		tests/client/test_signals.py::test_signals
+	)
+	local EPYTEST_IGNORE=(
+		tests/benchmarks
+	)
+
+	nonfatal epytest -o addopts= || die
+}