1 files changed, 63 insertions, 0 deletions
diff --git a/dev-python/httptools/httptools-0.9.0.ebuild b/dev-python/httptools/httptools-0.9.0.ebuild
new file mode 100644
index 000000000000..b6f5ee14ca3f
--- /dev/null
+++ b/dev-python/httptools/httptools-0.9.0.ebuild
@@ -0,0 +1,63 @@
+# Copyright 2024-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{13..14} )
+
+inherit distutils-r1
+
+DESCRIPTION="A collection of framework independent HTTP protocol utils"
+HOMEPAGE="
+	https://github.com/MagicStack/httptools/
+	https://pypi.org/project/httptools/
+"
+# sdist is missing cython source files, as of 0.6.2
+SRC_URI="
+	https://github.com/MagicStack/httptools/archive/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+# don't ask me why they use both
+DEPEND="
+	net-libs/http-parser:=
+	net-libs/llhttp:=
+"
+RDEPEND="
+	${DEPEND}
+"
+BDEPEND="
+	>=dev-python/cython-3.1.0[${PYTHON_USEDEP}]
+"
+
+EPYTEST_PLUGINS=()
+distutils_enable_tests pytest
+
+src_configure() {
+	cat > setup.cfg <<-EOF || die
+		[build_ext]
+		use_system_llhttp = true
+		use_system_http_parser = true
+		cython_always = true
+	EOF
+}
+
+python_test() {
+	local EPYTEST_DESELECT=()
+
+	case ${EPYTHON} in
+		pypy3*)
+			# no point trying to fix it
+			return
+			;;
+	esac
+
+	rm -rf httptools || die
+	epytest tests
+}