3 files changed, 174 insertions, 0 deletions
diff --git a/dev-ruby/rdoc/rdoc-6.14.1-r1.ebuild b/dev-ruby/rdoc/rdoc-6.14.1-r1.ebuild
new file mode 100644
index 000000000000..1ea4b946ac9e
--- /dev/null
+++ b/dev-ruby/rdoc/rdoc-6.14.1-r1.ebuild
@@ -0,0 +1,106 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+USE_RUBY="ruby32 ruby33 ruby34"
+
+RUBY_FAKEGEM_RECIPE_DOC=""
+RUBY_FAKEGEM_DOCDIR="doc"
+RUBY_FAKEGEM_EXTRADOC="History.rdoc README.rdoc RI.md TODO.rdoc"
+
+RUBY_FAKEGEM_BINWRAP=""
+RUBY_FAKEGEM_BINDIR="exe"
+
+RUBY_FAKEGEM_GEMSPEC="rdoc.gemspec"
+
+inherit ruby-fakegem
+
+DESCRIPTION="An extended version of the RDoc library from Ruby 1.8"
+HOMEPAGE="https://github.com/ruby/rdoc/"
+SRC_URI="https://github.com/ruby/rdoc/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="|| ( GPL-2 Ruby-BSD )"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~arm64-macos ~ppc-macos ~x64-macos ~x64-solaris"
+IUSE="doc"
+
+RDEPEND=">=app-eselect/eselect-ruby-20181225"
+
+ruby_add_rdepend "
+	dev-ruby/erb
+	>=dev-ruby/psych-4.0.0
+"
+
+ruby_add_bdepend "
+	>=dev-ruby/kpeg-1.1.0-r1
+	>dev-ruby/racc-1.4.10
+	dev-ruby/rake
+	test? (
+		dev-ruby/bundler
+		dev-ruby/prism
+		>=dev-ruby/minitest-5.8:5
+		dev-ruby/test-unit-ruby-core
+	)"
+
+all_ruby_prepare() {
+	# Other packages also have use for a nonexistent directory, bug 321059
+	sed -i -e 's#/nonexistent#/nonexistent_rdoc_tests#g' test/rdoc/rdoc*test.rb || die
+
+	# Avoid unneeded dependency on bundler, bug 603696
+	sed -i -e '/bundler/ s:^:#:' \
+		-e 's/Bundler::GemHelper.gemspec.full_name/"rdoc"/' \
+		-e '/rubocop\/rake/ s:^:#:' \
+		-e '/RuboCop/,/end/ s:^:#:' Rakefile || die
+
+	# Skip rubygems tests since the rubygems test case code is no longer installed by rubygems.
+	sed -i -e '/^task/ s/, :rubygems_test//' Rakefile || die
+
+	# Remove test that is depending on the locale, which we can't garantuee.
+	sed -i -e '/def test_encode_with/,/^  end/ s:^:#:' test/rdoc/rdoc_options_test.rb || die
+
+	# Remove test depending on FEATURES=userpriv, bug 361959
+	sed -i -e '/def test_check_files/,/^  end/ s:^:#:' test/rdoc/rdoc_options_test.rb || die
+
+	# Remove test depending on currently unpackaged prism
+	#rm -f test/rdoc/rdoc_parser_prism_ruby_test.rb || die
+
+	sed -i -e 's:_relative ": "./:' ${RUBY_FAKEGEM_GEMSPEC} || die
+}
+
+all_ruby_compile() {
+	all_fakegem_compile
+
+	if use doc ; then
+		ruby -S exe/rdoc --force-output || die
+		rm -f doc/js/*.gz || die
+	fi
+}
+
+each_ruby_compile() {
+	export LANG=C.UTF-8
+	${RUBY} -S rake generate || die
+}
+
+all_ruby_install() {
+	all_fakegem_install
+
+	for bin in rdoc ri; do
+		ruby_fakegem_binwrapper $bin /usr/bin/$bin-2
+
+		for version in $(ruby_get_use_implementations); do
+			version=`echo ${version} | cut -c 5-`
+			if use ruby_targets_ruby${version}; then
+				ruby_fakegem_binwrapper $bin /usr/bin/${bin}${version}
+				sed -i -e "1s/env ruby/ruby${version}/" \
+					"${ED}/usr/bin/${bin}${version}" || die
+			fi
+		done
+	done
+}
+
+pkg_postinst() {
+	if [[ ! -n $(readlink "${ROOT}"/usr/bin/rdoc) ]] ; then
+		eselect ruby set $(eselect --brief --colour=no ruby show | head -n1)
+	fi
+}
diff --git a/dev-ruby/sass/Manifest b/dev-ruby/sass/Manifest
index 7faff870b0c9..4fd6e3c7ef69 100644
--- a/dev-ruby/sass/Manifest
+++ b/dev-ruby/sass/Manifest
@@ -1 +1,2 @@
+DIST sass-3.7.4-ruby34-patches.tar.xz 9644 BLAKE2B 07d687ec39f0a9c031730f6cef4acf9c7458e2b892e24f02dd18b4bf7081e236d9bc73cfefe1be91500bef390a98e45a496021f6b56730b20cca5d34c291f052 SHA512 d4d43a0e143b7116214baf219fc60be4515dec116ef81ee683669bd90845724bc5d4caa547f6ad422f36530291d1390004c59db4aef6b1a2da87d92a27240c78
 DIST sass-3.7.4.tar.gz 401442 BLAKE2B 52abe37390282d2aead3eea6c2a049da529a5e96bac44b01ccded1e3c4d2c332d82f164da941413c0138fd3a94f59cda084d8fb724db87fc522f33dd7bc31adb SHA512 4bebb6ddc84e7f2687d9b801e6b30e897d83a46940249349d775e0139d1fca8ffd96d0976f4c35a7a0dba9ebf786883a70aff2ff002708e28b685a034634aaf2
diff --git a/dev-ruby/sass/sass-3.7.4-r3.ebuild b/dev-ruby/sass/sass-3.7.4-r3.ebuild
new file mode 100644
index 000000000000..1203151d2c3b
--- /dev/null
+++ b/dev-ruby/sass/sass-3.7.4-r3.ebuild
@@ -0,0 +1,67 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+USE_RUBY="ruby32 ruby33 ruby34"
+
+RUBY_FAKEGEM_TASK_DOC=""
+RUBY_FAKEGEM_DOCDIR="doc"
+RUBY_FAKEGEM_EXTRADOC="README.md"
+
+RUBY_FAKEGEM_EXTRAINSTALL="rails init.rb VERSION VERSION_NAME"
+RUBY_FAKEGEM_GEMSPEC="sass.gemspec"
+
+inherit ruby-fakegem
+
+DESCRIPTION="An extension of CSS3, adding nested rules, variables, mixins, and more"
+HOMEPAGE="https://sass-lang.com/"
+SRC_URI="https://github.com/sass/ruby-sass/archive/${PV}.tar.gz -> ${P}.tar.gz
+		 https://dev.gentoo.org/~graaff/ruby-team/${P}-ruby34-patches.tar.xz"
+RUBY_S="ruby-sass-${PV}"
+
+LICENSE="MIT"
+SLOT="$(ver_cut 1-2)"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux"
+IUSE="doc test"
+
+ruby_add_bdepend "
+	doc? ( >=dev-ruby/yard-0.5.3 )
+	test? ( dev-ruby/minitest )
+"
+
+ruby_add_rdepend "
+	!!<dev-ruby/sass-3.4.25-r1:3.4
+	!!<dev-ruby/sass-3.5.7-r1:3.5
+	dev-ruby/listen
+"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-3.7.4-use-listen-not-sass-listen.patch
+)
+
+# tests could use `less` if we had it
+
+all_ruby_prepare() {
+	eapply ../000*
+
+	# We use dev-ruby/listen now instead of dev-ruby/sass-listen
+	sed -i \
+		-e "/sass-listen/s:, '~> 4.0.0'::" \
+		-e "s:sass-listen:listen:" \
+		${PN}.gemspec || die
+
+	# Don't require maruku as markdown provider but let yard decide.
+	sed -i -e '/maruku/d' .yardopts || die
+
+	# Keep VERSION_DATE around since we don't create a new package
+	sed -i -e '/at_exit/,/end/ s:^:#:' Rakefile || die
+
+	# Fix minitest deprecations
+	sed -e 's/MiniTest/Minitest/' \
+		-i test/test_helper.rb test/sass/test_helper.rb test/sass/*_test.rb test/sass/{scss,util}/*_test.rb || die
+}
+
+each_ruby_test() {
+	RUBOCOP=false ${RUBY} -S rake test:ruby || die
+}