12 files changed, 415 insertions, 0 deletions
diff --git a/dev-python/astroid/Manifest b/dev-python/astroid/Manifest
index 795eec25681d..e6726a186465 100644
--- a/dev-python/astroid/Manifest
+++ b/dev-python/astroid/Manifest
@@ -4,3 +4,5 @@ DIST astroid-4.1.2.tar.gz 414896 BLAKE2B 1888ca1d5f035fa2c4288e52392baefdb601aed
 DIST astroid-4.1.2.tar.gz.provenance 9395 BLAKE2B 0a178a7e3e1392b71c0a6ea9f910821581801f79c89345cf9aa62dfe1ea5c5f18b026f003ad88796b518054f859fc6b82c564a7a8af6f44fccf8a7c00f5e68e3 SHA512 59de972e0f8754be6d218d1d3f04942e9ffc8aaf277cdb1564f11024baea7085cad98610cb297d9076ce50ab28136e3577863456cb0b5215ed07c345853c3df9
 DIST astroid-4.3.1.tar.gz 439530 BLAKE2B c0225638bf18e097977f8a6e341071c26840f1bcd30f96ddaee93999e064304e28dba62116eb8b813f82a2d982672c520f0061c3b0fb76d265e6ff6b38407f77 SHA512 48376ba2509bdb5912bfcbad8f9e12c23352839d91fcde68bcde28a4ddf55d8a80ed55db7b63db2a30823fd4cd7a1e3e26d0a7e4184730932959c7fbb710ab2a
 DIST astroid-4.3.1.tar.gz.provenance 9887 BLAKE2B a232ac102e36420e5487b5476428ccd7cfa5bb0d1d877cf4d1f0a0c6f7d2345663df23bbaafd3adab992f8bd941a6b0b3a852d6061264ccdc8db3329f3aa35d3 SHA512 3eb5e5ccb6870f2842990afd85e35df2747aadae3a4434f6483baad560cdc4800a75240d649466c818fc7e7173981ff777055534efc4908c19298f54cb750b2b
