1 files changed, 46 insertions, 0 deletions
diff --git a/dev-python/wcwidth/wcwidth-0.9.2.ebuild b/dev-python/wcwidth/wcwidth-0.9.2.ebuild
new file mode 100644
index 000000000000..84dd9c3e323c
--- /dev/null
+++ b/dev-python/wcwidth/wcwidth-0.9.2.ebuild
@@ -0,0 +1,46 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{13..14} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Measures number of Terminal column cells of wide-character codes"
+HOMEPAGE="
+	https://pypi.org/project/wcwidth/
+	https://github.com/jquast/wcwidth/
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~arm64-macos ~x64-macos"
+IUSE="+native-extensions"
+
+EPYTEST_PLUGINS=()
+distutils_enable_tests pytest
+
+src_configure() {
+	if ! use native-extensions; then
+		# do not build extension
+		export WCWIDTH_NO_EXTENSION=1
+		# test without extension
+		export WCWIDTH_PYTHON=1
+	fi
+	# make extension builds fatal
+	export CIBUILDWHEEL=1
+}
+
+python_test() {
+	rm -rf wcwidth || die
+	epytest -o addopts=
+}
+
+python_install_all() {
+	docinto docs
+	dodoc docs/intro.rst
+	distutils-r1_python_install_all
+}