1 files changed, 40 insertions, 0 deletions
diff --git a/dev-python/jsonpath-ng/jsonpath-ng-1.11.0.ebuild b/dev-python/jsonpath-ng/jsonpath-ng-1.11.0.ebuild
new file mode 100644
index 000000000000..89b4a5fc7ef4
--- /dev/null
+++ b/dev-python/jsonpath-ng/jsonpath-ng-1.11.0.ebuild
@@ -0,0 +1,40 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYPI_VERIFY_REPO=https://github.com/jsonpath-ng/jsonpath-ng
+PYTHON_COMPAT=( python3_{13..14} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Python JSONPath Next-Generation"
+HOMEPAGE="
+	https://github.com/jsonpath-ng/jsonpath-ng/
+	https://pypi.org/project/jsonpath-ng/
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+RDEPEND="
+	dev-python/ply[${PYTHON_USEDEP}]
+"
+
+EPYTEST_PLUGINS=( hypothesis )
+distutils_enable_tests pytest
+
+EPYTEST_IGNORE=(
+	tests/benchmarks/
+)
+
+src_prepare() {
+	distutils-r1_src_prepare
+
+	# unbundle ply (sigh)
+	rm -r src/jsonpath_ng/_ply || die
+	find -name '*.py' -exec \
+		sed -i -e 's:jsonpath_ng[.]_ply[.]:ply.:' {} + || die
+}