+DIST astroid-4.3.2.tar.gz 441025 BLAKE2B 0d6cb9e7e6e948b4482741ea979ab57f68f6033e482b029ebaaab9091a57ee9343c2f14709da45ad4ff280420bf71afb4645851c85324b23fbad29c773db78a3 SHA512 3ee04381a84372da64d8d6da430fe388d24d7f14b371bafb4daf0149d6a43b9aded8d005659877bd586d5e84375c444750b20c35c51355379ef4d9b503c8f901
+DIST astroid-4.3.2.tar.gz.provenance 9460 BLAKE2B 5d49cbf84588e34e40022b30d7f954f1fd371091a5dea295e29b511da84f61c90867a27d224bea1fa1837f24df8c897a1bac71d73be9daac0c454be3b90972f8 SHA512 fa5f846fcf8edb37d8794ec24f26471c831eba617cc5558942853742bc6e22614cc3ef880ad20aec1aaedc3cd74bbbb1327ea1349d7b499dbda39f3d5d6edf98
diff --git a/dev-python/astroid/astroid-4.3.2.ebuild b/dev-python/astroid/astroid-4.3.2.ebuild
new file mode 100644
index 000000000000..a262de696687
--- /dev/null
+++ b/dev-python/astroid/astroid-4.3.2.ebuild
@@ -0,0 +1,86 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYPI_VERIFY_REPO=https://github.com/pylint-dev/astroid
+PYTHON_COMPAT=( python3_{13..14} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Abstract Syntax Tree for logilab packages"
+HOMEPAGE="
+	https://github.com/pylint-dev/astroid/
+	https://pypi.org/project/astroid/
+"
+
+LICENSE="LGPL-2.1+"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+# dev-python/regex isn't available for pypy
+BDEPEND="
+	dev-python/setuptools-scm[${PYTHON_USEDEP}]
+	test? (
+		dev-python/attrs[${PYTHON_USEDEP}]
+		>=dev-python/numpy-1.17.0[${PYTHON_USEDEP}]
+		dev-python/python-dateutil[${PYTHON_USEDEP}]
+		dev-python/regex[${PYTHON_USEDEP}]
+	)
+"
+
+EPYTEST_PLUGINS=()
+distutils_enable_tests pytest
+
+export SETUPTOOLS_SCM_PRETEND_VERSION=${PV}
+
+python_test() {
+	local EPYTEST_IGNORE=()
+	local EPYTEST_DESELECT=(
+		# hangs randomly
+		tests/test_nodes.py::AsStringTest::test_recursion_error_trapped
+		# no clue why they're broken
+		tests/test_modutils.py::GetModulePartTest::test_known_values_get_builtin_module_part
+		# TODO
+		tests/test_builder.py::BuilderTest::test_data_build_error_filename
+		# numpy-2 (https://github.com/pylint-dev/astroid/issues/2442)
+		tests/brain/numpy/test_core_einsumfunc.py::test_numpy_function_calls_inferred_as_ndarray
+		tests/brain/numpy/test_core_fromnumeric.py::BrainNumpyCoreFromNumericTest::test_numpy_function_calls_inferred_as_ndarray
+		tests/brain/numpy/test_core_multiarray.py::BrainNumpyCoreMultiarrayTest::test_numpy_function_calls_inferred_as_ndarray
+		tests/brain/numpy/test_core_numerictypes.py::NumpyBrainCoreNumericTypesTest::test_datetime_astype_return
+		tests/brain/numpy/test_core_numerictypes.py::NumpyBrainCoreNumericTypesTest::test_generic_types_are_subscriptables
+		tests/brain/numpy/test_core_umath.py::NumpyBrainCoreUmathTest::test_numpy_core_umath_functions_return_type
+		tests/brain/numpy/test_core_umath.py::NumpyBrainCoreUmathTest::test_numpy_core_umath_functions_return_type_tuple
+		# old pythons only
+		tests/brain/test_dataclasses.py::test_pydantic_field
+		tests/test_regrtest.py::NonRegressionTests::test_numpy_distutils
+		# -Werror, sigh
+		tests/test_nodes.py::test_deprecated_nodes_import_from_toplevel
+	)
+
+	if ! has_version "dev-python/mypy[${PYTHON_USEDEP}]"; then
+		EPYTEST_IGNORE+=(
+			tests/test_raw_building.py
+		)
+	fi
+
+	case ${EPYTHON} in
+		python3.15)
+			EPYTEST_DESELECT+=(
+				tests/brain/test_brain.py::TypingBrain::test_typing_object_notsubscriptable_3
+				tests/brain/test_dataclasses.py::test_kw_only_sentinel
+				tests/test_regrtest.py::test_regression_parse_deeply_nested_parentheses
+			)
+			;;
+	esac
+
+	if ! has_version "dev-python/pkg-resources[${PYTHON_USEDEP}]"; then
+		EPYTEST_DESELECT+=(
+			# tests a package using pkg_resources
+			tests/test_manager.py::AstroidManagerTest::test_identify_old_namespace_package_protocol
+		)
+	fi
+
+	epytest
+}
diff --git a/dev-python/boto3/Manifest b/dev-python/boto3/Manifest
index 85878056df81..17b52b0bdfc2 100644
--- a/dev-python/boto3/Manifest
+++ b/dev-python/boto3/Manifest
@@ -1,6 +1,7 @@
 DIST boto3-1.43.100.gh.tar.gz 1237221 BLAKE2B dd5cc359ef4772d8b0df5192b023637456e8e5107383cfd1e72ddad4d24afe7f2d7beeeddb6e0a0b421113f3395298e6005635786e2d34ecf0d007c9af5220c9 SHA512 006deaffaabf4b2a3b376bc4ba6ac6dfcd8ecf62aa73f05d9d5fd81ebf58fb13ba85ce2072315cd1d6c69b6cc1303c3bb30d588401eaddbf9e730e19f1e359dd
 DIST boto3-1.43.101.gh.tar.gz 1238893 BLAKE2B 04a2acb6a097495932a83310b58025251d264f32931eb86ef9f1dee908e5732cb5584e0c47fbed7632592d003da56c4f775cf9740e4b305ce3c90dd7f4f5ba35 SHA512 d92bdbbda3b4febb656ff9cee446414b1381d0a4b7481f61c0d3ce6ef7d6f85c3856a1d44ba392e498480496df10662e41fa41a94c16377a13e683fe33e6efa1
 DIST boto3-1.43.102.gh.tar.gz 1240274 BLAKE2B cf07fb436a0070e6ecad4a7455bb603d5bdd62c3a371d1cd2c8e0d2493279fe4d341b85d1068deb5f5e8bd114a12d18a5609a96df2205eff32f166061986cb45 SHA512 c3ccf431b135742770d57aa1caeeabcb6cd7c3fbdc34209eeff3eba742e857b1e63f44a13f776ecdde7fb0386acb065deb5683fa229aad58c4489552b776469f
