1 files changed, 32 insertions, 0 deletions
diff --git a/dev-python/vcsgraph/vcsgraph-0.3.0.ebuild b/dev-python/vcsgraph/vcsgraph-0.3.0.ebuild
new file mode 100644
index 000000000000..b2b6b926f3f0
--- /dev/null
+++ b/dev-python/vcsgraph/vcsgraph-0.3.0.ebuild
@@ -0,0 +1,32 @@
+# Copyright 2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+CRATES=""
+RUST_MIN_VER="1.83"
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{13..14} )
+
+inherit cargo distutils-r1
+
+DESCRIPTION="Graph algorithms for version control systems"
+HOMEPAGE="https://pypi.org/project/vcsgraph/ https://github.com/breezy-team/vcsgraph"
+SRC_URI="https://github.com/breezy-team/${PN}/archive/v${PV}.tar.gz -> ${P}.gh.tar.gz"
+SRC_URI+=" https://github.com/gentoo-crate-dist/${PN}/releases/download/v${PV}/${P}-crates.tar.xz"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+
+BDEPEND="
+	dev-python/setuptools-rust[${PYTHON_USEDEP}]
+"
+
+distutils_enable_tests unittest
+
+python_test() {
+	cd "${BUILD_DIR}/install$(python_get_sitedir)" || die
+	eunittest
+}