2 files changed, 0 insertions, 100 deletions
diff --git a/dev-python/hatchling/Manifest b/dev-python/hatchling/Manifest
index a59e8bccf95f..cdb66f53a5a7 100644
--- a/dev-python/hatchling/Manifest
+++ b/dev-python/hatchling/Manifest
@@ -1,2 +1 @@
 DIST hatch-hatchling-v1.32.0.gh.tar.gz 5360982 BLAKE2B a3eea27c39600ccf7b45e1b8de28112f3b92380f80579049013101cefde5f734225d71ac330d1b76a6c39c8f2e4a6e8b116f548b5eab305852a71d6d0b6c0094 SHA512 e8165a4444675382938502e692877cdad4a3f24e11f4b38bd0f6ae6ecc8a4fdde343ef5827719c803e5b40beddfd2a934d633270f0c200e3615c9b797038681e
-DIST hatch-hatchling-v1.32.4.gh.tar.gz 5364548 BLAKE2B be84990cf0a04a180221fa14642e7245c2b58830f2d538ba82446e4f525812cd9af598cc41e734b9c9e158c103c8f073abf2e5f240fa6fedf83d154bd092c453 SHA512 b595da39a0a614ba9f744f743be556be9a7be29a491646d64a2c206b044f2cda020120ebbf3d2975db8418af3b2c03152a3c3c82a8c60efae5ed0b6101f7ca7e
diff --git a/dev-python/hatchling/hatchling-1.32.4.ebuild b/dev-python/hatchling/hatchling-1.32.4.ebuild
deleted file mode 100644
index 1c1aa7618121..000000000000
--- a/dev-python/hatchling/hatchling-1.32.4.ebuild
+++ /dev/null
@@ -1,99 +0,0 @@
-# Copyright 2022-2026 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-DISTUTILS_USE_PEP517=standalone
-PYTHON_TESTED=( python3_{13..14} )
-PYTHON_COMPAT=( python3_{13..14} )
-
-inherit distutils-r1
-
-TAG=${P/-/-v}
-MY_P=hatch-${TAG}
-DESCRIPTION="Modern, extensible Python build backend"
-HOMEPAGE="
-	https://pypi.org/project/hatchling/
-	https://github.com/pypa/hatch/
-"
-SRC_URI="
-	https://github.com/pypa/hatch/archive/${TAG}.tar.gz
-		-> ${MY_P}.gh.tar.gz
-"
-S=${WORKDIR}/${MY_P}/backend
-
-LICENSE="MIT"
-SLOT="0"
-KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~arm64-macos ~x64-macos ~x64-solaris"
-IUSE="test"
-RESTRICT="!test? ( test )"
-
-# deps are listed in backend/src/hatchling/ouroboros.py
-# editables are optional but required for editable installs
-RDEPEND="
-	>=dev-python/editables-0.3[${PYTHON_USEDEP}]
-	>=dev-python/packaging-24.2[${PYTHON_USEDEP}]
-	>=dev-python/pathspec-0.10.1[${PYTHON_USEDEP}]
-	>=dev-python/pluggy-1.0.0[${PYTHON_USEDEP}]
-	>=dev-python/tomlkit-0.11.1[${PYTHON_USEDEP}]
-	dev-python/trove-classifiers[${PYTHON_USEDEP}]
-"
-BDEPEND="
-	${RDEPEND}
-	test? (
-		$(python_gen_cond_dep '
-			dev-python/atomicwrites[${PYTHON_USEDEP}]
-			dev-python/click[${PYTHON_USEDEP}]
-			dev-python/httpx[${PYTHON_USEDEP}]
-			dev-python/platformdirs[${PYTHON_USEDEP}]
-			dev-python/pytest[${PYTHON_USEDEP}]
-			dev-python/pytest-mock[${PYTHON_USEDEP}]
-			dev-python/rich[${PYTHON_USEDEP}]
-			dev-python/tomli-w[${PYTHON_USEDEP}]
-			dev-python/virtualenv[${PYTHON_USEDEP}]
-		' "${PYTHON_TESTED[@]}")
-	)
-"
-
-src_test() {
-	# top-level "tests" directory contains tests both for hatch
-	# and hatchling
-	cd "${WORKDIR}/${MY_P}" || die
-
-	# sigh; standalone test suites are overrated, right?
-	echo "__version__ = '${PV}'" > src/hatch/_version.py || die
-	local -x PYTHONPATH="src:${PYTHONPATH}"
-
-	# do not require uv for portability, sigh
-	mkdir "${T}/bin" || die
-	cat > "${T}/bin/uv" <<-EOF || die
-		#!/bin/sh
-		exit 127
-	EOF
-	chmod +x "${T}/bin/uv" || die
-	local -x PATH=${T}/bin:${PATH}
-
-	# tests mock cargo subprocess call but the backend raises if CARGO
-	# is not set and shutil.which() can't find it
-	local -x CARGO=cargo
-
-	distutils-r1_src_test
-}
-
-python_test() {
-	if ! has "${EPYTHON}" "${PYTHON_TESTED[@]/_/.}"; then
-		einfo "Skipping tests on ${EPYTHON}"
-		return
-	fi
-
-	local -x EPYTEST_DESELECT=(
-		# most of these run uv to install stuff
-		# the few remaining tests aren't worth running
-		tests/backend/dep/test_core.py
-		# broken if CARGO is set
-		tests/backend/builders/test_binary.py::TestBuildBootstrap::test_no_cargo
-	)
-
-	local EPYTEST_PLUGINS=( pytest-mock )
-	epytest tests/backend
-}