+DIST boto3-1.43.103.gh.tar.gz 1242075 BLAKE2B 907fe54732510a077b049526c5524b1d774c411656aacf5f8ab26619c449fa81b16502aca7a1e69f22d87d12e1deeef526fb55d07ddec432e743df36a514b6ac SHA512 85156ed2492c4eac9dd9c52e71cf6d33431adeb9969f584cbfb0aab9c15080a34f1561f9077f509811daa6561d3ae869d4518764ce7a7f0b3d1a74c15073bb74
 DIST boto3-1.43.72.gh.tar.gz 1208773 BLAKE2B 1250a1fffa6b31c2e3c5ab40221db938a56605c09b19b1d07db8eafe5acd68d06e3d6b75fc206fad1cd4c8b2ae9c663a69fdeb9c8b32246dad3134c1f4154275 SHA512 b357a17de48ff1ab460ba71315249f294e979311b7787aa2bfc7f82e2b54717039a04420d63d63ebbb51685b526eec863e0278ba58d2b68e7dfa60bdd4017f41
 DIST boto3-1.43.78.gh.tar.gz 1213393 BLAKE2B b3e4188ba53609873bf6613d5667792d24634d728dfe0e0588917ade93c4d6c9a5a28d2e46bd5ca314723604a9cab9a4fae7ca1e6f9e496cc29671bc68849d7e SHA512 c98ede06cf4934089ba4a62c4fb03da692a5f9e2a415728e9f51979e33942229d8f4cd6fa02ac229b360b63a930fd91890f2ed645d17011d4a42e236943fd780
 DIST boto3-1.43.83.gh.tar.gz 1218064 BLAKE2B 0758e28dd9b086615b045e107aece2ef46bee541110e51fdcd231c60cac0452f4cdfec58ea4041757835c195cd2b8becb3c4e9fd24ad7bc306d90b16af082f63 SHA512 ed110edd551138c5d63ab7ead46a4c9ddb410dea1b5e642045102936af22c4208f357f79fc994434fc6a7df7c16aba99052508103bad7599f8cc558ae1c5f842
diff --git a/dev-python/boto3/boto3-1.43.103.ebuild b/dev-python/boto3/boto3-1.43.103.ebuild
new file mode 100644
index 000000000000..93fbbe6dd59b
--- /dev/null
+++ b/dev-python/boto3/boto3-1.43.103.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{13..14} )
+
+inherit distutils-r1
+
+DESCRIPTION="The AWS SDK for Python"
+HOMEPAGE="
+	https://github.com/boto/boto3/
+	https://pypi.org/project/boto3/
+"
+SRC_URI="
+	https://github.com/boto/boto3/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc ~ppc64 ~riscv ~sparc ~x86"
+
+RDEPEND="
+	>=dev-python/botocore-${PV}[${PYTHON_USEDEP}]
+	>=dev-python/jmespath-0.7.1[${PYTHON_USEDEP}]
+	>=dev-python/s3transfer-0.19.0[${PYTHON_USEDEP}]
+"
+
+EPYTEST_PLUGINS=()
+EPYTEST_XDIST=1
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	# don't lock versions to narrow ranges
+	sed -e '/botocore/ d' \
+		-e '/jmespath/ d' \
+		-e '/s3transfer/ d' \
+		-i setup.py || die
+
+	# do not rely on bundled deps in botocore (sic!)
+	find -name '*.py' -exec sed -i \
+		-e 's:from botocore[.]vendored import:import:' \
+		-e 's:from botocore[.]vendored[.]:from :' \
+		{} + || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	epytest tests/{functional,unit}
+}
diff --git a/dev-python/botocore/Manifest b/dev-python/botocore/Manifest
index b56ddc91e752..e781163e5d5a 100644
--- a/dev-python/botocore/Manifest
+++ b/dev-python/botocore/Manifest
@@ -1,6 +1,7 @@
 DIST botocore-1.43.100.gh.tar.gz 17215276 BLAKE2B f799985125d4522f867a684507c748026d31cba917c5a40b75179ff77b70adefe0b172d5f92c9293a43ddc9e54a8e449255c6a649dcdf1de950462f2456e03d8 SHA512 a7724a4d57d870ca91fc8564bb73f200065f63ae1070464f73bddaf1c066e8f0df29725ec2f9969d8c857c37bbd3f53414fcaeeb71f5cb86b7bfeb3de83ed8d1
 DIST botocore-1.43.101.gh.tar.gz 17252992 BLAKE2B feff627b2ba10eaff021969d19b65d58eb54f070c0a8dc4e0cd19d4d74232e12ebe7a1c3b1d24f198a0c21bafbd3c30845cc4c14966c5dd14b90167c6e9766c8 SHA512 3ffa93196421163b6b9ac66975cc2d182f0bdb80fc6837e431b47543190c7d69be9a8c7e405e04ca73c14828cd1e476286be32c96b96abb9057a2d0d3c9f2bc5
 DIST botocore-1.43.102.gh.tar.gz 17285032 BLAKE2B 16baa0bc60258fc9700f3eee01403e71cf588f202a0cd0d8584b0ebf6c14a57fc9495b7e0257b2b8dec94e798ac4c5885e1b2ea458d43381d62d177daff2236b SHA512 f32dc1e903d25881a3c8ae03b01a4a74a73bf669719a48957a1b44e102be050fdc5536e73d3514c6cd06206403c7dd5f70c217bfcde30b2bd283e296e01a666c
