12 files changed, 230 insertions, 29 deletions
diff --git a/dev-ruby/afm/afm-0.2.2.ebuild b/dev-ruby/afm/afm-0.2.2.ebuild
deleted file mode 100644
index 4a843beafb4c..000000000000
--- a/dev-ruby/afm/afm-0.2.2.ebuild
+++ /dev/null
@@ -1,26 +0,0 @@
-# Copyright 1999-2020 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=5
-USE_RUBY="ruby24 ruby25 ruby26 ruby27"
-
-RUBY_FAKEGEM_TASK_DOC="rdoc"
-RUBY_FAKEGEM_EXTRADOC="README.rdoc"
-
-inherit ruby-fakegem
-
-DESCRIPTION="A very simple library to read Adobe Font Metrics files"
-HOMEPAGE="https://github.com/halfbyte/afm"
-
-LICENSE="MIT"
-SLOT="0"
-KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ppc ~ppc64 ~sparc ~x86"
-IUSE="test"
-
-all_ruby_prepare() {
-	sed -i -e "/[Bb]undler/s/^/#/" Rakefile test/helper.rb || die
-}
-
-each_ruby_test() {
-	${RUBY} -Ilib:test test/test_afm.rb || die
-}
diff --git a/dev-ruby/annoy/annoy-0.5.6-r2.ebuild b/dev-ruby/annoy/annoy-0.5.6-r2.ebuild
new file mode 100644
index 000000000000..90a6c8e64eb0
--- /dev/null
+++ b/dev-ruby/annoy/annoy-0.5.6-r2.ebuild
@@ -0,0 +1,25 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+USE_RUBY="ruby26 ruby27 ruby30"
+
+RUBY_FAKEGEM_TASK_TEST=""
+
+RUBY_FAKEGEM_DOCDIR="doc"
+RUBY_FAKEGEM_EXTRADOC="CHANGES.txt README.rdoc"
+
+RUBY_FAKEGEM_BINWRAP=""
+
+inherit ruby-fakegem
+
+DESCRIPTION="Like your annoying friend that asks you questions all the time"
+HOMEPAGE="http://solutious.com/"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE=""
+
+ruby_add_rdepend '>=dev-ruby/highline-1.5.0:*'
diff --git a/dev-ruby/blankslate/blankslate-3.1.3-r1.ebuild b/dev-ruby/blankslate/blankslate-3.1.3-r1.ebuild
index d3ebf1f271ef..b6499aceb038 100644
--- a/dev-ruby/blankslate/blankslate-3.1.3-r1.ebuild
+++ b/dev-ruby/blankslate/blankslate-3.1.3-r1.ebuild
@@ -17,7 +17,7 @@ HOMEPAGE="https://rubygems.org/gems/blankslate"
 IUSE=""
 LICENSE="MIT"
 SLOT="0"
-KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ppc ~ppc64 ~riscv ~sparc ~x86"
+KEYWORDS="~alpha amd64 arm arm64 ~hppa ppc ppc64 ~riscv sparc x86"
 
 all_ruby_prepare() {
 	# Avoid test failing with rspec 2.x.
diff --git a/dev-ruby/dust/dust-0.1.7-r3.ebuild b/dev-ruby/dust/dust-0.1.7-r3.ebuild
new file mode 100644
index 000000000000..f1dc68162c9b
--- /dev/null
+++ b/dev-ruby/dust/dust-0.1.7-r3.ebuild
@@ -0,0 +1,30 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+USE_RUBY="ruby26 ruby27 ruby30"
+
+RUBY_FAKEGEM_EXTRADOC="README"
+
+inherit ruby-fakegem
+
+DESCRIPTION="Descriptive block syntax definition for Test::Unit"
+HOMEPAGE="http://dust.rubyforge.org/"
+LICENSE="MIT"
+
+KEYWORDS="~amd64 ~x86"
+SLOT="0"
+IUSE=""
+
+# Remove a long-obsolete rubygems method.
+all_ruby_prepare() {
+	sed -i -e '/manage_gems/d' \
+		-e '/gempackagetask/d' \
+		-e '/GemPackageTask/,/end/d' \
+		-e 's:rake/rdoctask:rdoc/task:' rakefile.rb || die "Unable to update rakefile.rb"
+
+}
+
+each_ruby_test() {
+	${RUBY} -I. test/all_tests.rb || die
+}
diff --git a/dev-ruby/json/Manifest b/dev-ruby/json/Manifest
index a5e364879ccd..d2cb154f1999 100644
--- a/dev-ruby/json/Manifest
+++ b/dev-ruby/json/Manifest
@@ -1,2 +1,3 @@
 DIST json-2.3.0.gem 114176 BLAKE2B 329f1305a0cae3d44c74cc7475c7340e86b8447d5e4ffdd5854620669ee4ef5bba0ed7dbc617b0beffb7bfd8b3d79d46ce26feef37685413a4a5a9c230d0ce0c SHA512 9086a64b664f2d774439c0c9f10c2c1cd897684050eb60f8e3ad9256e0b9541deec3bd22fab0bdcf66e3d5bc795720c6923d514b6edb824c9962fc22f162b332
 DIST json-2.5.1.tar.gz 131183 BLAKE2B 2ccdf5921ef476b66cb1dbf72cc01763636c82b0eb5d0a5cfc029e14177c7c6766464e7852b11c2424db401f5b931cb64c01d3952929236c9979378a7928ea59 SHA512 4df7ec9b86692376e89c2019c2c1ab3ae9af28fb4742864acc6f985c0551fc10795742cc1124d6435e820617c00d4c5f4aa6c83b21d2fff43ed05cd9d0a89087
+DIST json-2.6.1.tar.gz 132705 BLAKE2B 5a8e83b8d11e360402324427de5d2520f39ee1567e2fbf3c92c738546792bb5dec4a9a3c36f3286a3de63161bb5d9f9e7b059c2560f7a3fa50271ce2aa3dc0fc SHA512 e9d0ef77d77ae54a0300b490e3e5c445d0b5aefbce1b160454916bd4f4f8f943131223047e6a7416347cc40d9e7fb1870101c3cbf3a2663a9053f07bdfbd13cf
diff --git a/dev-ruby/json/json-2.6.1.ebuild b/dev-ruby/json/json-2.6.1.ebuild
new file mode 100644
index 000000000000..34e2b84f19d0
--- /dev/null
+++ b/dev-ruby/json/json-2.6.1.ebuild
@@ -0,0 +1,63 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+USE_RUBY="ruby26 ruby27 ruby30"
+
+RUBY_FAKEGEM_EXTRADOC="CHANGES.md README.md"
+RUBY_FAKEGEM_DOCDIR="doc"
+
+RUBY_FAKEGEM_GEMSPEC="json.gemspec"
+
+RUBY_FAKEGEM_EXTENSIONS=(ext/json/ext/parser/extconf.rb ext/json/ext/generator/extconf.rb)
+
+inherit multilib ruby-fakegem
+
+DESCRIPTION="A JSON implementation as a Ruby extension"
+HOMEPAGE="https://github.com/flori/json"
+SRC_URI="https://github.com/flori/json/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+LICENSE="Ruby"
+
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+SLOT="2"
+IUSE=""
+
+RDEPEND="${RDEPEND}"
+DEPEND="${DEPEND}
+	dev-util/ragel"
+
+ruby_add_bdepend "dev-ruby/rake
+	doc? ( dev-ruby/rdoc )
+	test? ( dev-ruby/test-unit:2 )"
+
+all_ruby_prepare() {
+	# Avoid building the extension twice!
+	# And use rdoc instead of sdoc which we don't have packaged
+	# And don't call git to list files. We're using the pregenerated spec anyway.
+	sed -i \
+		-e '/task :test/ s|:compile,||' \
+		-e 's| => :clean||' \
+		-e 's|sdoc|rdoc|' \
+		-e 's|`git ls-files`|""|' \
+		Rakefile || die "rakefile fix failed"
+
+	# Remove hardcoded and broken -O setting.
+	sed -i -e '/^  \(if\|unless\)/,/^  end/ s:^:#:' \
+		-e '/^unless/,/^end/ s:^:#:' ext/json/ext/*/extconf.rb || die
+
+	# Avoid setting gem since it will not be available yet when installing
+	sed -i -e '/gem/ s:^:#:' tests/test_helper.rb || die
+}
+
+#each_ruby_compile() {
+#	for ext in parser generator ; do
+#		cp ext/json/ext/${ext}/${ext}$(get_modname) ext/json/ext/ || die
+#	done
+#}
+
+each_ruby_install() {
+	each_fakegem_install
+
+	#ruby_fakegem_newins ext/json/ext/generator$(get_modname) lib/json/ext/generator$(get_modname)
+	#ruby_fakegem_newins ext/json/ext/parser$(get_modname) lib/json/ext/parser$(get_modname)
+}
diff --git a/dev-ruby/ruby-mp3info/ruby-mp3info-0.8.10-r1.ebuild b/dev-ruby/ruby-mp3info/ruby-mp3info-0.8.10-r1.ebuild
new file mode 100644
index 000000000000..d1bfe6bc1172
--- /dev/null
+++ b/dev-ruby/ruby-mp3info/ruby-mp3info-0.8.10-r1.ebuild
@@ -0,0 +1,24 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+USE_RUBY="ruby26 ruby27 ruby30"
+
+RUBY_FAKEGEM_EXTRADOC="History.txt README.md"
+RUBY_FAKEGEM_GEMSPEC="ruby-mp3info.gemspec"
+
+inherit ruby-fakegem
+
+DESCRIPTION="A pure Ruby library for access to mp3 files (internal infos and tags)"
+HOMEPAGE="http://rubyforge.org/projects/ruby-mp3info/"
+SRC_URI="https://github.com/moumar/${PN}/archive/v${PV}.tar.gz -> ${P}-git.tgz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+IUSE=""
+
+DEPEND+=" test? ( media-sound/id3v2 )"
+
+ruby_add_bdepend "test? ( dev-ruby/hoe dev-ruby/test-unit:2 )"
diff --git a/dev-ruby/ruby-openid/ruby-openid-2.9.2.ebuild b/dev-ruby/ruby-openid/ruby-openid-2.9.2.ebuild
index 4d4607ffb29b..12c8796205e4 100644
--- a/dev-ruby/ruby-openid/ruby-openid-2.9.2.ebuild
+++ b/dev-ruby/ruby-openid/ruby-openid-2.9.2.ebuild
@@ -1,8 +1,8 @@
 # Copyright 1999-2021 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI=7
-USE_RUBY="ruby24 ruby25 ruby26 ruby27"
+EAPI=8
+USE_RUBY="ruby26 ruby27 ruby30"
 
 RUBY_FAKEGEM_TASK_DOC=""
 RUBY_FAKEGEM_EXTRADOC="CHANGELOG.md README.md NOTICE UPGRADE.md"
diff --git a/dev-ruby/set/Manifest b/dev-ruby/set/Manifest
index a6c44f426863..0390b8d14a34 100644
--- a/dev-ruby/set/Manifest
+++ b/dev-ruby/set/Manifest
@@ -1 +1,2 @@
 DIST set-1.0.1.tar.gz 12567 BLAKE2B 0677108ff15108fda793f150586f7e7620d1f83e3636724881227021b7d78e4259e14b7191688bf41c512e49fe26d5d57872f4a369408f7e277967759f765be1 SHA512 0fbe6dd5d14f1f08725958892afed85c9f9a11912a0dc7d5456cc54782e348ab19973b21abfdfb5109e511e8b6932a469f7888f3387024e178c6a63fba8ba795
+DIST set-1.0.2.tar.gz 14237 BLAKE2B 767e8ea3684a91475f8dfc1190e2a8022b4330071ceb12ee06f76c23d688f6203571c127592adf5de7ff7b5722999d7a7605df8dc5215e183dabd65fb7863c80 SHA512 b64aeb47b7abe1e1245d33cc081c21f36ab66a115a88678c8b99c44149ef87eb1a522f166d8e02abe614623178992758cb88e9a0aea25fee0e39229265eab59c
diff --git a/dev-ruby/set/set-1.0.2.ebuild b/dev-ruby/set/set-1.0.2.ebuild
new file mode 100644
index 000000000000..2ca245abc0f2
--- /dev/null
+++ b/dev-ruby/set/set-1.0.2.ebuild
@@ -0,0 +1,23 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+USE_RUBY="ruby26 ruby27 ruby30"
+
+RUBY_FAKEGEM_BINWRAP=""
+RUBY_FAKEGEM_GEMSPEC="set.gemspec"
+
+inherit ruby-fakegem
+
+DESCRIPTION="Provides a class to deal with collections of unordered, unique values"
+HOMEPAGE="https://github.com/ruby/set"
+SRC_URI="https://github.com/ruby/set/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE=""
+
+all_ruby_prepare() {
+	sed -i -e 's/git ls-files -z/find * -print0/' ${RUBY_FAKEGEM_GEMSPEC} || die
+}
diff --git a/dev-ruby/tidy_table/tidy_table-0.0.5-r6.ebuild b/dev-ruby/tidy_table/tidy_table-0.0.5-r6.ebuild
new file mode 100644
index 000000000000..52707fd36dd7
--- /dev/null
+++ b/dev-ruby/tidy_table/tidy_table-0.0.5-r6.ebuild
@@ -0,0 +1,30 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+USE_RUBY="ruby26 ruby27 ruby30"
+
+RUBY_FAKEGEM_RECIPE_TEST="rspec3"
+
+RUBY_FAKEGEM_DOCDIR="doc"
+
+RUBY_FAKEGEM_EXTRADOC="History.txt README.txt"
+
+inherit ruby-fakegem
+
+DESCRIPTION="Tool to convert an array of struct into an HTML table"
+HOMEPAGE="https://github.com/topfunky/tidy_table"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE=""
+
+all_ruby_prepare() {
+	# Remove reference to RSpec 1
+	sed -i -e '/spec/d' -e '1irequire "date"' spec/spec_helper.rb || die
+
+	# Remove metadata so a stub gemspec will be created to avoid the
+	# wrong runtime dependency on dev-ruby/hoe.
+	rm -f ../metadata || die
+}
diff --git a/dev-ruby/wirble/wirble-0.1.3-r5.ebuild b/dev-ruby/wirble/wirble-0.1.3-r5.ebuild
new file mode 100644
index 000000000000..43536f9ebca6
--- /dev/null
+++ b/dev-ruby/wirble/wirble-0.1.3-r5.ebuild
@@ -0,0 +1,30 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+USE_RUBY="ruby26 ruby27 ruby30"
+
+RUBY_FAKEGEM_EXTRADOC="README ChangeLog"
+
+RUBY_FAKEGEM_TASK_TEST=""
+
+inherit ruby-fakegem
+
+DESCRIPTION="Wirble is a set of enhancements for Irb"
+HOMEPAGE="http://pablotron.org/software/wirble/"
+
+LICENSE="Ruby"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86"
+IUSE=""
+
+pkg_postinst() {
+	elog "The quick way to use wirble is to make your ~/.irbrc look like this:"
+	elog "  # load libraries"
+	elog "  require 'rubygems'"
+	elog "  require 'wirble'"
+	elog "  "
+	elog "  # start wirble (with color)"
+	elog "  Wirble.init"
+	elog "  Wirble.colorize"
+}