+DIST botocore-1.43.103.gh.tar.gz 17299294 BLAKE2B d589d82cd6d0e1cb53280c606e04159291910f0eb5276d8dc158ae5bdae9e8b866a36f29eb87e7d545c63f73880c4b93edb6690f35c64bdacc48ca8f8825f4e0 SHA512 2d6f2991428ee3d6fd7fd7cc2d1cf28eabcd0732c73d8fda48da8a28c2c2d1a89296800c20ba3769e2b85ad5663484532428d6906eef48f825b8bdcaaababa92
 DIST botocore-1.43.72.gh.tar.gz 16966215 BLAKE2B ccb01e2001fd1584bc635a19daf241371bf9e00b97f5d1adf07f4dbff0a5f8ac75ab93f66b8e05976a1fda1c111c6148ade5bdfa585ccdad4376a7651cf088e2 SHA512 0ee8aa2a82c6db2d1094679612146b9be98eff499880a33721cbc324b631ba6e268031e4ec0c1f8025da5dd187e7f211ef6da6c97ab13c5a3b9d9d93f4a80248
 DIST botocore-1.43.78.gh.tar.gz 17008224 BLAKE2B 137656d64f62025ca47f03c48ba84aa7eccae9dbc752c81f909c3c3f12dd843bb40173075fc7e255492385d8ea8824da08e5d3155bb5ff1dbfd62c858c0a057f SHA512 bd65c7fe451ef0b3bef21e25e557aa37748ca01f71e567b31b852ac356d323f1cfa6dd0e920eff7c52e0db879a34cf99eed6c1b841dfa6065e139362702f9d13
 DIST botocore-1.43.83.gh.tar.gz 17038145 BLAKE2B f74b399b04f9b259e1a2f424719c4b80cc279627174ac96f9b79d85418ecc0442fbd27d7e79ccdf12526ac02489fde4254e360f216103f3cd5ff050b3cf1a838 SHA512 618c0ef0fc89879ee6900606e3378b2876901c4a63ede52529de12898a65e34fc41a8f0ad8ab682b7788626176f9b86904e257b63d88be9d58c53116918b1d12
diff --git a/dev-python/botocore/botocore-1.43.103.ebuild b/dev-python/botocore/botocore-1.43.103.ebuild
new file mode 100644
index 000000000000..14ad5b2d1f27
--- /dev/null
+++ b/dev-python/botocore/botocore-1.43.103.ebuild
@@ -0,0 +1,80 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{13..14} )
+
+inherit distutils-r1
+
+DESCRIPTION="Low-level, data-driven core of boto 3"
+HOMEPAGE="
+	https://github.com/boto/botocore/
+	https://pypi.org/project/botocore/
+"
+SRC_URI="
+	https://github.com/boto/botocore/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc ~ppc64 ~riscv ~sparc ~x86"
+
+RDEPEND="
+	<dev-python/jmespath-2[${PYTHON_USEDEP}]
+	dev-python/python-dateutil[${PYTHON_USEDEP}]
+	>=dev-python/urllib3-1.25.4[${PYTHON_USEDEP}]
+"
+# unbundled packages
+RDEPEND+="
+	dev-python/requests[${PYTHON_USEDEP}]
+	dev-python/six[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/jsonschema[${PYTHON_USEDEP}]
+	)
+"
+
+EPYTEST_PLUGINS=()
+EPYTEST_XDIST=1
+distutils_enable_tests pytest
+
+src_prepare() {
+	# unpin deps
+	sed -i -e "s:>=.*':':" setup.py || die
+
+	# unbundle deps
+	rm -r botocore/vendored || die
+	find -name '*.py' -exec sed -i \
+		-e 's:from botocore[.]vendored import:import:' \
+		-e 's:from botocore[.]vendored[.]:from :' \
+		{} + || die
+
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# rely on bundled six
+		tests/functional/test_six_imports.py::test_no_bare_six_imports
+		tests/functional/test_six_threading.py::test_six_thread_safety
+	)
+
+	# The test suite can eat up a lot of memory when running via xdist,
+	# and slow down some tiny tests.  Let's just run a safe subset
+	# of tests known to be slow-ish in parallel, and the rest in series.
+	local parallel_tests=(
+		tests/functional/*/
+		tests/functional/test_event_alias.py
+		tests/functional/test_[cds-z]*.py
+		tests/unit/
+	)
+
+	epytest "${parallel_tests[@]}"
+
+	local EPYTEST_IGNORE=( "${parallel_tests[@]}" )
+	EPYTEST_XDIST= epytest tests/functional
+}
diff --git a/dev-python/platformdirs/Manifest b/dev-python/platformdirs/Manifest
index 94939dae938f..42affdaf08c9 100644
--- a/dev-python/platformdirs/Manifest
+++ b/dev-python/platformdirs/Manifest
@@ -6,6 +6,8 @@ DIST platformdirs-4.11.12.tar.gz 40016 BLAKE2B d8f5b81cdde33623e59b21c5309d357e5
 DIST platformdirs-4.11.12.tar.gz.provenance 9617 BLAKE2B fd02ecf2e8bceb5f143d5184e8a242ddcce1b981af46f679de638714096c0e30ba8cc6040e594680a049c9ef5544e324503f95ddc372c885dda7365687a43491 SHA512 7b588b06856b2a61c83bc0607325befb42b95146db61ec34d6620dd07f93a74b07c9e055576271e40f4082383b009317707c39edef8eaa8b10480e62f49c1bfa
 DIST platformdirs-4.11.14.tar.gz 45301 BLAKE2B cbb1cf6980d7aab45525a46438a8accc2eb188a30c652fe9ae66e9a1f8858d1a287e7b898be54f1f0221777bfbe3b5bfe016314be1973f223b5acbb6faa53ea4 SHA512 8d386d0535728f51b7a2eacf7f994e986becc55515472c58bb244bb324c47354427ac704984afe01bf956d52c4832768be5a2cad5d464fc7e57131b219c38e09
 DIST platformdirs-4.11.14.tar.gz.provenance 9805 BLAKE2B 532406b48218fb89b03be35e52b1d2567a72897a23952fe17d8b085f7c55fb7b8df8e5c6a7f7f14188a1ee64febee56b7cfaf75d68b392bb87c202fad2b79c09 SHA512 465302f0476f2f11439339c1ee5ff17304022f1930351afa86a1dfcb1e0cd0ee4e943ec74af61d54dd9984fcc53034766a1da3a5efebd56b5c8ae3d912a22b89
+DIST platformdirs-4.11.15.tar.gz 46059 BLAKE2B 69da625f4bad69e17c1739c0f4133ff619671f0c592035c91b98b7fe88d6da2b9c6a98e11a52c1d6368f7a383da4c0ce32bbeaeb1e24a191533c6f8f1db00144 SHA512 0e8f7b7fa2fe817695e61a4df091346cf56e0493ab80abe0871df5c88be7a0e96f63f64451e8848da53e5bda7cd33296a1e8475f847a68c4798f59771fe0d855
+DIST platformdirs-4.11.15.tar.gz.provenance 9958 BLAKE2B c85324fdb9dc97ab5d29503da0916a13f3416f31362466182d9bd62cb1f0ce5bb55a6b350ceec05e600e7fb3e5895222517e2cd84610ff4670bf350fcf8f18f4 SHA512 7a18eb7c497cd2af7ad0dd1903c5b482d05d814fade6e3aefbc6363056de78ec2607eb46c9a416d47a701e995ae3c784efbb3df3e3bcc09af795ff3a3c0707e3
 DIST platformdirs-4.11.3.tar.gz 33050 BLAKE2B c838822e0d5a9391d13fbf240c3006ade7094c2a2ad7c5b9904fce23c48ea9db6e851d04c887a80f37fee3bd0612e010ae58516751c050fb881c8ec6da1ab22e SHA512 0d90ccbb4f75bc2c0eda42223d475c688c59214fd696ff4690abd022322d9883816bc7c33765da8c9a792afc04ab21faa08c69dcbe027f7cbdcb4087e5baa2a1
 DIST platformdirs-4.11.3.tar.gz.provenance 9777 BLAKE2B 9b4f683aaab5b99f085f560e4ff21e3a9533b892e974e8e39aef047ee2021ff416ff88af6db98c6fd284ef592a926b425c8b7c05f5cb0f4b8d5c23bb59ac8229 SHA512 97833d43052e8b2c303f204f8291cfb39bc1b399c2ecfbeabe18b54e5d20bb8920c802013fc43060c9e4f2ed7f359c5a5c763dc8cb14e9ba8bc52f328a64fa34
 DIST platformdirs-4.11.4.tar.gz 34079 BLAKE2B daf5b088aa61382c1cbcbda0eebb23b9b4e7071472589ee1cc61c04f5386952d1be1b3090198104c4749c09c0fe5fcf8677ddfd31c1f8efe34219ef1a9708b3d SHA512 557782bd9f2af016372e9406a05a55194259303ae63ee90f684595f9a5dfbe0cc8ba11252135ebf31cb5a93bef740487581b4ca852f467ef781287cda15e4a0c
diff --git a/dev-python/platformdirs/platformdirs-4.11.15.ebuild b/dev-python/platformdirs/platformdirs-4.11.15.ebuild
new file mode 100644
index 000000000000..97987e113428
--- /dev/null
+++ b/dev-python/platformdirs/platformdirs-4.11.15.ebuild
@@ -0,0 +1,50 @@
+# Copyright 2021-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=flit-core
+PYPI_VERIFY_REPO=https://github.com/tox-dev/platformdirs
+PYTHON_COMPAT=( python3_{13..14} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="A small Python module for determining appropriate platform-specific dirs"
+HOMEPAGE="
+	https://pypi.org/project/platformdirs/
+	https://github.com/tox-dev/platformdirs/
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~arm64-macos ~x64-macos ~x64-solaris"
+
+BDEPEND="
+	test? (
+		dev-python/appdirs[${PYTHON_USEDEP}]
+	)
+"
+
+EPYTEST_PLUGINS=( pytest-mock )
+distutils_enable_tests pytest
+
+src_configure() {
+	grep -q 'build-backend = "hatchling' pyproject.toml ||
+		die "Upstream changed build-backend, recheck"
+	# write a custom pyproject.toml to ease setuptools bootstrap
+	cat > pyproject.toml <<-EOF || die
+		[build-system]
+		requires = ["flit_core >=3.2,<4"]
+		build-backend = "flit_core.buildapi"
+
+		[project]
+		name = "${PN}"
+		version = "${PV}"
+		description = 'A small Python package for determining appropriate platform-specific dirs, e.g. a "user data dir".'
+	EOF
+	# sigh
+	cat > src/platformdirs/version.py <<-EOF || die
+		__version__ = version = '${PV}'
+		__version_tuple__ = version_tuple = (${PV//./, })
+	EOF
+}
diff --git a/dev-python/scikit-build-core/Manifest b/dev-python/scikit-build-core/Manifest
index 8b6455821650..397394212d5b 100644
--- a/dev-python/scikit-build-core/Manifest
+++ b/dev-python/scikit-build-core/Manifest
@@ -2,3 +2,5 @@ DIST scikit_build_core-1.0.2.tar.gz 469825 BLAKE2B 11abd8868155e046a0c25b1b2596e
 DIST scikit_build_core-1.0.2.tar.gz.provenance 10011 BLAKE2B c1c9d40f30db12f204447fa487c79ec5aaf2b6361d1a39bc4dfeb4d2188ff6b2f60294d7d3396630c6bb5c3071d29cfa4a5a5c77d9c66a56add636ca322b7fc1 SHA512 e68f3c66e62ab402d5eca861e7711cad3726e33d7378a79c0dbd3b78f31b0ead88d41928669f6cedfbf7372d7e00265e2344a1e6f59d093c0d75ba056efe13d9
 DIST scikit_build_core-1.0.3.tar.gz 477539 BLAKE2B c06ccb744e5c0ebe6afef33425d1442e7e515b5209ab76ee9891776cb75b31a5f01c847056c3df68ae0464f4417e48f1a2a863252f2d8f43b0a0563bf1b15aac SHA512 84f73b5133750ed09804e9cfde48435cd533881948320613c425c42820b78d19a1041f8354a3fb385745bd2036a569dc04b393aea6cb93fd4cc289ed837c8b18
 DIST scikit_build_core-1.0.3.tar.gz.provenance 9921 BLAKE2B 19e77a7d1ba1fa8c0b46933494427a3c8ebe41a865e2a6e9dca2781a2e2b634c69034df110c62c97ff144c5d03c0d05296a044be90966a8d7b64bccf9611325b SHA512 313a5a7fe184725a9b18a7a53950ce05cf128c87c10d93698e75f9aac236d55d609430003778e8207e80c9386d73337edc52fa35c14c5d8727d0b37276db7377
+DIST scikit_build_core-1.1.0.tar.gz 513774 BLAKE2B 8dcb06a40e7a49b5aafb3f078334736d30e00bdaef07c2b0305b2acff0da0ff45b3e699872e5d2b9d1eb5e90919e68f87c233f37f47cc390edc7a7881fbd4f11 SHA512 1ef26dc17f142a93383b01200cdfc79e0da6c5caae6ab0918bd53399d6b31b583d1c5590a4a7ce48ef1be3cc33b4ae9ec463dccb0da5ecf70b5c0f613fddca9e
+DIST scikit_build_core-1.1.0.tar.gz.provenance 10013 BLAKE2B 0b49854e75518c6550acccc4cfca59244912712205480cfd125de29ee270b899b0ef376cf24a34cc3212671126ce0b00f6585d555a60de03691bf76587e8c476 SHA512 bdbb837ec19ae8fffc182e00b26d93ab7dca16328c601aa94d334e5b92cda9006f5358fd693c6f249b89fd09716bbee2aaad3538b9694254a4c9825e15e91773
diff --git a/dev-python/scikit-build-core/scikit-build-core-1.1.0.ebuild b/dev-python/scikit-build-core/scikit-build-core-1.1.0.ebuild
new file mode 100644
index 000000000000..96f33014caf2
--- /dev/null
+++ b/dev-python/scikit-build-core/scikit-build-core-1.1.0.ebuild
@@ -0,0 +1,52 @@
+# Copyright 2023-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYPI_VERIFY_REPO=https://github.com/scikit-build/scikit-build-core
+PYTHON_COMPAT=( python3_{13..14} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Build backend for CMake based projects"
+HOMEPAGE="
+	https://github.com/scikit-build/scikit-build-core/
+	https://pypi.org/project/scikit-build-core/
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~arm64-macos ~x64-macos ~x64-solaris"
+
+# we always want [pyproject] extra
+RDEPEND="
+	app-alternatives/ninja
+	dev-build/cmake
+	>=dev-python/packaging-23.2[${PYTHON_USEDEP}]
+	>=dev-python/pathspec-0.12.0[${PYTHON_USEDEP}]
+	>=dev-python/pyproject-metadata-0.5[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	dev-python/hatch-vcs[${PYTHON_USEDEP}]
+	test? (
+		dev-python/build[${PYTHON_USEDEP}]
+		>=dev-python/cattrs-22.2.0[${PYTHON_USEDEP}]
+		dev-python/fastjsonschema[${PYTHON_USEDEP}]
+		dev-python/pybind11[${PYTHON_USEDEP}]
+		dev-python/setuptools[${PYTHON_USEDEP}]
+		dev-python/virtualenv[${PYTHON_USEDEP}]
+	)
+"
+
+EPYTEST_PLUGINS=( pytest-subprocess )
+distutils_enable_tests pytest
+
+python_test() {
+	local EPYTEST_IGNORE=(
+		# needs unpackaged validate_pyproject
+		tests/test_schema.py
+	)
+
+	epytest -m "not isolated and not network"
+}
diff --git a/dev-python/tox/Manifest b/dev-python/tox/Manifest
index f5d3d604472a..e6785347821c 100644
--- a/dev-python/tox/Manifest
+++ b/dev-python/tox/Manifest
@@ -20,3 +20,5 @@ DIST tox-4.64.1.tar.gz 314417 BLAKE2B e781f568e92679b3e3418efe7bbfa67fc1b8f36a0f
 DIST tox-4.64.1.tar.gz.provenance 9536 BLAKE2B aec4451138b8b7776fdeeeef5f6dec928d9e32816d5c98817ea9956a7576a663fa59bdc9dc53fcc7d8a1e46a64801377822f44a45bf678aa2a2564c66cf89be4 SHA512 9854963c80fecc01ad6e62a93854e8cecf23a180620cca889faf67c8977177425b5090ef90c407b73703d488a6e0d1124dd56e40e7cceb5cc2139991295d62eb
 DIST tox-4.64.2.tar.gz 315797 BLAKE2B c87794ccfc1576b523391334e87fab7971f822b49cfff2c561a5520777e3d66681bf8082aed13a62b46856421dcee8c4aa2bac9cdf96c9ba4f66ea2005481148 SHA512 c2b13f35a85796d43a14adb4690a3d8e8f352d319349ee19bce6dd6c56eedbcb2fb629c81aec5f2b46fca66293703e3fa89c61b1a16a28a6fe243ee7fd5542f9
 DIST tox-4.64.2.tar.gz.provenance 9532 BLAKE2B ba270535d40da24e136aeceff18aaf8b396a62cb33d1f6588eaec9b827c6a728fb41503b1808e5348cf304c599d8e98568e586a455b4d9f6858cb1af8966dd37 SHA512 774adc6a4f329ac446bcf05ea1ab2cea988c61a90e30a4cde2bb0dd2636f355e3dae3c88d7e4279a0e18144b63e6b95a62ad925ede5cd28ac45b0b8a80e68ac2
+DIST tox-4.64.3.tar.gz 316391 BLAKE2B bc50918e6e65a56671930f62c4ad0907b27930685b7c262e484f0f5c3335405baa296de8ae6f7f7f5c29d9b9d055497cb73752e83d603c83f89a9b7bb08a85c0 SHA512 ef22fbd1a4a3bfb190af0d5f7ef683f0ffc35b889852e6b84eae9d062fe4722061db73a9f1973a6c5e72cc92b8f16dfa10cb4778f78d9050701f6404e15da113
+DIST tox-4.64.3.tar.gz.provenance 9485 BLAKE2B ebba61eec097a57a7260524ce45f4ac2cd26ae77c589fd76037c0b906010d35f2956ddb9b6daaaeb374d34b55ab9aeb12d7cccd8dd465730445f1666bff126cb SHA512 2f9eb62809e074ca389442bfb2b96eeb0fa2cb0647b6c2076fa572db2a80abbfd8b9a5255553171dde12fc73a5036e274329308d5572ad511de90dc15507d75d
diff --git a/dev-python/tox/tox-4.64.3.ebuild b/dev-python/tox/tox-4.64.3.ebuild
new file mode 100644
index 000000000000..9d80c8ee22b8
--- /dev/null
+++ b/dev-python/tox/tox-4.64.3.ebuild
@@ -0,0 +1,84 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYPI_VERIFY_REPO=https://github.com/tox-dev/tox
+PYTHON_COMPAT=( python3_{13..14} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="virtualenv-based automation of test activities"
+HOMEPAGE="
+	https://tox.readthedocs.io/
+	https://github.com/tox-dev/tox/
+	https://pypi.org/project/tox/
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~m68k ~ppc ~ppc64 ~riscv ~s390 ~x86"
+
+RDEPEND="
+	dev-python/cachetools[${PYTHON_USEDEP}]
+	dev-python/colorama[${PYTHON_USEDEP}]
+	dev-python/filelock[${PYTHON_USEDEP}]
+	dev-python/packaging[${PYTHON_USEDEP}]
+	dev-python/platformdirs[${PYTHON_USEDEP}]
+	dev-python/pluggy[${PYTHON_USEDEP}]
+	dev-python/pyproject-api[${PYTHON_USEDEP}]
+	dev-python/python-discovery[${PYTHON_USEDEP}]
+	dev-python/tomli-w[${PYTHON_USEDEP}]
+	dev-python/virtualenv[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '
+		>=dev-python/typing-extensions-4.15[${PYTHON_USEDEP}]
+	' 3.12)
+"
+BDEPEND="
+	dev-python/docutils[${PYTHON_USEDEP}]
+	dev-python/hatch-vcs[${PYTHON_USEDEP}]
+	test? (
+		dev-python/argcomplete[${PYTHON_USEDEP}]
+		dev-python/build[${PYTHON_USEDEP}]
+		dev-python/distlib[${PYTHON_USEDEP}]
+		dev-python/psutil[${PYTHON_USEDEP}]
+		dev-python/re-assert[${PYTHON_USEDEP}]
+	)
+"
+
+EPYTEST_PLUGINS=( pytest-{mock,rerunfailures,timeout,xdist} time-machine )
+EPYTEST_RERUNS=3
+# upstream timeouts are quite short
+: ${EPYTEST_TIMEOUT:=180}
+EPYTEST_XDIST=1
+distutils_enable_tests pytest
+
+src_prepare() {
+	# upstream lower bounds are meaningless
+	sed -i -e 's:>=[0-9.]*::' pyproject.toml || die
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	# devpi_process is not packaged, and has lots of dependencies
+	cat > "${T}"/devpi_process.py <<-EOF || die
+		def IndexServer(*args, **kwargs): raise NotImplementedError()
+	EOF
+
+	local -x PYTHONPATH=${T}:${PYTHONPATH}
+	local EPYTEST_DESELECT=(
+		# Internet
+		tests/tox_env/python/virtual_env/package/test_package_cmd_builder.py::test_build_wheel_external
+		tests/tox_env/python/virtual_env/package/test_package_cmd_builder.py::test_run_installpkg_targz
+		tests/tox_env/python/virtual_env/package/test_package_pyproject.py::test_pyproject_installpkg_pep517_envs
+		# require tombi
+		tests/session/cmd/test_schema.py::test_schema_tombi_lint
+	)
+	local EPYTEST_IGNORE=(
+		# requires devpi*
+		tests/test_provision.py
+	)
+
+	epytest -o addopts=
+}